根据多个条件查找重复的 excel 值答案

【问题标题】：Find duplicate excel value based on multiple criteria根据多个条件查找重复的 excel 值
【发布时间】：2020-02-13 05:35:26
【问题描述】：

我有一个包含 4 列的电子表格（例如，请参见下文）。第一列有一个唯一的 ID，接下来的三列是请求日期、客户名称和国家/地区。我想弄清楚当其他三列相同时如何匹配 ID。

当前数据集：

ID | Date Requested | Customer name | Country
1      1/1/2019         Bob Smith      USA
2      2/2/2019         Sal Jones      DE
3      1/1/2019         Bob Smith      USA
4      12/2/2017        Jim Gold       USA
5      2/2/2019         Sal Jones      DE

我希望能够创建另一列来显示具有相同信息的行的 ID。例如，新表如下所示：

ID | Date Requested | Customer name | Country | Duplicate ID
1      1/1/2019         Bob Smith      USA         3
2      2/2/2019         Sal Jones      DE          5
3      1/1/2019         Bob Smith      USA         1
4      12/2/2017        Jim Gold       USA
5      2/2/2019         Sal Jones      DE          2

有没有办法为新列或 excel 中的某些其他功能使用 VLookUp？

编辑：最终目标是能够通过一个共同的“组”或 ID 号将两者实际链接在一起。例如，表格最终会是这样的：

ID | Date Requested | Customer name | Country | Duplicate ID | Group
1      1/1/2019         Bob Smith      USA         3            1
2      2/2/2019         Sal Jones      DE          5            2
3      1/1/2019         Bob Smith      USA         1            1
4      12/2/2017        Jim Gold       USA
5      2/2/2019         Sal Jones      DE          2            2

这样，您可以过滤组列，两个重复条目将彼此相邻/在同一列中具有公共链接。

【问题讨论】：

可以有多个重复，还是总是只有一个？您的 ID 是纯数字还是字母数字？
您有下一步吗？或者这是最终的结果？如果您尝试做的不仅仅是审核条目，那么可能有更好的方法来获得您最终想要的结果。
是否总是只有一个副本或者可能不止一个副本？找到重复条目的ID后，您的最终目标是什么？删除它们？
总是只有一个重复或没有重复

标签： excel excel-formula vlookup

【解决方案1】：

这是一个选项：

E2中的公式：

=IFERROR(MATCH(1,INDEX(($B$2:INDEX(B:B,COUNTA(B:B))=B2)*($C$2:INDEX(C:C,COUNTA(C:C))=C2)*(($D$2:INDEX(D:D,COUNTA(D:D))=D2))*(ROW($A$2:INDEX(A:A,COUNTA(A:A)))<>ROW()),),0),"")

如果您的 ID 与 MATCH 不匹配 =).... 您将需要实现另一个 INDEX：

=IFERROR(INDEX($A$2:INDEX(A:A,COUNTA(A:A)),MATCH(1,INDEX(($B$2:INDEX(B:B,COUNTA(B:B))=B2)*($C$2:INDEX(C:C,COUNTA(C:C))=C2)*(($D$2:INDEX(D:D,COUNTA(D:D))=D2))*(ROW($A$2:INDEX(A:A,COUNTA(A:A)))<>ROW()),),0)),"")

它有点广泛，但我想让它动态化，以避免使用整列引用，从而加快你的公式。 速度 > 长度

虽然它是一个数组公式，但不要担心这样输入。 MATCH 函数后面的INDEX 将结果捕获到一个数组中。

【讨论】：