如何使用 Apache Perl 处理程序进行重定向？答案

【问题标题】：How does one redirect using an Apache Perl Handler?如何使用 Apache Perl 处理程序进行重定向？
【发布时间】：2017-06-11 08:52:14
【问题描述】：

我有一个 Apache 处理程序，它为 Perl 脚本设置了扩展名.redir。代码如下：

Action redir-url /cgi-bin/redir.pl
AddHandler redir-url .redir

脚本应该简单地将用户重定向到包含在.redir 文件中的页面。示例：

so.redir:

http://stackoverflow.com/

如果用户访问http://example.com/so.redir，他们将被重定向到http://stackoverflow.com/。

我当前的代码如下，虽然它返回错误 500，并且可能完全关闭：

#!/usr/bin/perl
use strict;
use warnings;

use Path::Class;
use autodie;

my $file = file($ENV{'PATH_TRANSLATED'});

my $file_handle = $file->openw();

my @list = ('a', 'list', 'of', 'lines');

foreach my $line ( @list ) {
    # Add the line to the file
    $file_handle->print("Location: ".$line."\n\n");
}

感谢您的帮助！

【问题讨论】：

标头缺少状态码。您还在循环中输出标题，这是没有意义的。
您认为可以在一次响应中将客户重定向到多少个地方？ :)
这只是从网上复制粘贴各种代码，有点不切实际:)

标签： apache perl redirect cgi cgi-bin

【解决方案1】：

在 cgi 时代，我们曾经有一个小子程序来执行重定向：

sub redirect_url {
    my ($url, %params) = @_;

    $params{Location} = $url;

    if ( ($ENV{'HTTP_USER_AGENT'}=~m|Mozilla\/4\.|)
        && !($ENV{'HTTP_USER_AGENT'}=~m|MSIE|) ) {

        # handle redirects on netscape 4.x
        $params{Status} = '303 See Other'
            unless exists $params{Status};
        $params{'Content-Type'} = 'text/html; charset=utf-8'
            unless exists $params{'Content-Type'};
        $params{Content} =<<EOF;
<html>
  <head>
    <script language="JavaScript"><!--
location.href = "$params{Location}";
//--></script>
  </head>
  <body bgcolor="#FFFFFF">
    <a href="$params{Location}">Redirect</a>
  </body>
EOF
    }
    else {
            $params{Status} = '301 Moved Permanently'
            unless exists $params{Status};
        $params{'Content-Type'} = 'text/plain; charset=utf-8'
            unless exists $params{'Content-Type'};
    }

    $params{Expires} = 'Fri, 19 May 1996 00:00:00 GMT'
        unless exists $params{Expires};
    $params{Pragma} = 'no-cache'
        unless exists $params{Pragma};
    $params{'Cache-Control'} = 'no-cache'
        unless exists $params{'Cache-Control'};

    my $content = exists $params{Content}
        ? $params{Content} : $params{Status};
    delete $params{Content};

    while (my ($key, $value) = each %params) {
        print "$key: $value\n";
    }
    print "\n";
    print $content;

    exit 0;
}

所以如果我得到你的代码仪式的其余部分：

use strict;
my $file = $ENV{'PATH_TRANSLATED'};
open (my $fh, '<', $file) or die 'cant open';
my $url = <$fh>;
chomp($url);
redirect_url($url);

会做的。

【讨论】：

你有没有在开头添加she-bang行，以及函数定义？你设置了可执行位吗？
没关系，完美运行。我有一个糟糕的use 声明，指向一个不存在的类。删除它，一切都修复了。