如何在unix中比较和替换不同行中的字符串

Question

我想比较和替换 unix 中不同行中的字符串

例如我有一个文件，每行有两个单词

<a> <b>
<d> <e>
<b> <c>
<c> <e>

如果任何行的第二个单词与任何其他行的第一个单词匹配，则该行的第二个单词应该替换为匹配行的第二个单词，并且它应该迭代直到该行的第二个单词与第一个单词之间没有匹配另一行的

我需要类似的结果

<a> <e>
<b> <e>
<c> <e>
<d> <e>

我是 unix 新手，不知道如何实现它。任何人都可以提出建议或解释我们如何做到这一点

Answer 1

这显然是递归下降解决方案的一个案例：

$ cat tst.awk
function descend(node) {return (map[node] in map ? descend(map[node]) : map[node])}
{ map[$1] = $2 }
END { for (key in map) print key, descend(key) }

$ awk -f tst.awk file
<a> <e>
<b> <e>
<c> <e>
<d> <e>

如果您的输入中可能存在无限递归，这里的方法将在递归开始之前将最后一个节点打印为第二个字段，并在其旁边放置一个“*”，以便您知道它正在发生：

$ cat tst.awk
function descend(node,  child, descendant) {
    stack[node]
    child = map[node]
    if (child in map) {
        if (child in stack) {
            descendant = node "*"
        }
        else {
            descendant = descend(child)
        }
    }
    else {
        descendant = child
    }
    delete stack[node]
    return descendant
}
{ map[$1] = $2 }
END { for (key in map) print key, descend(key) }

.

$ cat file
<w> <w>
<x> <y>
<y> <z>
<z> <x>
<a> <b>
<d> <e>
<b> <c>
<c> <e>

$ awk -f tst.awk file
<w> <w>*
<x> <z>*
<y> <x>*
<z> <y>*
<a> <e>
<b> <e>
<c> <e>
<d> <e>

如果您需要输出顺序与输入顺序匹配和/或打印重复的行两次，请将脚本的底部 2 行更改为：

{ keys[++numKeys] = $1; map[$1] = $2 }
END {
    for (keyNr=1; keyNr<=numKeys; keyNr++) {
        key = keys[keyNr]
        print key, descend(key)
    }
}

Answer 2

Perl 的救援：

#!/usr/bin/perl
use warnings;
use strict;

my (@buff);
sub output {
    my $last = pop @buff;
    print map "$_ $last\n", @buff;
    @buff = ();
}

while (<>) {
    my @F = split;
    output() if @buff and $F[0] ne $buff[-1]; # End of a group.
    push @buff, $F[0] unless @buff;           # Start a new group.
    push @buff, $F[1];
}

output();                                     # Don't forget to print the last buffer.

解释：逐行读取输入。保留要打印的单词列表，其中包含相同的第二个单词。如果第一个单词与上一行的第二个单词不同，则打印缓冲输出。

Answer 3

awk '{i++;a[i]=$1;b[i]=$2;next}
      END{
            for(i=1;i in a;i++)
            {
              f=1;
              while (f==1)
              {
                f=0;
                for(j=i+1;j in a;j++)
                {
                  if(b[i]==a[j])
                  {
                    b[i]=b[j];
                    f=1;
                  }
                }
              }
            }
            for(i=1;i in a;i++)
            {
              print a[i],b[i];
            }
          }' input.txt

输入：

<a> <b>
<d> <e>
<b> <c>
<c> <e>

输出：

<a> <e>
<d> <e>
<b> <e>
<c> <e>

输入：

<a> <b>
<e> <z>
<b> <e>

输出：

<a> <z>
<e> <z>
<b> <e>

---

编辑

如果你需要得到

<a> <z>
<e> <z>
<b> <z>

作为第二个输入的输出，您可以更改此行：

if(b[i]==a[j])

到：

if(j!=i&&b[i]==a[j])

还有这个：

for(j=i+1;j in a;j++)

到：

for(j=1;j in a;j++)

另请注意，此代码假定不存在一行的第二个单词等于一行的第一个单词及其第二个单词的情况，即：

<a> <b>
<e> <z>
<b> <b>

在这种情况下，代码的执行将永远不会结束。