匹配日志文件上的日期并使用 awk 打印行

Question

我有一个日志文件，在其他 100 行中可能包含以下行

hosta: Info: Tue Nov 25  19:44:39 2014>
User jwayman at position 170.198.3.141 disconnected 

hosta: Info: Tue Nov 23  19:44:39 2014>
User jho at position 170.198.3.141 disconnected 

hosta: Info: Tue Nov 26  19:44:39 2014>
User jho at position 170.198.3.141 disconnected 

我需要查找“断开连接”的出现，然后如果日期（从它上面的行）与今天的日期匹配，那么我想打印以下信息：

user jho disconnected from server "hosta"

所以我需要从两行中提取数据，然后对其进行处理。 我正在考虑在数组中执行此操作并将所有出现的事件分配给数组中的变量。 但我希望有人可以介绍一种更简单的方法，可能是grep 和awk。

Answer 1

使用 GNU awk 实现 gensub() 和时间函数：

$ awk -v RS= '
    BEGIN { today=strftime("%a%b%d") }
    (($3$4$5)==today) && /disconnected/ {
        print $8, $9, $NF, "from server \"" gensub(/:/,"\"","",$1)
    }
' file
User jho disconnected from server "hosta"

Answer 2

与 fedorqui 相同的概念（他领先我几分钟），但具有您要求的确切输出，而不仅仅是输入断开的线路。

awk -v date="$(date "+%a %b %d")" '$2 == "Info:" {
                                       if ($3" "$4" "$5==date) {
                                           s=$1; sub(/:$/,"",s)
                                       } else {
                                           s=""
                                       }
                                       next
                                   }
                                   s && ($NF == "disconnected") {
                                       print "user",$2,"disconnected from server \""s"\""
                                       s=""
                                       next
                                   }'

解释：

• $2 == "Info: 我们在看Info 行吗
  • if ($3" "$4" "$5==date) {是今天的这条线
  • s=$1; sub(/:$/,"",s) 将服务器分配给s 并去掉结尾的冒号
  • else这是前几天的一条线
  • s="" 取消设置我们的服务器变量。
  • next 跳到下一行
• s && ($NF == "disconnected") 我们有保存的服务器吗，这是断线吗
  • print "user",$2,"disconnected from server \""s"\"" 打印所需的输出
  • s="" 取消设置我们的服务器变量。
  • next跳到下一行

Answer 3

您可以使用以下内容：

awk -v today="$(date "+%a %b %d")" '$3 FS $4 FS $5 == today {f=1; next}
                                    f && /disconnected/ {print}
                                    f=0 ' file

说明

• $(date "+%a %b %d") 返回格式为 Wed Nov 26。
• $3 FS $4 FS $5 == today {f=1; next} 检查当前行是否具有这种格式。如果是这样，则会激活标志 f。
• f && /disconnected/ {print} 如果设置了标志并且该行包含disconnected，则打印它。
• f=0 取消设置标志。

测试

示例文件：

$ cat a
hosta: Info: Tue Nov 25  19:44:39 2014>
User jwayman at position 170.198.3.141 disconnected 

hosta: Info: Tue Nov 23  19:44:39 2014>
User jho at position 170.198.3.141 disconnected 

hosta: Info: Wed Nov 26  19:44:39 2014>
User jho at position 170.198.3.141 disconnected 

hosta: Info: Wed Nov 26  19:44:39 2014>
User jho at position 170.198.3.141 here

检查脚本：

$ awk -v today="$(date "+%a %b %d")" '$3 FS $4 FS $5 == today {f=1; next} f && /disconnected/ {print} f=0 ' a
User jho at position 170.198.3.141 disconnected