String.to_integer/1 的奇怪行为

Question

String.to_integer 在 Elixir 中有一些奇怪的东西。没什么大不了的，但我想知道是否有办法将我的所有功能与管道运算符链接起来。

这就是问题所在。这行代码（可以在“iex”中试试）：

[5, 6, 7, 3] 
|> Enum.reverse 
|> Enum.map_join "", &(Integer.to_string(&1))

返回字符串"3765"

我想要的是一个整数。所以我只需要在前一个语句的末尾添加这段代码|> String.to_integer，我应该有一个整数。我们试试吧。这段代码：

[5, 6, 7, 3] 
|> Enum.reverse 
|> Enum.map_join "", &(Integer.to_string(&1)) 
|> String.to_integer

给我这个："3765"。不是整数，是字符串！

如果我这样做：

a = [5, 6, 7, 3] 
|> Enum.reverse 
|> Enum.map_join "", &(Integer.to_string(&1)) 
String.to_integer(a)

它返回一个整数：3765。

这就是我现在正在做的事情，但这让我很生气，因为我很想用出色的管道操作员将所有这些功能链接起来。

感谢您的帮助或灯光。 Elixir 很好玩！

Answer 1

您需要在map_join 的参数周围添加括号。目前，您的代码被解释为

[5, 6, 7, 3] 
|> Enum.reverse 
|> Enum.map_join("", &(Integer.to_string(&1) |> String.to_integer))

你想要的是什么

[5, 6, 7, 3] 
|> Enum.reverse 
|> Enum.map_join("", &(Integer.to_string(&1)))
|> String.to_integer

通常，当您在管道中使用捕获时，您总是需要使用括号以避免歧义。捕获也可以简化为&Integer.to_string/1：

[5, 6, 7, 3] 
|> Enum.reverse 
|> Enum.map_join("", &Integer.to_string/1)
|> String.to_integer

但是一个普通的Enum.join 会做同样的事情。如果您查看the implementation，它将使用the String.Chars protocol 将整数转换为字符串。

[5, 6, 7, 3] 
|> Enum.reverse 
|> Enum.join
|> String.to_integer

顺便说一句，你完全不用字符串也能达到同样的效果：

[5, 6, 7, 3] 
|> Enum.reverse 
|> Enum.reduce(0, &(&2 * 10 + &1))

哦，还有Integer.digits 和Integer.undigits，可用于将整数与数字列表相互转换。它在当前版本中不存在，尽管它在 1.1.0-dev 分支中，所以我怀疑它会出现在 1.1.0 中。可以here查看进度。

[5, 6, 7, 3] 
|> Enum.reverse 
|> Integer.undigits