使用 Terraform 创建 Azure Spot 实例

Question

我正在尝试使用 Terraform 创建一个 Azure 点实例。我看到了这个讨论How do I request azure spot instances using terraform, in a virtual machine scale set?

我仍然无法弄清楚如何使用 terraform 配置 Azure 现场实例。然后我找到了这个 repo https://github.com/terraform-providers/terraform-provider-azurerm/tree/master/examples/vm-scale-set/linux

我使用 repo 中的示例来编写自己的 terraform 代码。我把它推到了 gitlab 这里是链接..https://gitlab.com/cloud-projectz/azure-spot-terraform.git

基本上，我想要实现的是创建一个或多个具有公共 ip 和 ssh 访问权限的现场实例，同时自动化网络安全规则。当我运行 terraform apply 时，一切似乎都很好。然后我注意到公共IP没有附加到现场vm！ 我不知道如何访问现场虚拟机！ repo 中还有一个 bash 脚本，它概述了我使用 terraform 完成的任务。

有人帮我解决这个问题吗？通过具有公共 ip 和 ssh 访问权限的 terraform 的 Azure 点 vm？

谢谢

Answer 1

关于问题，请参考以下脚本

provider "azurerm" {

    version = "~>2.0"
        
        features {}

}

resource "azurerm_resource_group" "example" {
  name     = "example-resources"
  location = "East Asia"
}

resource "azurerm_virtual_network" "example" {
  name                = "example-network"
  resource_group_name = azurerm_resource_group.example.name
  location            = azurerm_resource_group.example.location
  address_space       = ["10.0.0.0/16"]
}
resource "azurerm_subnet" "internal" {
  name                 = "internal"
  resource_group_name  = azurerm_resource_group.example.name
  virtual_network_name = azurerm_virtual_network.example.name
  address_prefixes     = ["10.0.2.0/24"]
}
resource "azurerm_network_security_group" "example" {
  name                = "allow-ssh"
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name
  
 security_rule {
    name                       = "SSH"
    priority                   = 1001
    direction                  = "Inbound"
    access                     = "Allow"
    protocol                   = "Tcp"
    source_port_range          = "*"
    destination_port_range     = "22"
    source_address_prefix      = "<IP address>"
    destination_address_prefix = "*"
  }
}
resource "azurerm_public_ip_prefix" "example" {
  name                = "example-pip"
  location            = azurerm_resource_group.example.location
  resource_group_name = azurerm_resource_group.example.name
}

resource "azurerm_linux_virtual_machine_scale_set" "example" {
  name                            = "example-vmss"
  resource_group_name             = azurerm_resource_group.example.name
  location                        = azurerm_resource_group.example.location
  sku                             = "Standard_F2"
  instances                       = 1
  admin_username                  = "azure"
  eviction_policy                 = "Deallocate"
  priority                        = "Spot"
  max_bid_price                   = 0.5

  admin_ssh_key {
    username   = "azure"
    public_key = file("/root/.ssh/Azure.pub")
  }


  source_image_reference {
    publisher = "Canonical"
    offer     = "UbuntuServer"
    sku       = "18.04-LTS"
    version   = "latest"
  }

  network_interface {
    name    = "interface"
    primary = true
    network_security_group_id= azurerm_network_security_group.example.id

    ip_configuration {
      name      = "internal"
      primary   = true
      subnet_id = azurerm_subnet.internal.id

      public_ip_address {
        name                = "first"
        public_ip_prefix_id = azurerm_public_ip_prefix.example.id
    }
  }
}

  os_disk {
    storage_account_type = "Standard_LRS"
    caching              = "ReadWrite"
  }
}