带和函数的索引匹配答案

【问题标题】：Index-Match with Sum-Function带和函数的索引匹配
【发布时间】：2021-02-20 21:55:50
【问题描述】：

我有两个标签 Product-Overview 和 Prices。

在Prices-选项卡上，我想添加我的数据并在财务选项卡上获得概览。

我尝试使用index-match，但是如果我的Prices-tab 中同一个月有多个值，我不知道如何总结？

我想得到以下结果：

在下面找到我作为谷歌表的最小可行示例：

Google Sheet

有什么建议吗？

【问题讨论】：

标签： google-sheets google-sheets-formula vlookup array-formulas google-query-language

【解决方案1】：

删除 D 列并在 D2 中使用它：

=ARRAYFORMULA(IF(A2:A="";;TEXT(B2:B; "mm/yy")))

那么你可以这样做：

=QUERY(Prices!A2:D; "select A,sum(C) where A is not null group by A pivot D")

在 O5 中更高级：

=ARRAYFORMULA(IF(O1:1="";;IF(B5:B="";;
 IFNA(VLOOKUP(B5:B; QUERY(Prices!A2:D; 
 "select A,sum(C) where A is not null group by A pivot D"); 
 MATCH(TO_TEXT(O1:T1); QUERY(QUERY(Prices!A2:D; 
 "select sum(C) where A is not null group by A pivot D"); 
 "limit 0"; 1); 0)+1; 0))*1)))

当然B5可以是：

=SORT(UNIQUE(Prices!A2:A))

那么 D5 可以是：

=ARRAYFORMULA(IF(B5:B="";;"Product "&REGEXEXTRACT(TO_TEXT(B5:B); ".(\d+)")))

平均 N5 可以这样完成：

=ARRAYFORMULA(QUERY(TRANSPOSE(QUERY(TRANSPOSE(O5:100);
 "select "&TEXTJOIN(","; 1; IF(B5:B="";; 
 "avg(Col"&ROW(O5:O)-ROW(O5)+1&")"))&""));
 "select Col2"))

在 O1 中生成日期，例如：

=ARRAYFORMULA(ARRAY_CONSTRAIN(TRANSPOSE(UNIQUE(TEXT(ROW(INDIRECT(
 DATEVALUE("1/11/2020")&":"&
 DATEVALUE("1/11/2050"))); "mm/yy"))); 1; COLUMNS(O1:1)-1))

在 O2 中的年限如下：

=ARRAYFORMULA(IFNA(20&REGEXEXTRACT(O1:1; "/(\d+)")))

【讨论】：

【解决方案2】：

您正在寻找的是sumifs 公式：

这将解决您的问题，它不是数组公式，但如果您将其拖动到您希望它们去的单元格，它就可以工作。

=sumifs(
  Prices!$C$2:$C;
  Prices!$A$2:$A;$B5;
  Prices!$D$2:$D;">="&if(isblank(N$1);date(year(O$1);month(O$1)-1;day(O$1));N$1);
  Prices!$D$2:$D;"<="&if(isblank(O$1);date(year(N$1);month(N$1)+1;day(N$1));O$1)
)

【讨论】：