将 Java 转换为 Clojure - 附加到列表并返回列表

Question

我想将以下 java 翻译成惯用的 clojure：

List<SimpleRecord> recs = new ArrayList<SimpleRecord>();
ParquetReader<SimpleRecord> reader = null;
    try {
      PrintWriter writer = new PrintWriter(Main.out, true);
      reader = new ParquetReader<SimpleRecord>(new Path(input), new SimpleReadSupport());
      for (SimpleRecord value = reader.read(); value != null; value = reader.read()) {
        //value.prettyPrint(writer);
        //writer.println();
        recs.add(value);
      }
      return value;
    } finally {
      if (reader != null) {
        try {
          reader.close();
        } catch (Exception ex) {
        }
      }
    }

但我在每一步都无法将元素推送到列表中。 这就是我现在拥有的：

(let [rows   (vector)
      reader (new parquet.hadoop.ParquetReader (new org.apache.hadoop.fs.Path "file.pq") 
                                               (new SimpleReadSupport))]
  ;reader  
  (try   
    (for [value (.read reader) :while (not (nil? value))]
      (conj value rows)) ;y u no recur?
    rows
    (finally (.close reader)))
  )

但我不知道在for 中这样做的惯用方式是什么。我猜我必须使用reduce 不？谢谢

Answer 1

对镶木地板或您想要做什么一无所知，这是我的最佳猜测和一些观察：

(with-open [reader (parquet.hadoop.ParquetReader. 
                     (org.apache.hadoop.fs.Path. "file.pq") 
                     (SimpleReadSupport.))]
  (doall (for [value (repeatedly #(.read reader))
               :while value] 
           value))

nil 和 false 是假的，其他一切都是真的，如果 value 永远不会是假的，那么只需使用 value 而不是 (not (nil? value))。 （额外的陷阱：(Boolean. false) 是真的，见https://github.com/clojure/clojure/blob/master/src/jvm/clojure/lang/Compiler.java#L2607 :)

它需要是一个向量，为什么？这里的代码返回一个seq，是doall提前实现的（要在with-open范围内，相当于你的try-finally。）

Clojure 的数据是不可变的，您不需要附加到列表中，而是告诉它从旧数据中创建新数据并让 Clojure 处理细节 :-)。在您的代码示例中，您无法更改 rows 的值，一旦设置，就没有“变量”。有有个可变引用类型，但在这里使用它们是不好的形式。从技术上讲，您可以使用循环/递归来实现这一点，但这里没有理由这样做（也许是性能），并且通常使用惰性序列方法确实有好处。

reduce 不起作用，因为它消除了提前退出的能力，而且这里的输入是一个 java 对象，reduce 需要一个 seq-able 的东西，所以你仍然必须找到一些方法来生成一个懒惰的序列，你又回到了原点。

for 不是循环，而是列表理解。它会生成一个惰性值序列。

我不认为new 惯用，我不知道为什么:-)。不过，它是使用宏生成代码的更好选择。

花时间理解这些概念，它们在实践中很棒！

Answer 2

gtrak 的方法当然是最好的，但我仍然想向您展示如何在 clojure 中编写显式循环。

(with-open [reader (parquet.hadoop.ParquetReader. 
                     (org.apache.hadoop.fs.Path. "file.pq") 
                     (SimpleReadSupport.))]
  (loop [rows []]
    (let [value (.read reader)]
      (if value
          (recur (conj rows value))
          rows))))

Answer 3

Clojure 中的for 不是 for 循环，它是一个序列理解。

默认的 Clojure 数据结构是不可变的，应该迭代构建，而不是在迭代中发生变异。

(with-open [reader (parquet.hadoop.ParquetReader. 
                     (org.apache.hadoop.fs.Path. "file.pq") 
                     (SimpleReadSupport.))]
  (doall
   (take-while (complement nil?)
               (repeatedly (fn []
                             (try (.read reader)
                                  (catch Exception e))))))