如何获取元组列表并创建包含列表的元组列表

Question

我的目标是接受如下输入：

[(8, P1), (8, P2), (10, P3)]

然后把它变成这样的东西：

[(8, [P1, P2]), (10, P3)]

假设8 和10 之类的数字是数据类型Time（包装和Int），P1 和P2 是数据类型Person（包装String）。这是我到目前为止所做的：

groupTogether :: [(Time, Person)] -> [(Time, Person)]
groupTogether [] = []
groupTogether ((x, y) : (a, b) : ks)
  | x == a = (x, (y : (b))) : groupTogether ks
  | otherwise = (x, y) : groupTogether ((a, b) : ks)

而且它“有点”有效，但通常输出是 (8, Name1Name2) 而不是 (8, [Name1, Name1])。而且我只是不知道一旦列表中只有一个元素，该函数应该做什么。它说缺少“详尽的模式”。我究竟做错了什么？如果我尝试使用 : 将元素放在一起，代码将无法运行。

Answer 1

这个怎么样？

import Data.List
import Data.Function

data P = P1 | P2 | P3 deriving Show

x = [(8, P1), (8, P2), (10, P3)]

fun list = let lists = groupBy ((==) `on` fst) x -- [[(8,P1),(8,P2)],[(10,P3)]]
               nums  = map (fst . head) lists    -- [8,10]
               ps    = (map . map) snd lists     -- [[P1,P2],[P3]]
           in zip nums ps                        -- [(8,[P1,P2]),(10,[P3])]      

在lists 中，我根据数字的相等性对项目进行了分组，在nums 中，我提取了每个组中所有项目共有的数字，在ps 中，我提取了那些@987654326 @ 事物，无论它们是什么，通过 (map . map) . snd 应用 snd 通过两个功能层。

请注意，如果通常x 中相同数量的项目不一定相邻（在您的示例中它们是相邻的），您可能希望在使用groupBy 之前使用适当的排序算法来sort 列表，如下面的 cmets 中所建议的那样。

---

关于你想要的输出

[(8, [P1, P2]), (10, P3)]

这根本不可能获得，因为在 Haskell 中，列表的所有元素都具有相同的类型，但 (8, [P1, P2]) 和 (10, P3) 必须具有不同的类型，即 (Time, [Person]) 和 (Time, Person)。您的问题下的一些 cmets 已经暗示了这一点，但您尚未更正您的问题（您应该）。在我的回答中，我假设您打算写 [(8, [P1, P2]), (10, [P3])]。

关于你的尝试

groupTogether :: [(Time, Person)] -> [(Time, Person)]
groupTogether [] = []
groupTogether ((x, y) : (a, b) : ks)
  | x == a = (x, (y : (b))) : groupTogether ks
  | otherwise = (x, y) : groupTogether ((a, b) : ks)

它有几个语法问题：

• 签名错误，因为它表明输出与输入具有相同的类型；这当然是可能的，但不能反映（校正后的）所需输出；可能你打算写groupTogether :: [(Time, Person)] -> [(Time, [Person])]
• groupTogether [] = [] 处理空列表输入，而groupTogether ((x, y) : (a, b) : ks) 处理两个或更多元素的列表输入，但是没有办法处理单例列表，这正是“exaustive pattern missing”错误所暗示的；
• 因为y和b具有相同的类型，Person，表达式y : (b)是不正确的，因为它等价于y:b，而:想要一个a在左边和一个@ 987654349@在右边；你可能想把它改成y:[b]，或者[y,b]；
• 以类似的方式，y 在otherwise 的情况下应该是[y]。

但是，即使您应用了上述更正，仍然会有一些不太正确的地方。看看这个：

groupTogether ((x, y) : (a, b) : ks)
  | x == a = (x, y : [b]) : groupTogether ks

您正在模式匹配列表中的前两对并将它们放在一对中，但是如果ks 中的第一对有另一个a 作为它的第一个元素怎么办？您将其留在ks，而不是将其与其他两个分组。从您的问题文本来看，这要么是错误的，要么是不清楚的，在这种情况下，您应该改进它。

Answer 2

这个怎么样？ （注意Foldable t 可以是一个列表）

% ghci
λ> :m +Data.Map
λ> data P = P1 | P2 | P3 deriving (Eq, Ord, Show)
λ> let input = [(8, P1), (8, P2), (10, P3)] :: [(Int, P)]
λ> :type Prelude.foldl
_ :: Foldable t => (b -> a -> b) -> b -> t a -> b
λ> :type Prelude.foldl (\mp (k, p) -> insertWith (<>) k [p] mp)
_ :: (Foldable t, Ord k) => Map k [a] -> t (k, a) -> Map k [a]
λ> :type Prelude.foldl (\mp (k, p) -> insertWith (<>) k [p] mp) mempty
_ :: (Foldable t, Ord k) => t (k, a) -> Map k [a]
λ> :type Prelude.foldl (\mp (k, p) -> insertWith (<>) k [p] mp) mempty input
_ :: Map Int [P]
λ> Prelude.foldl (\mp (k, p) -> insertWith (<>) k [p] mp) mempty input
fromList [(8,[P2,P1]),(10,[P3])]
λ> toList (Prelude.foldl (\mp (k, p) -> insertWith (<>) k [p] mp) mempty input)
[(8,[P2,P1]),(10,[P3])]