如何加载包含小黄瓜变量的文件，而不是在机器人框架测试中写入变量

Question

我目前在机器人框架中使用小黄瓜排版来运行如下场景（它有效）：

*** Test Cases ***
Scenario: compute my data
    [Template]  Scenario Outline: compute my data
    origin1    SVA1000    NR
    origin2    SVA2000    NR2

*** Keywords ***
Scenario Outline: compute my data
    [Arguments]  ${origin}  ${reportingGroup}  ${report}
    Given print it ${origin} ${reportingGroup} ${report}


print it ${origin} ${reportingGroup} ${report}
    Log To Console    ${origin} ${reportingGroup} ${report}

我有大量数据，所以我想把我的变量放在一个 .txt 文件中：

origin1    SVA1000    NR
origin2    SVA2000    NR2

问题：如何加载包含变量的文件而不是在机器人代码中写入变量？

Answer 1

您可以参考此部分“Resource and variable files”。创建一个 python 文件并创建一个列表来存储你的变量。

我的解决方案：

variables.py

list =  [
            ["origin1","SVA1000","NR"],
            ["origin2","SVA2000","NR2"]
        ]

main.robot

*** Settings ***
Variables    variables.py

*** Test Cases ***
Scenario: compute my data
    FOR    ${data}    IN    @{list}
        FOR    ${data_0}    ${data_1}    ${data_2}    IN    @{data}
            Scenario Outline: compute my data    ${data_0}    ${data_1}    ${data_2}
        END
    END

*** Keywords ***
Scenario Outline: compute my data
    [Arguments]  ${origin}  ${reportingGroup}  ${report}
    Given print it ${origin} ${reportingGroup} ${report}


print it ${origin} ${reportingGroup} ${report}
    Log To Console    ${origin} ${reportingGroup} ${report}

输出：

==============================================================================
Main
==============================================================================
Scenario: compute my data                                             origin1 SVA1000 NR
origin2 SVA2000 NR2
Scenario: compute my data                                             | PASS |
------------------------------------------------------------------------------
Main                                                                  | PASS |
1 test, 1 passed, 0 failed
==============================================================================