用户窗体中多个命令按钮的唯一代码

Question

我正在尝试获取用户窗体中几个命令按钮的标题。我知道如何获取一个命令按钮的标题，但我不想复制粘贴所有命令按钮的代码，例如

Sub CommandButton1_Click()
CodeXYZ
End Sub

Sub CommandButton2_Click()
CodeXYZ
End Sub

....

有没有可能做类似的东西

Sub Master_CommandButton_Click()
ActiveSheet.Range("A1").Value = Master_CommandButton.Caption 

End Sub

编辑： 我正在从表中动态加载标题（取决于行和列）。如果单击其中一个命令按钮，则单击按钮的标题将写入单元格。

Private Sub UserForm_Initialize()
CommandButton1.Caption = ThisWorkbook.ActiveSheet.Range("B2").Value
CommandButton2.Caption = ThisWorkbook.ActiveSheet.Range("C2").Value
CommandButton3.Caption = ThisWorkbook.ActiveSheet.Range("D2").Value
CommandButton4.Caption = ThisWorkbook.ActiveSheet.Range("E2").Value
CommandButton5.Caption = ThisWorkbook.ActiveSheet.Range("F2").Value
End Sub

Private Sub CommandButton1_Click()
ThisWorkbook.ActiveSheet.Cells(5, 5).Value = CommandButton1.Caption
End Sub

我知道需要的不是定义每个按钮本身。我想将一个主代码交给所有按钮。

Answer 1

您可以使用类模块来处理表单上所有命令按钮的点击事件。

这是一种方法。

创建一个名为CCmdBtns 的类模块并将此代码添加到其中。

Option Explicit

Public WithEvents CmdGroup As MSForms.CommandButton

Private Sub CmdGroup_Click()
    ThisWorkbook.ActiveSheet.Cells(5, 5).Value = CmdGroup.Caption
End Sub

在标准模块中添加此代码。

Option Explicit

Public CmdButtons() As New CCmdBtns

现在您可以在用户表单模块中添加此代码。

Option Explicit

Private Sub UserForm_Initialize()
Dim ctl As MSForms.Control
Dim cnt As Long
    
    For Each ctl In Me.Controls
        If TypeName(ctl) = "CommandButton" Then
            cnt = cnt + 1
            ctl.Tag = ctl.BackColor
            ReDim Preserve CmdButtons(1 To cnt)
            Set CmdButtons(cnt).CmdGroup = ctl
        End If
    Next ctl
    
End Sub

现在，当您单击用户窗体上的任何命令按钮时，它的标题将被写入活动工作表上的 E5。

请注意，您可以使用循环来简化设置字幕的代码。

Dim idx As Long

    For idx = 1 To 5
        Me.Controls("CommandButton" & idx).Caption = ThisWorkbook.ActiveSheet.Cells(2, idx + 1).Value        
    Next idx