Terraform 多个实例，但通过单独执行

Question

我正在尝试使用负载均衡器、安全组和三个实例创建 AWS 实例 ---> GROUP 1

我可以通过声明适当的资源来做到这一点。

现在我想创建多个独立于先前实例的此类实例 ---> GROUP 2

我想要这个是因为 GROUPS 的安全性，即一个组的信息不应与其他组的信息重叠。

我尝试了很多，但找不到方法。

以下是实例示例：

resource "aws_instance" "node" {
  ami                    = data.aws_ami.ubuntu.id
  subnet_id              = aws_subnet.development-private-1a.id
  key_name               = aws_key_pair.nodes.key_name
  instance_type          = var.instance_type
  vpc_security_group_ids = [aws_security_group.dev-ec2-sg.id]
  
  tags          = {
    Name        = "${var.app_name}"
    #Environment = "production"
  }
  
  root_block_device {
        volume_type     = "gp2"
        volume_size     = 8
        delete_on_termination   = true
  }

  user_data = file("install_apache.sh")
}

resource "aws_lb_target_group_attachment" "node" {
  target_group_arn = aws_lb_target_group.dev.arn
  target_id        = aws_instance.node.id
  port             = 80
}

我想添加多个具有不同安全组和负载均衡器以及所有其他内容的实例。但我不想在 terraform 文件中添加相同的其他副本。我希望这些实例独立于这个实例，但我面临的问题是 terraform 只操纵这个实例。

Answer 1

基于 cmets，您可以考虑将实例代码及其依赖项（例如目标组附件）组织为 terraform (TF) modules。此外，由于您希望创建相同类型的多个实例，您可以考虑使用aws_autoscaling_group，它不仅可以让您轻松创建多个实例，还可以轻松管理它们。

随后，您可以如下定义一个模块。以下只是部分示例。我也不使用aws_autoscaling_group，而是使用count创建多个实例：

./module/ec2/main.tf

variable "subnet_id" {}

variable "app_name" {}

variable "key_pair" {}

variable "security_group_id" {}

variable "target_group_arn" {}

variable "instance_count" {
   default = 1
}

data "aws_ami" "ubuntu" {
 # ...
}

resource "aws_instance" "node" {
 
  count = var.instance_count
  
  ami                    = data.aws_ami.ubuntu.id
  subnet_id              = var.subnet_id
  key_name               = var.key_pair
  instance_type          = var.instance_type
  vpc_security_group_ids = [var.security_group_id]
  
  tags          = {
    Name        = "${var.app_name}"
    #Environment = "production"
  }
  
  root_block_device {
        volume_type     = "gp2"
        volume_size     = 8
        delete_on_termination   = true
  }

  user_data = file("install_apache.sh")
}

resource "aws_lb_target_group_attachment" "node" {

  count = var.instance_count

  target_group_arn = var.target_group_arn
  target_id        = aws_instance.node[count.index].id
  port             = 80
}

# some outputs skipped 

拥有这样的模块，在您的父文件/模块中，您将创建 GROUP 1 和 2 实例，如下所示（同样，只是部分示例）：

./main.tf

# resoruces such as LB, SGs, subnets, etc.


module "group1" {
  
  source = "./module/ec2/"

  instance_count = 3

  security_group_id = <security-group-id1>

  target_group_arn = aws_lb_target_group.dev.arn

  # other parameters
}

module "group2" {
  
  source = "./module/ec2/"

  instance_count = 3

  security_group_id = <security-group-id2>

  target_group_arn = aws_lb_target_group.dev.arn

  # other parameters
}