Applescript 更改剪贴板上的文本

Question

我编写了一个 AppleScript 来自动化我的工作设置，只需要最后的润色。我在脚本中将某些内容复制到剪贴板；我需要编辑我复制的文本以仅保留最后一行（最好不要打开实际的文本编辑器应用程序，因为这会使我的工作区变得混乱），然后将该行粘贴到 Google Chrome 浏览器中。

---

到目前为止，在我的脚本的最后一步中，我做了一些导致消息文本输出到终端的操作。然后我将终端中可见的文本复制到剪贴板，如下所示：

tell application "Terminal"
    tell front window
        set the clipboard to contents of selected tab as text
    end tell
end tell

现在我可以粘贴它，类似于

...
[I 15:03:31.259 LabApp] Serving notebooks from local directory: /workspace
[I 15:03:31.259 LabApp] The Jupyter Notebook is running at:
[I 15:03:31.259 LabApp] http://1fw5c518af9:1932/?token=5e6d97b348fsy734gd
[I 15:03:31.259 LabApp]   or http://88.0.0.1:1932/?token=5e6d97b348fsy734gd
[I 23:56:47.798 LabApp] Use Control-C to stop this server and shut down all kernels (twice to skip confirmation).
[C 23:56:47.803 LabApp] 
    
    To access the notebook, open this file in a browser:
        file:///root/.local/share/jupyter/runtime-open.html
    Or copy and paste one of these URLs:
        http://1fw5c518af9:1932/?token=5e6d97b348fsy734gd
     or http://88.0.0.1:1932/?token=5e6d97b348fsy734gd

这总是以or *URL* 格式的文本结尾，例如在上面的示例中，它将是or http://88.0.0.1:1932/?token=5e6d97b348fsy734gd。这与上面的行由行分隔符和“或”之前的一些尾随空格分隔。

我需要做的是获取该 URL，启动 Google Chrome 浏览器并将其粘贴到那里。

打开谷歌浏览器应该很简单，下面的代码（来自这个tut）带你到Instagram：

tell application "Google Chrome" to activate

tell application "System Events"
   key code 37 using command down
   delay 0.5
   keystroke "https://www.instagram.com/instagram"
   delay 1
   key code 36
   delay 1

end tell

实际上我所需要的只是将剪贴板上的内容编辑为*URL*（在上面的示例中，只是http://88.0.0.1:1932/?token=5e6d97b348fsy734gd）。之后，我可以从剪贴板（在教程中输入 Instagram）粘贴它。

---

在尝试了下面@user3439894 的可爱回答后，我发现情况有点复杂：

1. 在结尾后有不可预知的空白行“” 链接。
2. 我也想知道最后是否有空格 还有

我已经知道http://88.0.0.1 的形式（它总是这样）所以有没有办法搜索它，然后用后面的链接抓住它？ （如果能够用“ ”或换行符分隔结尾，那就太好了）

编辑 2： 如果http://88.0.0.1... 出现多次，我们希望只选择这些网址中的一个 - 它们通常可能相同，但选择最后一个 是最安全的。

Answer 1

我需要做的是获取该 URL，启动 Google Chrome 浏览器并将其粘贴到那里。

&

这总是以or *URL* 格式的文本结尾，例如在上面 例如它将是or http://88.0.0.1:1932/?token=5e6d97b348fsy734gd。这是分开的 从上面的行由行分隔符加上一些尾随空格 在“或”之前。

&

如果http://88.0.0.1... 出现多次，我们希望 只选择这些 URL 中的 一个 - 它们通常可能是 相同，但选择 last 是最安全的。

如果您尝试做的是从 所选标签 的 contents 中获取最后一个以 http://88 开头的 URL Terminal 中的 front window，那么这里有一种不使用剪贴板的方法，在 Google Chrome 中打开它，也可以这样做无需使用 UI 脚本。

换句话说，无需更改剪贴板上的文本或击键 URL，因为您只需告诉 Google Chrome 为 URL 使用什么。

示例 AppleScript 代码：

tell application "Terminal" to ¬
    set theTextFromTerminal to ¬
        the contents of ¬
            the selected tab of ¬
                the front window ¬
                    as text

set theURL to ¬
    the last paragraph of ¬
        (do shell script ¬
            "grep -o 'http://88.*$' <<< " & ¬
            theTextFromTerminal's quoted form & ¬
            "; exit 0")

if theURL is "" then return
if theURL does not start with ¬
    "http://88." then return

tell application "Google Chrome"
    activate
    delay 1
    if exists front window then
        make new tab at ¬
            end of front window ¬
            with properties {URL:theURL}
    else
        set URL of ¬
            the active tab of ¬
                (make new window) to theURL
    end if
end tell

---

_{注意：示例 AppleScript 代码 就是这样，并且没有任何包含的错误处理不包含任何适当的额外错误处理。用户有责任根据需要或需要添加任何错误处理。查看AppleScript Language Guide 中的try statement 和error statement。另请参阅Working with Errors。此外，在适当的情况下，可能需要在事件之间使用delay 命令，例如delay 0.5，延迟的值设置得当。}