用 \n 替换引用字符串中的换行符

Question

我需要编写一个快速（到明天）过滤器脚本，用转义换行符\n 替换双引号字符串中的换行符（LF 或 CRLF）。内容是一个（损坏的）javascript 程序，所以我需要在字符串中允许像"ab\"cd" 和"ab\\"cd"ef" 这样的转义序列。

我知道 sed 不适合这项工作，因为它按行工作，所以我转向 perl，我对此一无所知 :)

我已经编写了这个正则表达式："(((\\.)|[^"\\\n])*\n?)*" 并使用 http://regex.powertoy.org 对其进行了测试。它确实匹配带换行符的引用字符串，但是，perl -p -e 's/"(((\\.)|[^"\\\n])*(\n)?)*"/TEST/g' 不匹配。

所以我的问题是：

1. 如何让 perl 匹配换行符？
2. 如何编写“replace-by”部分，使其保留原始字符串并仅替换换行符？

similar question 有 awk 解决方案，但这不是我所需要的。

注意：我通常不会问“请为我做这件事”的问题，但我真的不想在明天之前学习 perl/awk...:)

编辑：样本数据

"abc\"def" - matches as one string
"abc\\"def"xy" - match "abcd\\" and "xy"
"ab
cd
ef" - is replaced by "ab\ncd\nef"

Answer 1

这是一个简单的 Perl 解决方案：

s§
    \G # match from the beginning of the string or the last match
    ([^"]*+) # till we get to a quote
    "((?:[^"\\]++|\\.)*+)" # match the whole quote
§
    $a = $1;
    $b = $2;
    $b =~ s/\r?\n/\\n/g; # replace what you want inside the quote
    "$a\"$b\"";
§gex;

---

如果您不想使用 /e 并且只使用一个正则表达式，这是另一种解决方案：

use strict;

$_=<<'_quote_';
hai xtest "aa xx aax" baix "xx"
x "axa\"x\\" xa "x\\\\\"x" ax
xbai!x
_quote_

print "Original:\n", $_, "\n";

s/
(
    (?:
        # at the beginning of the string match till inside the quotes
        ^(?&outside_quote) "
        # or continue from last match which always stops inside quotes
        | (?!^)\G
    )
    (?&inside_quote)  # eat things up till we find what we want
)
x   # the thing we want to replace
(
    (?&inside_quote)  # eat more possibly till end of quote
    # if going out of quote make sure the match stops inside them
    # or at the end of string
    (?: " (?&outside_quote) (?:"|\z) )?
)

(?(DEFINE)
    (?<outside_quote> [^"]*+ ) # just eat everything till quoting starts
    (?<inside_quote> (?:[^"\\x]++|\\.)*+ ) # handle escapes
)
/$1Y$2/xg;

print "Replaced:\n", $_, "\n";

输出：

Original:
hai xtest "aa xx aax" baix "xx"
x "axa\"x\\" xa "x\\\\\"x" ax
xbai!x

Replaced:
hai xtest "aa YY aaY" baix "YY"
x "aYa\"Y\\" xa "Y\\\\\"Y" ax
xbai!x

要使用换行符而不是 x，只需在正则表达式中替换它，如下所示：

s/
(
    (?:
        # at the beginning of the string match till inside the quotes
        ^(?&outside_quote) "
        # or continue from last match which always stops inside quotes
        | (?!^)\G
    )
    (?&inside_quote)  # eat things up till we find what we want
)
\r?\n # the thing we want to replace
(
    (?&inside_quote)  # eat more possibly till end of quote
    # if going out of quote make sure the match stops inside them
    # or at the end of string
    (?: " (?&outside_quote) (?:"|\z) )?
)

(?(DEFINE)
    (?<outside_quote> [^"]*+ ) # just eat everything till quoting starts
    (?<inside_quote> (?:[^"\\\r\n]++|\\.)*+ ) # handle escapes
)
/$1\\n$2/xg;

Answer 2

在 OP 发布一些示例内容以供测试之前，请尝试将“m”（可能还有“s”）标志添加到正则表达式的末尾；来自perldoc perlreref (reference)：

m  Multiline mode - ^ and $ match internal lines
s  match as a Single line - . matches \n

为了进行测试，您可能还会发现添加命令行参数“-i.bak”以便保留原始文件的备份（现在扩展名为“.bak”）。

另请注意，如果您想捕获但不存储某些内容，您可以使用(?:PATTERN) 而不是(PATTERN)。获取捕获的内容后，使用 $1 到 $9 从匹配部分访问存储的匹配项。

有关更多信息，请参阅链接以及 perldoc perlretut (tutorial) 和 perldoc perlre (full-ish documentation)

Answer 3

#!/usr/bin/perl
use warnings;
use strict;
use Regexp::Common;

$_ = '"abc\"def"' . '"abc\\\\"def"xy"' . qq("ab\ncd\nef");

print "befor: {{$_}}\n";
s{($RE{quoted})}
 {  (my $x=$1) =~ s/\n/\\n/g;
    $x
 }ge;
print "after: {{$_}}\n";

Answer 4

使用 Perl 5.14.0（使用 perlbrew 安装）可以做到这一点：

#!/usr/bin/env perl

use strict;
use warnings;

use 5.14.0;

use Regexp::Common qw/delimited/;

my $data = <<'END';
"abc\"def"
"abc\\"def"xy"
"ab
cd
ef"
END

my $output = $data =~ s/$RE{delimited}{-delim=>'"'}{-keep}/$1=~s!\n!\\n!rg/egr;

print $output;

我需要 5.14.0 作为内部替换的 /r 标志。如果有人知道如何避免这种情况，请告诉我。