Terraform for_each 用例答案

【问题标题】：Terraform for_each use caseTerraform for_each 用例
【发布时间】：2020-12-19 01:40:36
【问题描述】：

我在每个区域创建了一堆 Route 53 解析器规则，这对 for_each 循环非常有效：

resource "aws_route53_resolver_rule" "resolver-rule" {
  for_each = var.resolver-rules
  domain_name          = each.value.domain-name
  name                 = format("core-%s", each.value.domain-label)
  rule_type            = "FORWARD"
  resolver_endpoint_id = aws_route53_resolver_endpoint.outbound-endpoint.id
  target_ip {
    ip = each.value.forwarder1
  }
  target_ip {
    ip = each.value.forwarder2
  }

  tags     = merge(var.tags, map("Name", format("core-%s-%s-%s", var.team_name, var.environment, each.value.domain-label)))
}

我的 var 看起来像这样：

variable "resolver-rules" {
  description = "A map of parameters needed for each resolver rule"
  type = map(object({
    domain-name   = string
    domain-label  = string   
    forwarder1    = string
    forwarder2    = string
  }))
}

resolver-rules = {
    "resolver-rule1" = {
        domain-name     = "10.in-addr.arpa."
        domain-label    = "10-in-addr-arpa"
        forwarder1      = "10.10.1.100"
        forwarder2      = "10.10.2.100"
    }
    "resolver-rule2" = {
        domain-name     = "mycompany.com."
        domain-label    = "mycompany-com"
        forwarder1      = "10.10.1.100"
        forwarder2      = "10.10.2.100"
    }
}

现在我需要将这些规则与资源共享相关联（不在此处发布）：

resource "aws_ram_resource_association" "rule-association" {
  for_each           = var.resolver-rules
  resource_arn       = aws_route53_resolver_rule.resolver-rule.arn
  resource_share_arn = aws_ram_resource_share.rte53-resolver-share.arn
}

问题：如何修改（枚举）我的资源关联部分，以便为我定义的每个规则创建每个关联（它必须是 1 对 1 关联）。我就是无法理解它:)

【问题讨论】：

标签： amazon-web-services terraform amazon-route53

【解决方案1】：

您的aws_route53_resolver_rule.resolver-rule 将是一个地图，其中包含resolver-rule1 和resolver-rule2 的键。

因此，要在您的rule-association 中访问其arn，您可以执行以下操作：

resource "aws_ram_resource_association" "rule-association" {
  for_each           = var.resolver-rules
  resource_arn       = aws_route53_resolver_rule.resolver-rule[each.key].arn
  resource_share_arn = aws_ram_resource_share.rte53-resolver-share.arn
}

在您的问题中，aws_ram_resource_share.rte53-resolver-share.arn 未显示，因此我不知道您是否还需要对其进行一些更改。

【讨论】：