如何使用 cmake 链接到 awesomium

Question

我是使用 awesomium 进行开发的新手，我正在尝试让 helo world 示例在 Ubuntu 中运行。我正在使用 CLion，它使用 CMake 作为构建系统。我想知道如何使用 CMake 成功链接到 Awesomium。

Answer 1

经过一波又一波的反复试验，我想通了：

CMakeList.txt：

cmake_minimum_required(VERSION 3.3)
project(LetsChat)

set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

set(SOURCE_FILES main.cpp)

find_package (Awesomium REQUIRED)
include_directories (${AWESOMIUM_INCLUDE_DIR})
add_executable(LetsChat ${SOURCE_FILES})

target_link_libraries(LetsChat ${AWESOMIUM_LIBRARY})

FindAwesomium.cmake（在 CMake 子目录下）

include (FindPackageHandleStandardArgs)

find_path(AWESOMIUM_INCLUDE_DIR Awesomium/WebCore.h
        PATH_SUFFIXES include
        PATHS
        ${AWESOMIUM_ROOT}
        $ENV{AWESOMIUM_ROOT}
        ~/Library/Frameworks
        /Library/Frameworks
        /usr/local/
        /usr/
        /sw          # Fink
        /opt/local/  # DarwinPorts
        /opt/csw/    # Blastwave
        /opt/)

find_library(AWESOMIUM_LIBRARY
        NAMES libawesomium-1-7.so
        PATH_SUFFIXES lib64 lib build/lib
        PATHS
        ${AWESOMIUM_ROOT}
        $ENV{AWESOMIUM_ROOT}
        ~/Library/Frameworks
        /Library/Frameworks
        /usr/local/
        /usr/lib/
        /usr/
        /sw          # Fink
        /opt/local/  # DarwinPorts
        /opt/csw/    # Blastwave
        /opt/)

find_package_handle_standard_args (Awesomium DEFAULT_MSG AWESOMIUM_INCLUDE_DIR AWESOMIUM_LIBRARY)
mark_as_advanced (AWESOMIUM_INCLUDE_DIR AWESOMIUM_LIBRARY)

if (AWESOMIUM_FOUND)
    message (STATUS "Found Awesomium: ${AWESOMIUM_INCLUDE_DIR}")
endif ()