使用 ColdFusion 将上传的图像保存到服务器

Question

我认为创建功能以允许用户将图片上传到服务器目录并寻求一些帮助是一项相对简单的任务，这让我感到困惑。

我有一个简单的表单，它有一个简单的界面，传递一个名为“imagedata”的变量，它是从文件输入传递的数据，一个名为“name”的变量，它是一个指定的图像名称，以及一个名为“imagetype”的变量它传递一个文件扩展名。

我在函数（处理程序）中用来保存这个文件的代码如下：

<cfset form.imageName = form.name & "." & form.imagetype />
...
<cffile action="write" file="#sitepath#storage/bannerImages/#form.imagename#" output="#form.imageData#" />

这显然行不通；它将以正确的名称保存文件，但不会正确保存文件并且不会呈现为图像。我认为这是相对简单的事情，我认为我忽略了一些事情，因为我在谷歌上没有找到任何东西，这很奇怪。对此问题的帮助将不胜感激。

Answer 1

不要使用action="write"，使用action="upload"。

例子：

<cffile
    action       = "upload"
    fileField    = "ImageData"
    destination  = "/tmp/uploads"
    accept       = "image/jpg"
    nameConflict = "MakeUnique"
/>

这会将文件放在/tmp/uploads（例如在Windows 上使用d:/tmp/uploads）- 这是一个无法在线访问的目录。

此时，您必须验证该文件是否与其声称的相同 - 具有适当尺寸和文件大小的图像文件，而不是经过掩码的 EXE 或 embedded ZIP。

一旦您对文件可以安全地托管在您的服务器上感到满意，您就可以将其移动到适当的目录并将名称设置为所选择的名称。

类似...

<cfif cffile.FileWasSaved>

    <cfset UploadedFileName = cffile.ServerDirectory & '/' & cffile.ServerFile />

    <cfif NOT IsImageFile( UploadedFileName )>
        <cfthrow message="Uploaded file not an image." />
    </cfif>

    <!--- INFO: Checks if zip embedded in image. --->
    <cftry>
        <cfzip action="list" file="#UploadedFileName#" name="tmp"/>
        <cfthrow message="Embedded zip files not allowed."/>
        <!--- TODO: Verify correct exception type for CF: --->
        <cfcatch type="java.util.zip.zipexception"></cfcatch>
    </cftry>

    <!---
        TODO: Validate any necessary business rules
        (e.g. image not too large, etc)
    --->        

<cfelse>
    <cfthrow message="File Upload Error"/>
</cfif>


<cfif refind('\W',Form.Name)>
    <cfthrow message="Invalid Name specified. Only alphanumerics allowed."/>
</cfif>
<cfif NOT ListFindNoCase('PNG,JPG,GIF',Form.ImageType)>
    <cfthrow message="Invalid FileType specified. Must be PNG/JPG/GIF"/></cfif>
</cfif>

<cffile
    action      = "rename"
    source      = "#UploadedFileName#"
    destination = "#sitepath#storage/bannerImages/#Form.Name#.#Form.ImageType#"
/>

该代码未经测试，并且 - 与您在服务器上运行的所有内容一样，尤其是涉及客户端上传的代码 - 确保在使用之前了解它的作用。
在Adobe LiveDocs 和various CF blogs 上有很多有价值的信息，值得花一些时间来消化。