返回没有最后一个元素的列表

Question

我刚刚开始学习球拍。

我有这个代码：

#lang racket

(define l1 '(1 2 3 4))
(car l1)
(cdr l1)

(car l1) 返回 1。
(cdr l1) 返回 '(2 3 4)

有没有返回'(1 2 3)的函数？

我试过了：

#lang racket

(define l1 '(1 2 3 4))
(map
 (lambda (l i)
   (if (not (= i (sub1 (length l1)))) l '()))
 l1 (range 0 (length l1)))

但是，它返回：'(1 2 3 ())

我也试过了：

#lang racket

(define l1 '(1 2 3 4))
(map
 (lambda (l i)
   (cond ((not (= i (sub1 (length l1)))) l )))
 l1 (range 0 (length l1)))

但是，它返回：'(1 2 3 #<void>)

Answer 1

这样的事情怎么样？

(define (myCdr l)
    (if (not (pair? (cdr l)))
        '()
        (cons (car l) (myCdr (cdr l)))
    )
)

Answer 2

map 函数总是返回一个与其输入长度相同的列表。您需要一个比其输入短的输出列表。您要查找的函数传统上称为but-last：

(define (but-last xs) (reverse (cdr (reverse xs))))

Answer 3

length 在 Scheme 中通常是一种反模式，因为需要读取整个列表才能得到结果。 W. Ness 指出map 不会改变列表的结构，filter 的行为是基于列表的值，两者都不适合您的需要。

您可以使用直接递归计算列表的init，而不是首先进行可能昂贵的计算或笨拙地应用库函数 -

(define (init l)
  (cond ((null? l)
         (error 'init "cannot get init of empty list"))
        ((null? (cdr l))
         null)
        (else
         (cons (car l)
               (init (cdr l))))))

(init '(a b c d e)) ;; '(a b c d)
(init '(a))         ;; '(a)
(init '())          ;; init: cannot get init of empty list

或者只使用一个reverse的尾递归形式-

(define (init l)
  (let loop ((acc null)
             (l l))
    (cond ((null? l)
           (error 'init "cannot get init of empty list"))
          ((null? (cdr l))
           (reverse acc))
          (else
           (loop (cons (car l) acc)
                 (cdr l))))))

(init '(a b c d e)) ;; '(a b c d)
(init '(a))         ;; '(a)
(init '())          ;; init: cannot get init of empty list

最后是尾递归形式，不使用length 或 reverse。有关其工作原理的更多直觉，请参阅"How do collector functions work in Scheme?" -

(define (init l (return identity))
  (cond ((null? l)
         (error 'init "cannot get init of empty list"))
        ((null? (cdr l))
         (return null))
        (else
         (init (cdr l)
               (lambda (r)
                 (return (cons (car l) r)))))))

(init '(a b c d e)) ;; '(a b c d)
(init '(a))         ;; '(a)
(init '())          ;; init: cannot get init of empty list

Answer 4

这里还有另一种选择，假设列表非空。它很高效（它对列表执行一次遍历），而且没有比这更简单的了！

(define (delete-last lst)
  (drop-right lst 1))

(delete-last '(1 2 3 4))
=> '(1 2 3)

Answer 5

我自己使用递归的解决方案：

#lang racket

(define but-last
  (lambda (l)
    (cond ((null? (cdr l)) '())
          (else (cons (car l) (but-last (cdr l)))))))

另一个使用filter-not 和map 的解决方案：

#lang racket

(define l1 '(1 2 3 4))

(filter-not empty? (map
 (lambda (l i)
   (if (not (= i (sub1 (length l1)))) l empty))
 l1 (range 0 (length l1))))

Answer 6

这里还有一个，通过压缩：

#lang racket

(require srfi/1)

(define (but-last-zip xs)
  (if (null xs)
      xs                      ; or error, you choose
      (map (lambda (x y) x)
           xs
           (cdr xs))))

这是另一个，通过附加列表模拟过滤，其中空列表自行消失：

(define (but-last-app xs)
  (if (null? xs)
      xs
      (let ((n (length xs)))
        (apply append                  ; the magic
               (map (lambda (x i)
                      (if (= i (- n 1)) '() (list x)))
                    xs
                    (range n))))))

或者我们可以直接使用decorate--filter--undecorate，代码更多！

(define (but-last-fil xs)
  (if (null? xs)
      xs
      (let ((n (length xs)))
        (map car
             (filter (lambda (x) (not (null? x)))
                     (map (lambda (x i)
                            (if (= i (- n 1)) '() (list x)))
                          xs
                          (range n)))))))

Answer 7

这里是 Will Ness's beautiful but-last-zip 的等价物，它不依赖于 Racket 中的 srfi/1：没有 srfi/1 Racket 的 map 坚持认为它的所有参数都是相同的长度（事实上 R5RS 版本也是如此）但在其他 Lisps 中，函数在最短列表的末尾终止是很常见的。

这个函数使用 Racket 的 for/list 并且还假设空列表的结果是空列表。

#lang racket

(define (but-last-zip xs)
  (for/list ([x xs] [y (if (null? xs) xs (rest xs))])
    x))

我认为 Will 的版本更纯粹：我认为在事物上映射函数是非常 Lisp 的事情，而 for/list 对我来说不那么 Lisp。这个版本的唯一优点是它不需要模块。