汇编 IA-32：添加/减去 32 位有符号值并返回有符号 64 位

Question

在 IA-32 架构上，我如何将两个 32 位有符号 值相加/相减并将结果存储在 64 位 (EDX:EAX) 中，同时维护标志？

对于这个 32 位值：

A = 97
B = 232
C = 2147483600
D = 200

如何在 Assembly 中执行 C + A - D + B 并返回 64 位值？

注意：C + A 的结果会溢出 32 位注册表。

在将 C 添加到 A 之后，我尝试使用 adc 函数将进位添加到 edx，但由于它已签名，因此它不会像我假装的那样做。

我为 C+A 尝试过的，但它没有保留标志：

#Prologue
    pushl %ebp
    movl %esp, %ebp

    #Body
    movl $0, %edx
    movl $0, %ecx
    movl $0, %eax
    movb 8(%ebp), %al       #
    movsx %al, %eax         #move with sign extention to 32 bit eax
    addl 16(%ebp), %eax     #adding C + A
    adcl $0, %edx

如果 C 是 -97 而 A 是 -2147483600（对于负值），我也会遇到同样的问题。

Answer 1

最好的方法是在使用CDQ进行相应计算之前将32位有符号值扩展为64位有符号值：

.section .data

fmt: .string "Result: %lli\n"

.section .text
.globl main

main:
    pushl $97           # A
    pushl $232          # B
    pushl $2147483600   # C
    pushl $200          # D
    call do_it
    add $8, %esp

    push %edx
    push %eax
    push $fmt
    call printf
    add $8, %esp

    pushl $0
    call exit

do_it:
    pushl %ebp                  # Prologue
    movl %esp, %ebp

    mov 12(%ebp), %eax          # C
    cdq
    mov %edx, %edi              # X = C
    mov %eax, %esi

    mov 20(%ebp), %eax          # A
    cdq
    add %eax, %esi
    adc %edx, %edi              # X += A

    mov 8(%ebp), %eax           # D
    cdq
    sub %eax, %esi              # X -= D
    sbb %edx, %edi

    mov 16(%ebp), %eax          # B
    cdq
    add %eax, %esi
    adc %edx, %edi              # X += B

    mov %edi, %edx              # RETURN = X
    mov %esi, %eax

    leave                       # Epilogue
    ret