如何从多个电子表格的末尾获取数据[关闭]答案

【问题标题】：How to take data from the end of multiple spreadsheets [closed]如何从多个电子表格的末尾获取数据[关闭]
【发布时间】：2021-11-26 10:56:33
【问题描述】：

我对 VBA 很陌生。我确实有一个任务，我有 36 个单独的 Excel 文档，每天更新，我想从所有这些文档中获取数据并将其粘贴到不同电子表格上的 4 个合并文件中。

机制应该是：

打开合并文件 (CF) >
打开单个 Excel 文件 (IF) >
从第 2 行（无标题）循环到数据末尾并复制此选择 (IF) >
将其粘贴到该选择 (CF) 末尾指定工作表中的 CF 中并保存。

尝试了一些东西，但我无法让它工作，而且代码很多（打开 36 个文件等）

【问题讨论】：

欢迎来到 Stack Overflow。请注意，由于这不是免费的代码编写服务，因此您有必要展示到目前为止您尝试过的内容以及遇到的问题或错误（通过展示您的代码），或者至少展示您的研究内容和您所做的努力制成。否则，它只是要求我们为您完成所有工作（No attempt was made）。阅读How to Ask 可能会帮助您改进您的问题。

标签： excel vba automation

【解决方案1】：

请使用 IMPORTRANGE 功能导入数据。

IMPORTRANGE("https://docs.google.com/spreadsheets/d/abcd123abcd123", "sheet1!A1:C10")

【讨论】：

ImportRange 是 Google 表格功能，在 Excel 中不可用。 See this 用于 Excel 替代方案。

【解决方案2】：

这是一个很大的问题，当你想要很多，而你真的不知道很多时。让我们一步一步地做到这一点。试试下面的代码。让它发挥作用，然后再回来提出更具体的问题。

Sub Basic_Example_1()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, Fnum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    'Fill in the path\folder where the files are
    MyPath = "C:\Users\Ron\test"

    'Add a slash at the end if the user forget it
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    'If there are no Excel files in the folder exit the sub
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    'Fill the array(myFiles)with the list of Excel files in the folder
    Fnum = 0
    Do While FilesInPath <> ""
        Fnum = Fnum + 1
        ReDim Preserve MyFiles(1 To Fnum)
        MyFiles(Fnum) = FilesInPath
        FilesInPath = Dir()
    Loop

    'Change ScreenUpdating, Calculation and EnableEvents
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'Add a new workbook with one sheet
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    'Loop through all files in the array(myFiles)
    If Fnum > 0 Then
        For Fnum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next

                With mybook.Worksheets(1)
                    Set sourceRange = .Range("A1:C1")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    'if SourceRange use all columns then skip this file
                    If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= BaseWks.Rows.Count Then
                        MsgBox "Sorry there are not enough rows in the sheet"
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        'Copy the file name in column A
                        With sourceRange
                            BaseWks.cells(rnum, "A"). _
                                    Resize(.Rows.Count).Value = MyFiles(Fnum)
                        End With

                        'Set the destrange
                        Set destrange = BaseWks.Range("B" & rnum)

                        'we copy the values from the sourceRange to the destrange
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next Fnum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

来源：

https://www.rondebruin.nl/win/s3/win008.htm

【讨论】：