根据日期阈值对重复项的最大值求和

Question

我有以下几列数据：

 Unique ID | Value | Date
     1     |   20  | 15/10/2018
     2     |   30  | 15/10/2018
     1     |   40  | 16/10/2018
     2     |   50  | 16/10/2018

然后我需要编写一个公式来根据日期阈值对 Value 列求和，但我只想包括每个唯一 ID 的最大值。

Date Threshold | Sum Formula
16/10/2018     | =SUMIF(C:C,"<="&F2,B:B)

显然，上述公式将对所有值求和 (140)。我只需要对每个唯一 ID (40+50=90) 小于或等于阈值日期的单个 MAX 值求和。

Answer 1

任何单个工作表公式都需要多级循环计算，这会使公式过于复杂，从而导致所需的计算时间。一个或多个“帮助”列可以大大减少这种情况。

把这个放在D2里，然后填写。

=IF(COUNTIF(A$2:A2, A2)=1, AGGREGATE(14, 7, B:B/((C$1:C$9<=F$2)*(A$1:A$9=A2)), 1), "")

您要查找的最大过滤值的总和只是 D 列的总和（例如 =sum(D:D)）。

_{请注意，我已将您的原始样本数据添加到更清楚地证明其他标准。}

可以简化和限制所需步骤的用户定义函数可能是您的最佳选择。

使用 Alt+F11 打开 VBE，使用 Alt+I、M 插入模块代码表并将此代码粘贴到新打开的代码窗格中。像使用任何其他标准工作表函数一样使用新的自定义函数。

Option Explicit

Function maxUniqueWithThreshold(ids As Range, vals As Range, _
                                dates As Range, thold As Long)
    Static d As Object, i As Long

    'create a dictionary for unique ids only if not previously created
    If d Is Nothing Then Set d = CreateObject("scripting.dictionary")
    d.RemoveAll

    'limit the processing ranges
    Set ids = Intersect(ids, ids.Parent.UsedRange)
    Set vals = vals.Resize(ids.Rows.Count, ids.Columns.Count)
    Set dates = dates.Resize(ids.Rows.Count, ids.Columns.Count)

    'cycle through the processing ranges
    For i = 1 To ids.Cells.Count
        'is date within threshold?
        If dates.Cells(i) <= thold Then
            'collect the maximum value for each unique id into dictionary Items
            d.Item(ids.Cells(i).Value2) = _
              Application.Max(d.Item(ids.Cells(i).Value2), vals.Cells(i).Value2)
        End If
    Next i

    maxUniqueWithThreshold = Application.Sum(d.items)

End Function

请注意，在 G2 中的工作表上使用 UDF，就像任何其他标准工作表函数一样。

Answer 2

第 1 步）生成唯一的 ID 列表

创建唯一 ID 列表。有一些公式可以为您执行此操作，或者您可以输入它们。假设您的示例在 F2:F3 中编写 ID

步骤 2) 截止日期

将您的截止日期放在一个单元格中，比如说 E2。

第 3 步）找到最大值

我相信 2016 年会有一个 MAXIF 函数。使用它来根据唯一 ID 和

=AGGREGATE(14,6,$B$2:$B$5/(($A$2:$A$5=$F2)*($C$2:$C$5<=$E$2)),1)

将该公式放在 G2 中，然后在每个唯一 ID 旁边复制。然后它将提供该日期在截止日期之前或等于截止日期的最大值。

第 4 步）对最大值求和

在未使用的列中对上一个公式的结果求和

=SUM(G2:G3)

这假设您的第一个表是 A:C 列。它还假设您的日期采用 excel 序列日期格式，而不是伪装成 excel 日期的字符串。您可以使用 =ISNUMBER(A1) 测试后者，其中 A1 是带有日期的单元格。 false 值表示它是一个字符串，需要转换。调整范围以适合您的数据。