如何使用 CMake 和 Mingw 在 Windows 中使用 zlib？

【问题标题】：How do I use zlib within windows using CMake and Mingw?如何使用 CMake 和 Mingw 在 Windows 中使用 zlib？
【发布时间】：2018-08-23 16:02:44
【问题描述】：

我的环境正在使用 CLion，运行 CMake 和 Mingw。

我需要在我的项目中使用 zlib，但我一辈子都无法在 windows 中链接它。

如果我遵循this stackoverflow article 的解决方案，尝试只构建zlib 示例二进制文件，并使用上述文章中的确切cmakelists，我会收到错误：

Could NOT find ZLIB (missing: ZLIB_INCLUDE_DIR)

我也无法在 zlib 官方网站上找到 zlib 的预编译二进制文件，zlib 自己的文档状态应该存在于网站上，因此尝试将其链接到我的项目中很困难。

我确实找到了一些二进制文件，但是在尝试链接它们时，（其中，我仍在尝试弄清楚如何将 dll 与 cmake 链接，所以这可能是问题的一部分），make 系统只是不行出去。

mingw32-make.exe[1]: *** [CMakeFiles/CMinecraft.dir/rule] Error 2 mingw32-make.exe: *** [CMinecraft] Error 2 CMakeFiles\Makefile2:153: recipe for target 'CMakeFiles/CMinecraft.dir/rule' failed

【问题讨论】：

  • 欢迎来到 Stack Overflow！如果您的代码有问题，请将代码添加到问题帖子中（以minimal reproducible example 的形式）并描述使用它时发生的情况。如果代码导致构建失败，请提供关于该失败的确切错误消息。 mingw32-make.exe[1]: *** [CMakeFiles/CMinecraft.dir/rule] Error 2 行不是描述性的，因为它只显示它是一些错误。
  • 嗨！感谢您的反馈。我对我使用的东西不是很具体。然而，我发布的错误是我收到的确切错误消息，我当然同意它表明发生了 some 错误，但编译器没有提供其他信息，这是我的困惑和原因的一部分首先是这个问题。

标签： windows cmake mingw zlib clion


【解决方案1】：

Personnaly for windows（VS 2015/2017 但应该与 Mingw 一起使用）我使用以下方法将其集成为 CMake 子项目：

在您的 CMakeLists.txt 中：

if(NOT TARGET ZLIB::ZLIB)
  message(STATUS "Target ZLIB::ZLIB not found.")
  message(STATUS "Adding CMake Subproject: ZLIB...")
  # Download and unpack zlib at configure time
  configure_file(
    ${CMAKE_CURRENT_SOURCE_DIR}/zlib.CMakeLists.txt
    ${CMAKE_BINARY_DIR}/zlib-download/CMakeLists.txt)
  execute_process(COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" .
    RESULT_VARIABLE result
    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/zlib-download)
  if(result)
    message(FATAL_ERROR "CMake step for zlib failed: ${result}")
  endif()
  execute_process(COMMAND ${CMAKE_COMMAND} --build .
    RESULT_VARIABLE result
    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/zlib-download)
  if(result)
    message(FATAL_ERROR "Build step for zlib failed: ${result}")
  endif()

  add_subdirectory(
    ${CMAKE_BINARY_DIR}/zlib-src
    ${CMAKE_BINARY_DIR}/zlib-build)
  message(STATUS "Adding CMake Subproject: ZLIB...DONE")
endif()

与 zlib.CMakeLists.txt：

cmake_minimum_required(VERSION 3.5)

# simplify variable expansion
cmake_policy(SET CMP0053 NEW)
cmake_policy(SET CMP0010 NEW)

project(zlib-download NONE)

include(ExternalProject)
ExternalProject_Add(zlib_project
  GIT_REPOSITORY "https://github.com/madler/zlib.git"
  GIT_TAG "v1.2.11"
  SOURCE_DIR "${CMAKE_BINARY_DIR}/zlib-src"
  BINARY_DIR "${CMAKE_BINARY_DIR}/zlib-build"
  UPDATE_COMMAND ""
  PATCH_COMMAND git apply "${PROJECT_SOURCE_DIR}/patches/zlib.patch"
  CONFIGURE_COMMAND ""
  BUILD_COMMAND ""
  INSTALL_COMMAND ""
  TEST_COMMAND ""
  LOG_DOWNLOAD ON
)

和补丁/zlib.path：

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 0fe939d..5f25cce 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1,24 +1,23 @@
-cmake_minimum_required(VERSION 2.4.4)
-set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS ON)
+cmake_minimum_required(VERSION 2.8.12)
+cmake_policy(SET CMP0048 NEW)
+project(zlib VERSION 1.2.11.1 LANGUAGES C)

-project(zlib C)
+option(ASM686 "Enable building i686 assembly implementation" OFF)
+option(AMD64 "Enable building amd64 assembly implementation" OFF)

-set(VERSION "1.2.11")
+include(GNUInstallDirs)
+set(INSTALL_BIN_DIR "${CMAKE_INSTALL_BINDIR}" CACHE PATH "Installation directory for executables")
+set(INSTALL_LIB_DIR "${CMAKE_INSTALL_LIBDIR}" CACHE PATH "Installation directory for libraries")
+set(INSTALL_INC_DIR "${CMAKE_INSTALL_INCLUDEDIR}" CACHE PATH "Installation directory for headers")

-option(ASM686 "Enable building i686 assembly implementation")
-option(AMD64 "Enable building amd64 assembly implementation")
-
-set(INSTALL_BIN_DIR "${CMAKE_INSTALL_PREFIX}/bin" CACHE PATH "Installation directory for executables")
-set(INSTALL_LIB_DIR "${CMAKE_INSTALL_PREFIX}/lib" CACHE PATH "Installation directory for libraries")
-set(INSTALL_INC_DIR "${CMAKE_INSTALL_PREFIX}/include" CACHE PATH "Installation directory for headers")
-set(INSTALL_MAN_DIR "${CMAKE_INSTALL_PREFIX}/share/man" CACHE PATH "Installation directory for manual pages")
-set(INSTALL_PKGCONFIG_DIR "${CMAKE_INSTALL_PREFIX}/share/pkgconfig" CACHE PATH "Installation directory for pkgconfig (.pc) files")
+set(INSTALL_MAN_DIR "${CMAKE_INSTALL_MANDIR}" CACHE PATH "Installation directory for manual pages")
+set(INSTALL_PKGCONFIG_DIR "${CMAKE_INSTALL_DATADIR}/pkgconfig" CACHE PATH "Installation directory for pkgconfig (.pc) files")

 include(CheckTypeSize)
 include(CheckFunctionExists)
 include(CheckIncludeFile)
 include(CheckCSourceCompiles)
-enable_testing()
+include(CTest)

 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
 check_include_file(stdint.h    HAVE_STDINT_H)
@@ -63,7 +62,6 @@ if(MSVC)
     set(CMAKE_DEBUG_POSTFIX "d")
     add_definitions(-D_CRT_SECURE_NO_DEPRECATE)
     add_definitions(-D_CRT_NONSTDC_NO_DEPRECATE)
-    include_directories(${CMAKE_CURRENT_SOURCE_DIR})
 endif()

 if(NOT CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR)
@@ -83,7 +81,6 @@ configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/zlib.pc.cmakein
        ${ZLIB_PC} @ONLY)
 configure_file(    ${CMAKE_CURRENT_SOURCE_DIR}/zconf.h.cmakein
        ${CMAKE_CURRENT_BINARY_DIR}/zconf.h @ONLY)
-include_directories(${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_SOURCE_DIR})


 #============================================================================
@@ -132,9 +129,9 @@ endif()
 if(CMAKE_COMPILER_IS_GNUCC)
     if(ASM686)
         set(ZLIB_ASMS contrib/asm686/match.S)
-    elseif (AMD64)
+           elseif(AMD64)
         set(ZLIB_ASMS contrib/amd64/amd64-match.S)
-    endif ()
+    endif()

    if(ZLIB_ASMS)
        add_definitions(-DASMV)
@@ -143,20 +140,20 @@ if(CMAKE_COMPILER_IS_GNUCC)
 endif()

 if(MSVC)
-    if(ASM686)
+   if(ASM686)
        ENABLE_LANGUAGE(ASM_MASM)
-        set(ZLIB_ASMS
+       set(ZLIB_ASMS
            contrib/masmx86/inffas32.asm
            contrib/masmx86/match686.asm
-       )
-    elseif (AMD64)
+           )
+   elseif(AMD64)
        ENABLE_LANGUAGE(ASM_MASM)
-        set(ZLIB_ASMS
+       set(ZLIB_ASMS
            contrib/masmx64/gvmat64.asm
            contrib/masmx64/inffasx64.asm
-       )
-    endif()
-
+           )
+       # set(ZLIB_SRCS ${ZLIB_SRCS} contrib/masmx64/inffas8664.c)
+   endif()
    if(ZLIB_ASMS)
        add_definitions(-DASMV -DASMINF)
    endif()
@@ -184,9 +181,25 @@ if(MINGW)
 endif(MINGW)

 add_library(zlib SHARED ${ZLIB_SRCS} ${ZLIB_ASMS} ${ZLIB_DLL_SRCS} ${ZLIB_PUBLIC_HDRS} ${ZLIB_PRIVATE_HDRS})
+target_include_directories(zlib PUBLIC
+   $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
+   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+   $<INSTALL_INTERFACE:include>)
+set_target_properties(zlib PROPERTIES
+   DEFINE_SYMBOL ZLIB_DLL
+   SOVERSION 1)
+
 add_library(zlibstatic STATIC ${ZLIB_SRCS} ${ZLIB_ASMS} ${ZLIB_PUBLIC_HDRS} ${ZLIB_PRIVATE_HDRS})
-set_target_properties(zlib PROPERTIES DEFINE_SYMBOL ZLIB_DLL)
-set_target_properties(zlib PROPERTIES SOVERSION 1)
+target_include_directories(zlibstatic PUBLIC
+   $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
+   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+   $<INSTALL_INTERFACE:include>)
+
+if(BUILD_SHARED_LIBS)
+   add_library(ZLIB::ZLIB ALIAS zlib)
+else()
+   add_library(ZLIB::ZLIB ALIAS zlibstatic)
+endif()

 if(NOT CYGWIN)
     # This property causes shared libraries on Linux to have the full version
@@ -197,6 +210,7 @@ if(NOT CYGWIN)
     # This has no effect with MSVC, on that platform the version info for
     # the DLL comes from the resource file win32/zlib1.rc
     set_target_properties(zlib PROPERTIES VERSION ${ZLIB_FULL_VERSION})
+    set_target_properties(zlibstatic PROPERTIES VERSION ${ZLIB_FULL_VERSION})
 endif()

 if(UNIX)
@@ -210,12 +224,30 @@ elseif(BUILD_SHARED_LIBS AND WIN32)
     set_target_properties(zlib PROPERTIES SUFFIX "1.dll")
 endif()

-if(NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL )
+#if(WIN32)
+#  add_definitions(-DZLIB_WINAPI)
+#endif()
+
+if(NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL)
     install(TARGETS zlib zlibstatic
-        RUNTIME DESTINATION "${INSTALL_BIN_DIR}"
-        ARCHIVE DESTINATION "${INSTALL_LIB_DIR}"
-        LIBRARY DESTINATION "${INSTALL_LIB_DIR}" )
-endif()
+           EXPORT ZLIBTargets
+           RUNTIME DESTINATION "${INSTALL_BIN_DIR}"
+           ARCHIVE DESTINATION "${INSTALL_LIB_DIR}"
+           LIBRARY DESTINATION "${INSTALL_LIB_DIR}")
+       install(EXPORT ZLIBTargets
+           NAMESPACE ZLIB::
+           DESTINATION lib/cmake/ZLIB)
+       include(CMakePackageConfigHelpers)
+       write_basic_package_version_file("${CMAKE_CURRENT_BINARY_DIR}/ZLIBConfigVersion.cmake"
+           VERSION ${PROJECT_VERSION}
+           COMPATIBILITY SameMajorVersion)
+       file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/ZLIBConfig.cmake"
+           "include(\"\${CMAKE_CURRENT_LIST_DIR}/ZLIBTargets.cmake\")"
+           )
+       install(FILES "${CMAKE_CURRENT_BINARY_DIR}/ZLIBConfig.cmake"
+           "${CMAKE_CURRENT_BINARY_DIR}/ZLIBConfigVersion.cmake"
+           DESTINATION lib/cmake/ZLIB)
+   endif()
 if(NOT SKIP_INSTALL_HEADERS AND NOT SKIP_INSTALL_ALL )
     install(FILES ${ZLIB_PUBLIC_HDRS} DESTINATION "${INSTALL_INC_DIR}")
 endif()
@@ -229,21 +261,22 @@ endif()
 #============================================================================
 # Example binaries
 #============================================================================
-
-add_executable(example test/example.c)
-target_link_libraries(example zlib)
-add_test(example example)
-
-add_executable(minigzip test/minigzip.c)
-target_link_libraries(minigzip zlib)
-
-if(HAVE_OFF64_T)
-    add_executable(example64 test/example.c)
-    target_link_libraries(example64 zlib)
-    set_target_properties(example64 PROPERTIES COMPILE_FLAGS "-D_FILE_OFFSET_BITS=64")
-    add_test(example64 example64)
-
-    add_executable(minigzip64 test/minigzip.c)
-    target_link_libraries(minigzip64 zlib)
-    set_target_properties(minigzip64 PROPERTIES COMPILE_FLAGS "-D_FILE_OFFSET_BITS=64")
+if(BUILD_TESTING)
+   add_executable(example test/example.c)
+   target_link_libraries(example zlib)
+   add_test(example example)
+
+   add_executable(minigzip test/minigzip.c)
+   target_link_libraries(minigzip zlib)
+
+   if(HAVE_OFF64_T)
+       add_executable(example64 test/example.c)
+       target_link_libraries(example64 zlib)
+       set_target_properties(example64 PROPERTIES COMPILE_FLAGS "-D_FILE_OFFSET_BITS=64")
+       add_test(example64 example64)
+
+       add_executable(minigzip64 test/minigzip.c)
+       target_link_libraries(minigzip64 zlib)
+       set_target_properties(minigzip64 PROPERTIES COMPILE_FLAGS "-D_FILE_OFFSET_BITS=64")
+   endif()
 endif()

源代码：https://github.com/google/or-tools/tree/master/cmake/external
ref: ExternalProject 技巧https://crascit.com/2015/07/25/cmake-gtest/

ZLIB PR #337：https://github.com/madler/zlib/pull/337

【讨论】：

  • 嗨！感谢您的回答，但我试图避免自己编译 zlib，zlib 开发团队似乎不鼓励这样做。您提供的链接将有助于我清理 cmake 文件时的一些想法！谢谢！
【解决方案2】：

我最终找到了解决办法。

CMake 不知道在哪里可以找到 zlib，即使它位于当前工作目录中。幸运的是，MinGW 作为其二进制文件的一部分附带了它，它可以被指向和使用。

set(ZLIB_INCLUDE_DIR "C:/MinGW/bin")
find_package(ZLIB REQUIRED)
if (ZLIB_FOUND)
    include_directories(${ZLIB_INCLUDE_DIRS})
endif()

target_link_libraries(CMinecraft ${ZLIB_LIBRARIES})

【讨论】：

  • 您是否尝试（不知道它是否有效）使用set ZLIB_INCLUDE_DIR="C:\MinGW\bin" 或设置路径以获得便携式CMake？ （即不是每个人都安装了 MinGW ......并且在这个位置......）
猜你喜欢
  • 1970-01-01
  • 2021-11-15
  • 2011-04-15
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 2017-05-03
相关资源
最近更新 更多
热门标签
Java Python linux javascript Mysql C# Docker 算法 前端 SpringBoot Redis Vue spring 设计模式 .net core .net kubernetes c++ 数据库 数据结构 大数据 js 机器学习 微服务 Android Go 程序员 面试 JVM ASP.net core 云原生 人工智能 后端 PHP git CSS golang k8s Nginx Django mybatis 深度学习 多线程 React 架构 devops 爬虫 云计算 Spring Boot LeetCode