指向（子）方法函数的指针？

Question

如果你喜欢使用方法的指针作为参数，你需要将方法type 设置为function of object 这样工作好：

type TAcceptor = function(filename:string):boolean of object;
function acceptor(filename:string):boolean; 
begin 
  result := filename <> ''; 
end;

如果你喜欢使用子方法的指针怎么办？它不起作用：

procedure TForm1.Button1Click(Sender:TObject);
  function acceptor(filename:string):boolean of object;
  begin 
    result := filename <> ''; 
  end;
begin
end;

发生错误：; expected but OF found!

问题：有没有子函数指针？可以投吗？

Answer 1

我不明白这怎么可能。

http://docwiki.embarcadero.com/RADStudio/XE6/en/Procedural_Types

如果您查看method pointers 部分，它明确表示不能使用嵌套过程和函数：

"嵌套过程和函数（在其他程序中声明的例程 例程）不能用作程序值，也不能预定义 过程和功能。”

您也许可以使用匿名方法来解决它。比如：

procedure TForm1.Button1Click(Sender:TObject);
begin
  DoSomethingWithAcceptor(function(FileName: string): Boolean
  begin 
    Result := FileName <> '';
  end);
end;

Answer 2

注意

我知道以下内容并不普遍适用，但它适用于所有已知的 Win32 版本的 Delphi。只要您意识到这一点，并在新版本中检查它的功能，它就是一个可行的 hack，IMO。

---

将嵌套函数传递给方法

在旧代码中，我用它来做一些“穷人的匿名方法”：

type
  TLocal = packed record
    Code: Pointer;  // local (nested) function
    Frame: Pointer; // outer stack frame for local function
   end;

为了在方法内部填充这样的局部，我编写了函数 Local：

function Local(LocalFunction: Pointer): TLocal;
asm
  MOV [EDX].TLocal.Frame,EBP
  MOV [EDX].TLocal.Code,EAX
end;

在我的单元（某种通用集合）中，我编写了一个函数来调用它们，传递一个参数（在这种情况下，类型为 TGeneric，在这种情况下，这并不重要，你也可以传递一个指针或类似的东西） .

// Calls local function using local closure provided, passing
// T as parameter to the local.
function CallLocal(T: TGeneric; const Local: TLocal): TGeneric;
asm 
  PUSH [EDX].TLocal.Frame
  CALL [EDX].TLocal.Code
  ADD ESP,4
end;

它是这样使用的：

function TStdCollection.AsArray: TGenericArray;
var
  I: Integer;
  A: TGenericArray;

  procedure ToArray(E: TGeneric);
  begin
    Result[I] := E.Traits.Copy(E);
    Inc(I);
  end;

begin
  SetLength(A, Count);
  I := 0;
  ForEach(Local(@ToArray));
  Assert(I = Count);
  Result := A;
end;

嵌套函数中的代码复制元素并将其存储在数组中。然后，主过程将嵌套函数 ToArray（连同其堆栈帧）作为参数传递给 ForEach，其实现方式如下：

function TStdCollection.ForEach(Operation: TLocal): ICollection;
var
  Enum: IEnumerator;
  Elem: TGeneric;
begin
  Enum := GetEnumerator;
  Elem := Enum.First;
  while Elem <> nil do
  begin
    CallLocal(Elem, Operation);
    Elem := Enum.Next;
  end;
  Result := Self;
end;

这些示例展示了如何使用 Locals。我希望这或多或少能回答你的问题。

注意

请注意，此代码是在 Delphi 6 时间范围内编写的。我知道现在有更好的选择，比如泛型和匿名方法。但是如果需要与 Delphi 7 兼容，上面可能是一个解决方案。