如何使用 Delphi 测试目录是否可写？

Question

目前我使用这个函数，基于JCL代码，效果很好：

function IsDirectoryWriteable(const AName: string): Boolean;
var
  FileName: PWideChar;
  H: THandle;
begin
  FileName := PWideChar(IncludeTrailingPathDelimiter(AName) + 'chk.tmp');

  H := CreateFile(FileName, GENERIC_READ or GENERIC_WRITE, 0, nil,
    CREATE_NEW, FILE_ATTRIBUTE_TEMPORARY or FILE_FLAG_DELETE_ON_CLOSE, 0);

  Result := H <> INVALID_HANDLE_VALUE;

  DeleteFile(FileName);
end;

这些标志有什么可以改进的吗？ 可以在不实际创建文件的情况下完成测试吗？ 或者这个功能是否已经在 RTL 或 Jedi 库中可用？

Answer 1

安德烈亚斯...

使用安全 API 获取文件/目录的有效权限是 PIA 的一团糟，而且不可靠。 （我为此倾倒了所有代码，而只是检查是否可以在目录中写入文件。）

参考，http://www.ureader.com/msg/16591730.aspx

（我有其他参考资料，但我是新用户，只能发布一个链接。只需按照上面链接中给出的网址进行操作即可。）

Answer 2

实际上写入目录是确定目录是否可写的最简单方法。有太多的安全选项可供单独检查，即便如此，您也可能会遗漏一些东西。

您还需要在调用DeleteFile() 之前关闭打开的句柄。由于您使用的是FILE_FLAG_DELETE_ON_CLOSE 标志，因此您无论如何都不需要调用它。

顺便说一句，您的代码中有一个小错误。您正在创建一个临时的String 并将其分配给PWideChar，但String 在实际使用PWideChar 之前超出范围，释放了内存。您的FileName 变量应该是String 而不是PWideChar。在调用 CreateFile() 时进行类型转换，而不是之前。

试试这个：

function IsDirectoryWriteable(const AName: string): Boolean; 
var 
  FileName: String; 
  H: THandle; 
begin 
  FileName := IncludeTrailingPathDelimiter(AName) + 'chk.tmp'; 
  H := CreateFile(PChar(FileName), GENERIC_READ or GENERIC_WRITE, 0, nil, 
    CREATE_NEW, FILE_ATTRIBUTE_TEMPORARY or FILE_FLAG_DELETE_ON_CLOSE, 0); 
  Result := H <> INVALID_HANDLE_VALUE; 
  if Result then CloseHandle(H);
end;

Answer 3

当然，您需要做的就是验证您对目录的访问权限。这有什么问题：

function IsDirectoryWriteable(aName : String);
var
  FileObject : TJwSecureFileObject;
  DesiredAccess: ACCESS_MASK;
begin
  DesiredAccess := FILE_GENERIC_WRITE;
  FileObject := TJwSecureFileObject.Create(aName);
  try
    result := FileObject.AccessCheck(DesiredAccess);
  finally
    FileObject.Free;
  end;
end;

Answer 4

这是我使用GetTempFileName 的版本，它将尝试在目标目录中创建一个唯一临时文件：

function IsDirecoryWriteable(const AName: string): Boolean;
var
  TempFileName: array[0..MAX_PATH] of Char;
begin
  { attempt to create a temp file in the directory }
  Result := GetTempFileName(PChar(AName), '$', 0, TempFileName) <> 0;
  if Result then
    { clean up }
    Result := DeleteFile(TempFileName);
end;