Delphi解析JSON数组或数组

Question

这是我希望能够解析的示例 JSON：

[
  {
    "a":{
      "username":"aaa",
      "email":"aaa@gmail.com"
    }
  },
  {
    "b":{
      "username":"bbb",
      "email":"bbb@gmail.com"
    }
  }
]

我需要对getData('b', 'email') 的调用必须输出bbb@gmail.com！

---

我真的很难理解如何使用System.JSON 单元，但我无法得到解决方案！我希望能够编写一个从上述 JSON 结构中提取特定数据的函数。到目前为止，这是我的代码。在类构造函数中我有：

var
  FIds: TJSONArray;
begin
  FIds := TJSONObject.ParseJSONValue({json string here}) as TJSONArray;
end;

然后，在必须返回数据的函数内部，我写了这个：

// 'name' can be 'a' or 'b'  | 'data' can be 'username' or 'email'
function TTest.getData(const name, data: string): string;
var
  FValue, FValueInner: TJSONValue;
begin
  for FValue in Fids do
  begin
    if (FValue is TJSONArray) then
    begin
      //Here I am sure that I have a TJSONArray (which can be 'a' or 'b' from above)
    end;
  end;
end;

根据我上面写的，我必须检查name 的值并决定是否必须访问a 或b 中的数据。然后，一旦我选择了正确的 JSON 数组 a 或 b，我必须选择是否要显示 username 或 email 字段（在 data 变量中指定）。

我该怎么做？

---

这是我最近的尝试，但我真的不明白该怎么做：

... same code above ...

if (FValue is TJSONArray) then
begin
  //here I want to check if the current array is a or b
  if ((FValue as TJSONArray).Items[0] as TJSONValue).Value = name then
  begin
    Farr := TJSONObject.ParseJSONValue(((FValue as TJSONArray).Items[0] as TJSONValue).ToJSON) as TJSONArray;
    try
      //here I want to get the data inside username or email
      for FValueInner in Farr do
        Result := FValueInner.GetValue<string>(data);
    finally
      Farr.Free;
    end;
  end;
end;

Farr: TJSONArray; 和 FValueInner: TJSONValue; 在哪里

Answer 1

对于寻找这些答案的新读者。

这个函数怎么样，或者如果你重构 JSON 数据更简单？

function getData(JsonString: String; User: String; Field: String): String;
var
  JSonValue: TJSonValue;
  JsonArray: TJSONArray;
  ArrayElement: TJSonValue;
  FoundValue: TJSonValue;
begin
  Result :='';

  // create TJSonObject from string
  JsonValue := TJSonObject.ParseJSONValue(JsonString);

  // get the array
  JsonArray := JsonValue as TJSONArray;

  // iterate the array
  for ArrayElement in JsonArray do begin
      FoundValue := ArrayElement.FindValue(User);
      if FoundValue <> nil then begin
        Result := ArrayElement.GetValue<string>(User + '.' + Field);
        break;
      end;
  end;
end;

上面示例 JSON 代码的问题在于它使用用户名“a”“b”作为用户数据的 JSON-key {key:data}。这样，您就不能在搜索数据时使用 GetValue("a")。以不同的方式构建 JSON 数据会使搜索过程变得容易得多。稍后我会举一个例子。

处理给定 JSON 数据的一种方法是使用 FindValue，这样您就可以检查一个字段是否带有 key“a”或“b”存在。

FoundValue := ArrayElement.FindValue("b");
if FoundValue <> nil then begin
    Result := ArrayElement.GetValue<string>("b"+ '.' + "email");
    break;

关于“解析 JSON 数组”问题：数据作为 TJSonObject 加载后，您可以将数据更改为 TJSONArray 并迭代元素。

  JsonValue := TJSonObject.ParseJSONValue(JsonString);  
  JsonArray := JsonValue as TJSONArray;
  for ArrayElement in JsonArray do begin
    ...

给定 JSON 数据的工作示例代码：

unit JsonArray1;

interface

uses System.JSON;

function getData2(JsonString: String; User: String; Field: String): String;
procedure Test1();

implementation

function getData2(JsonString: String; User: String; Field: String): String;
var
  JSonValue: TJSonValue;
  JsonArray: TJSONArray;
  ArrayElement: TJSonValue;
  FoundValue: TJSonValue;
begin
  Result :='';

  // create TJSonObject from string
  JsonValue := TJSonObject.ParseJSONValue(JsonString);

  // get the array
  JsonArray := JsonValue as TJSONArray;

  // iterate the array
  for ArrayElement in JsonArray do begin
      FoundValue := ArrayElement.FindValue(User);
      if FoundValue <> nil then begin
        Result := ArrayElement.GetValue<string>(User + '.' + Field);
        break;
      end;
  end;
end;

procedure Test1();
var
  DataBase: String;
  EmailAddress : String;
  Username: String;
begin
  DataBase := '[  {"a" : {"username":"aaa","email":"aaa@gmail.com"}},' +
                 '{"b" : {"username":"bbb","email":"bbb@gmail.com"}}  ]';

  EmailAddress := getData2(DataBase, 'b', 'email');
  Username := getData2(DataBase, 'a', 'username');

end;

end.

如前所述，使用适当的键重构 JSON 数据可使查找数据的代码更加简单。因为用户数据 "a":{}, "b":{} 之间存在 1 对 1 的关系，所以很容易引入 'user' 键。此外，向数组添加“用户”键会导致所有数据都有键。

  '{"users" : [{ "user":"a", "username":"aaa","email":"aaa@gmail.com"},' +
              '{ "user":"b", "username":"bbb","email":"bbb@gmail.com"}]}';

当您迭代用户时，您现在可以将 GetValue 与新的“用户”键一起使用。

  if ArrayElement.GetValue<String>('user') = 'b' then begin
    Result := ArrayElement.GetValue<String>('email');

通过给数组一个键，你现在可以得到数组：

JsonArray := JsonValue.GetValue<TJSONArray>('users');

重组 JSON 数据的工作示例代码：

unit JsonArray2;

interface

uses System.JSON;

function getData2(JsonString: String; User: String; Field: String): String;
procedure Test2();

implementation

function getData2(JsonString: String; User: String; Field: String): String;
var
  JSonValue: TJSonValue;
  JsonArray: TJSONArray;
  ArrayElement: TJSonValue;
  FoundValue: TJSonValue;
begin
  Result :='';

  // create TJSonObject from string
  JsonValue := TJSonObject.ParseJSONValue(JsonString);

  // get the array
  JsonArray := JsonValue.GetValue<TJSONArray>('users');

  // iterate the array
  for ArrayElement in JsonArray do begin
      if ArrayElement.GetValue<String>('user') = User then begin
        Result := ArrayElement.GetValue<String>(Field);
        break;
      end;
  end;
end;

procedure Test2();
var
  DataBase: String;
  EmailAddress : String;
  Username: String;
begin
  DataBase := '{"users" : [{ "user":"a", "username":"aaa","email":"aaa@gmail.com"},' +
                          '{ "user":"b", "username":"bbb","email":"bbb@gmail.com"}]}';

  EmailAddress := getData2(DataBase, 'b', 'email');
  Username := getData2(DataBase, 'a', 'username');

end;

end.

Answer 2

您的 JSON 是一个对象数组，因此 FIds 是一个包含 TJSONObject 元素的 TJSONArray。这些对象的a 和b 字段本身就是对象，而不是数组。所以FValue is TJSONArray 在枚举该数组时总是为假。

另外，(FValue as TJSONArray).Items[0] as TJSONValue).Value = name 是错误的，因为 JSON 对象包含名称/值对，但您忽略了名称，并且您试图枚举这些对，就好像它们是数组的元素一样，而实际上它们不是。如果要枚举对象的对，请使用 TJSONObject.Count 和 TJSONObject.Pairs[] 属性。但在这种情况下，这不是必需的，因为您正在通过名称查找特定的一对。 TJSONObject 有一个 Values[] 属性用于此目的。

而TJSONObject.ParseJSONValue(((FValue as TJSONArray).Items[0] as TJSONValue).ToJSON) as TJSONArray 简直太荒谬了。没有理由将对象转换回 JSON 字符串只是为了再次解析它。已经解析过一次，不需要再次解析。

最后，FValueInner.GetValue<string>(data) 是错误的，因为TJSONValue 没有GetValue() 方法，更不用说使用泛型的方法了。

现在，话虽如此，请尝试更多类似的东西：

// 'name' can be 'a' or 'b'  | 'data' can be 'username' or 'email'
function TTest.getData(const name, data: string): string;
var
  FValue, FValueInner: TJSONValue;
begin
  Result := '';
  for FValue in Fids do
  begin
    if (FValue is TJSONObject) then
    begin
      FValueInner := TJSONObject(FValue).Values[name];
      if FValueInner <> nil then
      begin
        if (FValueInner is TJSONObject) then
        begin
          FValueInner := TJSONObject(FValueInner).Values[data]; 
          if FValueInner <> nil then
            Result := FValueInner.Value;
        end;
        Exit;
      end;
    end;
  end;
end;

Answer 3

如果你使用AlcinoeTalJsonDocument，它会很简单：

aJsonDoc := TalJsonDocU.create;
aJsonDoc.loadFromFile(...);
for i := 0 to aJsonDoc.node.childnodes.count-1 do begin
  myValue := aJsonDoc.node.childNodes[i].getchildNodeValueText(['b', 'email']); 
  if myValue <> '' then break;
end;