【问题标题】:Delphi 2007 - Systemwide Hot key is NOT "system-wide" if setting "MainFormOnTaskBar := True"Delphi 2007 - 如果设置“MainFormOnTaskBar := True”,则系统范围的热键不是“系统范围的”
【发布时间】:2012-04-30 11:52:50
【问题描述】:

我有一个 Delphi 2007 项目,多年来在 Windows XP、Vista 和“7”上运行良好。它是 Delphi 5 的升级版,因此默认情况下“MainFormOnTaskBar”为“false”(我从未在 DPR 中更改过它)。在这种情况下,系统范围的热键在主窗体的 OnCreate 事件处理程序中使用以下代码在“系统范围内”工作。

HotKey_xyz := GlobalAddAtom('Hotkey_xyz');
if NOT RegisterHotKey(Self.Handle, HotKey_xyz, MOD_CONTROL, VK_F12) then
    ShowMessage('Unable to register Control-F12 as system-wide hot key') ;

(I have GlobalDeleteAtom() and UnregisterHotKey() in Form.OnDestroy as expected.)

现在,我需要一个表单来在任务栏上显示自己的按钮,所以我在 DPR 中设置了“Application.MainFormOnTaskBar := True”。这按预期工作。但是,这具有 Control-F12 在系统范围内不起作用的副作用,它仅在我的应用程序具有焦点时才起作用(因此,它不再是“系统范围的”。)

我在网上广泛搜索了很多关于“MainFormOnTaskBar”如何/为什么影响某些子表单/模态表单行为的文章。但是,我没有发现它对我上面描述的“系统范围的热键”问题的影响。我已经测试并重新测试了我的应用程序,并将 MainFormOnTaskBar 设置为 true 和 false,而其他所有内容都保持不变。我可以肯定地验证上述系统范围热键的问题与 MainFormOnTaskBar 标志有关。

我将非常感谢有关解决方法的任何指导。我确实需要两者 - 一个系统范围的热键和一个在任务栏上有自己的按钮的表单。

非常感谢。

【问题讨论】:

  • 你能用 new 项目复制它吗?我不能..
  • 我也无法重现这个。您可以发布更多代码吗? (同时可能尝试在RegisterHotkey 调用中将Self.Handle 更改为Application.Handle?WM_HOTKEY 消息仍将到达您的表单,因为应用程序的消息处理程序不对其进行任何处理;它将是像往常一样发送到您的表格。)
  • @KenWhite:如果Application.Handle 用于注册热键,那么WM_HOTKEY 消息将不会直接或间接地定向到TForm。它们将被定向到 TApplication,因此要捕获这些消息,您必须使用 TApplication.OnMessage 事件和/或 TApplication.HookMainWindow() 方法。
  • @Remy,这不是真的。消息发送到TApplication.WndProc,它没有任何处理。然后将其分派到其他窗口。 (我可以肯定地确认这一点,因为我有一个组件使用此方法将WM_HOTKEY 消息路由到通过Application.Handle 放置的任何形式。)不过,您的答案(AllocHWnd)看起来不错。
  • 为可能遇到相同问题的其他人添加以下评论。感谢这个社区,我的问题得到了解决。以下是我对为什么遇到此问题的最佳猜测。我多年来一直使用相同的代码,没有任何问题。可能是,设置“MainFormOnTaskBar := True”会导致 Main Form 的句柄在调用 Form.OnCreate() 之后的某个时间点被销毁和重新创建。显然,直到我更改了 DPR 中的代码,这才发生。再次感谢所有回复我信息的人。

标签: delphi delphi-2007


【解决方案1】:

TApplication.MainFormOnTaskbar 对系统范围的热键完全没有影响。我可以肯定地证实这一点。无论MainFormOnTaskbar 设置为什么,无论应用程序是否聚焦等,我都能接收WM_HOTKEY 消息。因此,无论您看到什么,都不是您认为正在发生的事情。

很可能,表单的Handle 只是在您调用RegisterHotKey() 后在您背后重新创建,因此您丢失了将接收WM_HOTKEY 消息的HWND。而不是使用OnCreate 事件,您应该覆盖表单的CreateWindowHandle() 和DestroyWindowHandle() 方法,以确保始终为表单的当前HWND 注册热键,无论发生什么事情(您应该始终这样做每当您将任何类型的数据绑定到表单的Handle),例如:

type
  TForm1 = class(TForm)
  private
    HotKey_xyz: WORD;
    procedure WMHotKey(var Message: TMessage); message WM_HOTKEY;
  protected
    procedure CreateWindowHandle(const Params: TCreateParams); override;
    procedure DestroyWindowHandle; override;
  end;

procedure TForm1.CreateWindowHandle(const Params: TCreateParams);
begin
  inherited;
  HotKey_xyz := GlobalAddAtom('Hotkey_xyz'); 
  if HotKey_xyz <> 0 then
    RegisterHotKey(Self.Handle, HotKey_xyz, MOD_CONTROL, VK_F12);
end;

procedure TForm1.DestroyWindowHandle(const Params: TCreateParams);
begin
  if HotKey_xyz <> 0 then
  begin
    UnregisterHotKey(Self.Handle, HotKey_xyz);
    GlobalDeleteAtom(HotKey_xyz);
    HotKey_xyz := 0;
  end;
  inherited;
end;

procedure TForm1.WMHotKey(var Message: TMessage);
begin
  ...
end;

更好的选择是使用AllocateHWnd() 分配一个单独的专用HWND 仅用于处理热键消息(然后您可以再次使用OnCreate 和OnDestroy 事件),例如:

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    HotKey_xyz: WORD;
    HotKeyWnd: HWND;
    procedure HotKeyWndProc(var Message: TMessage);
  end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  HotKeyWnd := AllocateHwnd(HotKeyWndProc);
  HotKey_xyz := GlobalAddAtom('Hotkey_xyz'); 
  if HotKey_xyz <> 0 then
    RegisterHotKey(HotKeyWnd, HotKey_xyz, MOD_CONTROL, VK_F12);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if HotKey_xyz <> 0 then
  begin
    UnregisterHotKey(HotKeyWnd, HotKey_xyz);
    GlobalDeleteAtom(HotKey_xyz);
    HotKey_xyz := 0;
  end;
  if HotKeyWnd <> 0 then
  begin
    DeallocateHWnd(HotKeyWnd);
    HotKeyWnd := 0;
  end;
end;

procedure TForm1.HotKeyWndProc(var Message: TMessage);
begin
  if Message.Msg = WM_HOTKEY then
  begin
    ...
  end else
    Message.Result := DefWindowProc(HotKeyWnd, Message.Msg, Message.WParam, Message.LParam);
end;

【讨论】:

  • +1 仅用于 AllocHWnd 代码示例。很好 - 我以前从未见过这样的做法。我将对此进行标记以供将来参考。
  • @Remy: 非常感谢: CreateWindowHandle() 和 DestroyWindowHandle() 方法 - 成功了。所以,不能感谢你。我将探索“AllocateWnd()”——我需要更多的教育!我想为你的答案投票,但 Stack Overflow 说我没有足够的“声誉”来这样做。
  • @All:感谢所有评论并花时间测试我的论点 MainFormOnTaskBar 标志是罪魁祸首的人 - 我受过教育,事实并非如此。再次,我非常感谢这个社区的支持和提供帮助的意愿。
猜你喜欢
  • 1970-01-01
  • 2012-05-30
  • 2011-04-15
  • 2012-04-30
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 2013-11-03
相关资源
最近更新 更多