正确使用 Fortran 流写入和读取整数数组答案

【问题标题】：Using Fortran stream correctly to write and read an array of integers正确使用 Fortran 流写入和读取整数数组
【发布时间】：2011-10-18 12:48:12
【问题描述】：

这与我最近关于 Fortran 流等的帖子有些相关：Converting data stored in Fortran 90 binaries to human readable format。

我正在尝试将一个简单的整数数组写入文件，然后使用 Fortran 的 READ 函数读取我创建的二进制文件。我通过在我的OPEN 指令中包含ACCESS="STREAM" 来使用流。我有以下代码：

MODULE streamtest2subs

  IMPLICIT NONE

CONTAINS

SUBROUTINE writeUstream(myarray)
  IMPLICIT NONE
  INTEGER, INTENT(IN), DIMENSION(4,10) :: myarray
  INTEGER :: myvalue = 12345, mypos
  OPEN(UNIT=11, FILE="ustream.demo", STATUS="REPLACE", ACCESS="STREAM")
  WRITE(11) myarray
  CLOSE(UNIT=11)
END SUBROUTINE writeUstream

SUBROUTINE readUstream
  IMPLICIT NONE
  INTEGER :: test1, test2, test3
  INTEGER :: n
  OPEN(UNIT=42, FILE="ustream.demo", STATUS="OLD", ACCESS="STREAM")
  READ(42, POS=1) test1
  READ(42, POS=2) test2
  READ(42, POS=3) test3

  WRITE(*,*) "This is the output:"
  WRITE(*,*) test1
  WRITE(*,*) test2
  WRITE(*,*) test3
END SUBROUTINE readUstream

END MODULE streamtest2subs

PROGRAM streamtest2
  USE streamtest2subs
  IMPLICIT NONE
  INTEGER :: i, j, k
  INTEGER, DIMENSION(4,10) :: a

  WRITE(*,*) "This is my input array:"
  k=1
  DO i=1,4
    DO j=1,10
      a(i,j)=k
      WRITE(*, "(i3)", ADVANCE="NO") a(i,j)
      k=k+1
    END DO
    WRITE(*,*)
  END DO
  WRITE(*,*)

  CALL writeUstream(a)
  CALL readUstream
END PROGRAM streamtest2

但是，当我使用 gfortran 编译并运行它时，我得到以下输出：

 This is my input array:
  1  2  3  4  5  6  7  8  9 10
 11 12 13 14 15 16 17 18 19 20
 21 22 23 24 25 26 27 28 29 30
 31 32 33 34 35 36 37 38 39 40

 This is the output:
           1
   184549376
      720896

为什么输出如此复杂？ READ 是否将 ustream.demo 文件作为字符串而不是整数读取？但是，当我将 test1、test2 和 test3 的类型更改为字符串时，我的输出只是一系列三个空行。

我是否在READ 中错误地使用了POS 指令？我认为POS 指定了输出中的字符号（尽管我不确定数组的元素是否以任何方式分隔）；这是正确的吗？

非常感谢您的宝贵时间！

【问题讨论】：

标签： arrays stream fortran

【解决方案1】：

出于您在上一个问题中描述的目的，我认为您的编程比必要的复杂。假设您想要一个没有额外记录结构的二进制文件，您想要未格式化和流式传输。您可以以与编写文件相同的方式阅读文件——不需要使用 POS——除非目的是学习如何使用 POS。

我的测试示例基于一个 Fortran 程序，在该程序中我读取了一个由其他人编写的二进制文件，几乎可以肯定是使用 C 程序编写的。该文件由标题组成，后跟可变长度的数组。我打开文件：

open ( unit=75, file=FileName, status='old', access='stream', form='unformatted', action='read' )

我读取了一个标头（一个包含许多子变量的用户定义类型的变量）：

read (75) header

我将数组分配给读取到标题的一个字段的长度，然后我读取数组：

allocate ( array (1:header % ArrayLen) )
read (75) array

然后我处理数组中的数据。然后我重复直到文件结束（代码示例中没有显示）。

非常简单...无需计算文件中的位置，使用READ的POS关键字。

【讨论】：

【解决方案2】：

问题在于您的读取语句，POS 是距文件开头的字节偏移量，与写入文件的原始 a 数组的数组索引没有直接关系。

因此，在您的代码中，如果test1 是一个 4 字节整数，Fortran 读取将通过读取文件的字节 1 到 4 来构造它。同样，test2 将从字节 2 到 5 构造，而值实际上存储在字节 5 到 8 中。

当我将读取行更改为，

READ(42, POS=1) test1
READ(42, POS=5) test2
READ(42, POS=9) test3

输出变成，

This is my input array:
1  2  3  4  5  6  7  8  9 10
11 12 13 14 15 16 17 18 19 20
21 22 23 24 25 26 27 28 29 30
31 32 33 34 35 36 37 38 39 40

This is the output:
       1
      11
      21

我认为这更像是你所追求的。请注意，如果这些值最初以 2 字节或 8 字节整数的形式写入文件，那么您在读取文件时必须在 POS 偏移量中考虑这些大小。

顺便说一句，值得学习命令行工具od 以快速查询二进制文件。例如，我做的第一件事是检查写入是否正常使用，

$ od -t d4 ustream.demo 
0000000                 1              11              21              31
0000020                 2              12              22              32
0000040                 3              13              23              33
0000060                 4              14              24              34
0000100                 5              15              25              35
0000120                 6              16              26              36
0000140                 7              17              27              37
0000160                 8              18              28              38
0000200                 9              19              29              39
0000220                10              20              30              40
0000240

【讨论】：