【问题标题】:regexp and sed find block of string in multiline block untill it end with space正则表达式和 sed 在多行块中查找字符串块,直到它以空格结尾
【发布时间】:2021-10-13 23:14:40
【问题描述】:

我尝试捕获这些字符串块并使用 regexp 和 sed 对它们进行注释。 每个块用空格分隔

some text here 
some text here 

AppServer1:
  name: ${AppServer1.name}
  ip: ${AppServer1.ip}
   
some text here 
some text here 

AppServer2:
  name: ${AppServer1.name}
  ip: ${AppServer1.ip}

some text here 
some text here 
   

我尝试使用这个正则表达式:

sed E '/./{H;1h;$!d} ; x ; s/[^\$AppServer1](AppServer1)/#\1/gi'

但结果是:

 #AppServer1:
      name: $#{AppServer1.name}
      ip: $#{AppServer1.ip}

我在这里缺少什么来评论完整的字符串:

#AppServer1:
#      name: ${AppServer1.name}
#      ip: ${AppServer1.ip}

【问题讨论】:

    标签: regex string sed comments multilinestring


    【解决方案1】:

    使用gnu-sed,您可以这样做:

    sed '/^AppServer1/I{:a; /^[[:blank:]]*$/!{s/.*/#&/; n; ba;} }' file
    
    some text here
    some text here
    
    #AppServer1:
    #  name: ${AppServer1.name}
    #  ip: ${AppServer1.ip}
    
    some text here
    some text here
    
    AppServer2:
      name: ${AppServer1.name}
      ip: ${AppServer1.ip}
    
    some text here
    some text here
    

    详情:

    • /^AppServer1/I:搜索AppServer1不区分大小写
    • {: 区块开始
      • :a:制作标签a
      • /^[[:blank:]]*$/!如果一行不是空行
      • {s/.*/#&/; n; ba;}:在每一行前加上#,阅读下一行并转到标签a
    • }:区块结束

    使用awk 你可以这样做:

    awk '/^AppServer1/ {b=1} b && !NF {b=0} b {$0 = "#" $0} 1' file
    
    some text here
    some text here
    
    #AppServer1:
    #  name: ${AppServer1.name}
    #  ip: ${AppServer1.ip}
    
    some text here
    some text here
    
    AppServer2:
      name: ${AppServer1.name}
      ip: ${AppServer1.ip}
    
    some text here
    some text here
    

    【讨论】:

    • 谢谢,但在我的情况下使用 awk 有点问题......
    • 我也提供了sed解决方案
    • 谢谢!如何使 AppServer1 在正则表达式中不区分大小写?
    • 你能解释一下sed expretion在做什么吗?
    • ok 检查更新的答案以获取解释和大小写忽略匹配
    【解决方案2】:

    一个更简单的sed 解决方案可能是这样,如果您也可以评论最后的空行:

    sed '/^AppServer1:/,/^[[:space:]]*$/s/^/# /' lines.txt 
    
    some text here
    some text here
    
    # AppServer1:
    #   name: ${AppServer1.name}
    #   ip: ${AppServer1.ip}
    # 
    some text here
    some text here
    
    AppServer2:
      name: ${AppServer1.name}
      ip: ${AppServer1.ip}
    
    some text here
    some text here
    

    它使用sed 范围模式,用逗号 (,) 表示。范围的开始是/^AppServer1:/,即任何以AppServer1: 开头的行(^)。范围的结尾是空行或仅包含空白字符的行:/^[[:space:]]*$/,其中^:行首; [[:space:]]*:零个或多个(*)空白字符([[:space:]]); $:行尾。

    接下来是 [s]substitution 命令 — s/^/# / — 在匹配范围内(包括结尾)的所有行中,将 ^ 行的开头替换为序列 # 。

    如果你想要一个不区分大小写的匹配,你需要 GNU sed。在这种情况下,您可以将 I 标志添加到范围开始模式。不过,此标志在 macOS sed 上不可用。

    【讨论】:

      【解决方案3】:

      假设您的输入中看起来空的行确实是空的,您可以在每个 Unix 机器上的任何 shell 中使用任何 awk 来执行此操作:

      $ awk -v RS= -v ORS='\n\n' '/^AppServer1:/{gsub(/^|\n/,"&#")} 1' file
      some text here
      some text here
      
      #AppServer1:
      #  name: ${AppServer1.name}
      #  ip: ${AppServer1.ip}
      
      some text here
      some text here
      
      AppServer2:
        name: ${AppServer1.name}
        ip: ${AppServer1.ip}
      
      some text here
      some text here
      

      【讨论】:

        猜你喜欢
        • 2021-10-14
        • 1970-01-01
        • 1970-01-01
        • 1970-01-01
        • 1970-01-01
        • 2010-12-02
        • 1970-01-01
        • 1970-01-01
        • 2021-07-04
        相关资源
        最近更新 更多