在资源创建中使用集合映射

Question

我有一个集合对象的地形图，如下所示

variable "BName" {
 type = string
 }
variable "type_names" {
 type = map(object({
 name   = string
 type   = string
 stream = string
 grp    = optional(string)
 }))
}

我也在尝试在以下资源中使用 type_name。 我们如何在资源创建过程中从集合映射中引用值

resource "azure_resource" "reso" {
  id = az_resource.B_Name.id
  name       = var.type_names.name

 }
resource "az_resource" "B_Name" {
  name        = var.BName

}

如何在 terraform.tfvars 文件中传递此值以创建以下资源。现在我正在尝试通过以下方式

 BName  = "Test"
 type_names =   {
   name = "cooper"
   type = "senior"
   stream=  "developer"
   grp   =  "Mid"
}
{
   name = "Mike"
   type = "Junior"
   stream=  "tester"
   grp   =  "entry"
}

Answer 1

对于使用map(object) 变量输入的单个定义创建多个资源，存在通用算法和模式。首先，我们需要声明中的变量结构定义。对于您的示例，我们有：

variable "type_names" {
  type = map(object({
    name   = string
    type   = string
    stream = string
    grp    = optional(string)
  }))
}

鉴于关键字optional 的出现，我假设对可选对象键使用实验性功能。在这种情况下，资源具有描述性标识符会很有帮助。那很可能是name，因此我们可以将它从object 值中删除，并将其重构为map 键。使用符合类型定义的示例 default 更新定义将是：

variable "type_names" {
  type = map(object({
    type   = string
    stream = string
    grp    = optional(string)
  }))
  default = {
    "cooper" = {
      type   = "senior"
      stream = "developer"
      grp    = "Mid"
    },
    "Mike" = {
      type   = "Junior"
      stream = "tester"
      grp    = "entry"
    }
  }
}

然后我们可以轻松地使用它来管理具有单个定义和输入变量的多个资源。由于问题中的示例资源使用的键与提供的变量所拥有的键不同，因此我们将稍微修改示例资源：

resource "azure_resource" "this" {
  for_each = var.type_names

  # value is the object, so we access object values with standard `.key` syntax
  name   = each.key
  type   = each.value.type
  stream = each.value.stream
  grp    = each.value.grp
}

每个资源的命名空间将是azure_resource.this["<key>"]，例如azure_resource.this["Mike"]，可以正常访问其属性。