Excel根据下拉菜单跳转到特定列/单元格[关闭]

Question

我在疗养院做志愿者，为护理人员创建简单的解决方案，以更好地帮助他们的居民。我正在开发一个交互式 Excel 日历，但我需要一个我一直在 Internet 上搜索但没有成功的功能。

我需要一个针对我的 excel 的解决方案（VBA，我猜测是基于类似的问题），它允许用户从包含大量日期的下拉列表中选择一个日历日期，然后用户将跳转到特定的单元格该日期在另一个范围内。

我的日期范围在一行中：F9:UA9，我的下拉菜单在 B11 中。

我希望通过在下拉列表中选择“20/09/2020”，用户将移动到该日期首次出现的 F9:UA9 范围内的单元格。

这是一些示例数据。 [1]：https://i.stack.imgur.com/l4GjH.png

提前致谢！

Answer 1

您链接到的问题具有您需要的基本外壳。您可以使用Application.Match 查找日期的第一个实例，然后使用Application.Goto 滚动到它。

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim dropDownRange As Range
    Set dropDownRange = Me.Range("B11")

    '// Check if the change is happening in your dropdown cell
    If Not Intersect(Target, dropDownRange) Is Nothing Then
        Dim lookInRange As Range
        Set lookInRange = Me.Range("F9:UA9")

        Dim matchResult As Variant
        matchResult = Application.Match(CLng(dropDownRange.Value), lookInRange, 0)

        '// First check that the corresponding date was found
        If Not IsError(matchResult) Then
            Application.Goto lookInRange.Cells(matchResult), Scroll:=True
        End If
    End If
End Sub

在工作表代码模块中添加此代码：

如果您想滚动到第 1 行，可能如下：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim dropDownRange As Range
    Set dropDownRange = Me.Range("B11")

    '// Check if the change is happening in your dropdown cell
    If Not Intersect(Target, dropDownRange) Is Nothing Then
        Dim lookInRange As Range
        Set lookInRange = Me.Range("F9:UA9")

        Dim matchResult As Variant
        matchResult = Application.Match(CLng(dropDownRange.Value), lookInRange, 0)

        '// First check that the corresponding date was found
        If Not IsError(matchResult) Then
            Dim matchRange As Range
            Set matchRange = lookInRange.Cells(matchResult)

            Application.Goto  Me.Cells(1, matchRange.Column), Scroll:=True
        End If
    End If
End Sub