使用 AppleScript 获取 NSTextFieldCell 值

Question

我正在尝试自动化一些需要在对话框中显示文本的任务（6 位代码）。

Accessibility Inspector 揭示了以下层次结构：

我是 AppleScript 领域的初学者，并且已经阅读了一些可以像这样完成类似操作的示例：

set myText to textField's stringValue() as text

但我不确定这是否适用于我的情况，因为 Accessibility Inspector 没有显示包含 6 位代码的 NSTextFieldCell 的任何变量名称。

如何提取 NSTextFieldCell 中的 6 位代码并可能返回此值以便 shell 脚本可以使用此代码？

我现在有这样的东西 -

tell application "FollowUpUI"
    activate
    # get the 6 digit code
end tell

---

更新

经过一些帮助，我尝试遍历文本字段

tell application "System Events"

    repeat with theProcess in processes

        #initialize
        tell theProcess
            set processName to name
            set allWindows to windows
        end tell

        #check if process exists
        if processName is "FollowUpUI" then

            activate

            say "FollowUpUI found"

            set windowsCount to count of the allWindows

            #only one window should exist
            if windowsCount is 1 then
                say "1 window was found"

                tell window 1
                    tell group 1
                        tell text field 1
                            set code to value
                        end tell
                    end tell
                end tell

            end if
        end if
    end repeat
end tell

但我因为错误而卡住了 -

System Events got an error: cant get window 1. Invalid index.

我不确定这是否是语法错误。任何指针都会有所帮助。谢谢

Answer 1

出现错误是因为你必须引用window 1 of process "FollowUpUI"

你的代码太复杂了，你只需要检查进程是否存在

tell application "System Events"
    if exists process "FollowUpUI" then
        tell process "FollowUpUI"
            tell window 1
                tell static text 1 of group 1
                    set code to its value
                end tell
            end tell
        end tell
    end if
end tell

如果代码是工作流的一部分，您必须等到窗口打开

tell application "System Events"
    repeat until exists window 1 of process "FollowUpUI"
        delay 0.2
    end repeat
    tell window 1 of process "FollowUpUI"
        tell static text 1 of group 1
            set code to its value
        end tell
    end tell
end tell

我在value 之前添加了its 以确保它引用当前引用（文本字段）

由于您不向窗口发送键或鼠标事件，因此您不需要activate 任何东西。

Answer 2

不是答案，但我无法在评论中粘贴代码。这是获取 UI 元素的技巧。按 Command-Shift-4 以获取带有坐标的光标。瞄准 UI 元素并记住坐标。单击以使箭头光标返回。使用此脚本中的坐标。

activate application "FollowUpUI"
tell application "System Events"
    tell application process "FollowUpUI"
        click at {290, 150}
    end tell
end tell

必须允许脚本编辑器控制计算机。您可以在系统偏好设置、安全和隐私、隐私中进行设置。