Gradle powermock 代码覆盖丢失

Question

当我在测试中使用 powermock 时，如何配置 gradle 以生成声纳的代码覆盖率？我发现 jacoco 不支持这一点。是否有任何其他代码覆盖插件可以与 powermock 一起使用？

Answer 1

只要https://github.com/powermock/powermock/issues/727 不固定，您就可以尝试使用 JaCoCo 离线检测而不是运行中检测，这将使 PowerMock 与 JaCoCo 运行中检测兼容。

或者，您可以使用不同的模拟框架，例如 e. G。 JMockit。据我所知，这与 JaCoCo 即时仪器兼容。

Answer 2

我放弃使用 gradle 和 jacoco。现在我正在使用 maven + cobertura + powermock，一切都没有黑客攻击。为什么我使用maven？因为我找不到如何使用 gradle 在 cobertura 中生成 xml 代码覆盖率报告。

Answer 3

Jacoco Offline Instrumentation 是解决这个问题的方法。

查看我的 gradle 构建文件

Build and run tests:
Linux:
\$ ./gradlew
Windows:
\$ gradlew
------------------------------------------
"""

apply plugin: 'java'
apply plugin: 'org.sonarqube'
apply plugin: 'jacoco'

// Project group and version
group 'com.abcd.jacocoTest'
version '1.0.0'

// JDK version source compatibility
sourceCompatibility = 1.8

// JDK version target compatibility
targetCompatibility = 1.8

configurations {
    jacocoAnt
    jacocoRuntime
}

task wrapper(type: Wrapper) {
    gradleVersion = "4.5.1"
}

defaultTasks 'clean', 'test'

buildscript {
    repositories {
        maven { url "https://plugins.gradle.org/m2/" }
    }

    dependencies {
        classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:2.6.2"
    }
}

repositories {
    mavenCentral()
}

dependencies {

    jacocoAnt group: 'org.jacoco', name: 'org.jacoco.ant', version: '0.8.1'
    jacocoAgent group: 'org.jacoco', name: 'org.jacoco.agent', version: '0.8.1'
    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile group: 'org.mockito', name: 'mockito-core', version: '2.8.9'
    testCompile group: 'org.powermock', name: 'powermock-module-junit4', version: '1.7.4'
    testCompile group: 'org.powermock', name: 'powermock-api-mockito2', version: '1.7.4'
    testCompile group: 'org.powermock', name: 'powermock-api-easymock', version: '1.7.4'

}

test {
    testLogging {
        afterSuite { desc, result ->
            if (!desc.parent) { // will match the outermost suite
                println "Unit Tests: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)"
            }
        }
    }

    jacoco {
        append = "false"
        destinationFile = file("$buildDir/reports/jacoco/jacoco-sonar/jacoco-coverage.exec")
    }
}

jacoco {
    toolVersion = "0.8.0"
}

jacocoTestReport {
    reports {
        html.destination file("${buildDir}/reports/jacoco/jacocoHtml")
    }
}

sonarqube {
    properties {
        property "sonar.projectName", 'JacocoTest'
        property "sonar.host.url", "http://localhost:9000"
        property "sonar.java.binaries", "${buildDir}/classes"
        property "sonar.java.libraries", "**/*.jar"
        property "sonar.dynamicAnalysis", "reuseReports"
        property "sonar.jacoco.reportPaths", "${buildDir}/reports/jacoco/jacoco-sonar/jacoco-coverage.exec"
    }
}

task instrument(dependsOn: ['classes']) {
    ext.outputDir = buildDir.path + '/reports/classes-instrumented'
    doLast {
        ant.taskdef(name: 'instrument',
                classname: 'org.jacoco.ant.InstrumentTask',
                classpath: configurations.jacocoAnt.asPath)
        ant.instrument(destdir: outputDir) {
            fileset(dir: sourceSets.main.output.classesDir)
        }
    }
}
gradle.taskGraph.whenReady { graph ->
    if (graph.hasTask(instrument)) {
        tasks.withType(Test) {
            doFirst {
                classpath = files(instrument.outputDir) + classpath + configurations.jacocoRuntime
            }
        }
    }
}
task report(dependsOn: ['instrument', 'test']) {
    doLast {
        ant.taskdef(name: 'report',
                classname: 'org.jacoco.ant.ReportTask',
                classpath: configurations.jacocoAnt.asPath)
        ant.report() {
            executiondata {
                ant.file(file: buildDir.path + '/reports/jacoco/jacoco-sonar/jacoco-coverage.exec')
            }
            structure(name: 'Example') {
                classfiles {
                    fileset(dir: sourceSets.main.output.classesDir)
                }
                sourcefiles {
                    fileset(dir: 'src/main/java')
                }
            }
            html(destdir: buildDir.path + '/reports/jacoco')
        }
    }
}

此处报告任务将创建项目的离线检测文件。

最后，执行 sonarqube 任务。 然后你可以看到powermocked类的覆盖范围也包括在内了。

Execution command ./gradlew report sonarqube

然后去看看你的声纳主机（localhost:9000）。