按每 N 个分隔符拆分文本并转置 Google 表格

Question

我需要从一段文本中提取文本。该块如下所示：

{"some text"},{"some more text"},{"some other"},{"some other text"},{"let's add more"},{"even more other text"}

文本应该成对出现，以便第一个和第二个 {""},{""} 进入同一个单元格，依此类推。我尝试了拆分功能，但由于分隔符是逗号，我无法成对拆分。所以我需要在每 2 个逗号后拆分，并将结果对放在它自己的单元格中。然后转置结果，使文本垂直进入一列。

我尝试了=SPLIT("",",")，但没有得到想要的输出。

我为此使用 Google 表格并希望在 Google 表格中执行此操作，但我愿意在 Excel 中执行此操作。

如果您想查看 Google 表格文件，这里是链接 https://docs.google.com/spreadsheets/d/1sbK6nF-6SO4oOKTdercgnfHGeQol-vfV5SRcFXNBy5o/edit?usp=sharing

Answer 1

有趣的查询。

在B2，看看下面的公式是否适合你：

=TRANSPOSE(SPLIT(REGEXREPLACE(A2,"([^,]+,[^,]+),","$1|"),"|"))

如果需要，可以使正则表达式更具体地仅针对大括号之间的逗号。

---

编辑

到SPLIT你想要的结果分成两列和去掉我想出的大括号和外引号：

=TRANSPOSE({SPLIT(REGEXREPLACE(A2,"{""([^,]+)""},{""([^,]+)""}(?:,|$)","$1|"),"|");SPLIT(REGEXREPLACE(A2,"{""([^,]+)""},{""([^,]+)""}(?:,|$)","$2|"),"|")})

Answer 2

要调整ARRAYFORMULA 的解决方案，我们只需用逗号连接所有字符串。

关于以下解决方案的几点说明：

使用REGEXREPLACE，我们剥离了所有周围的{"..."}。同时，我们用"♠" 替换每个偶数逗号（不仅仅是每个逗号，而是记录之间的逗号，例如字符串中的逗号不会受到影响），以便稍后将对拆分为单独的字符串，并且我们将每个奇数逗号替换为替换为 "♥" 以便稍后将一对拆分为两个字符串。

=ARRAYFORMULA(
  SPLIT(
    TRANSPOSE(
      SPLIT(
        REGEXREPLACE(
          TEXTJOIN(
            ",",
            True,
            A2:A
          ),
          "\{""(.*?)""\},\{""(.*?)""\},?",
          "$1♥$2♠"
        ),
        "♠"
      )
    ),
    "♥"
  )
)