rebol2 vid 应用程序中的请求日期答案

【问题标题】：request-date in a rebol2 vid applicationrebol2 vid 应用程序中的请求日期
【发布时间】：2017-02-10 12:21:58
【问题描述】：

谁能告诉我为什么下面的代码不起作用？它应该在加载时在字段中设置日期，然后允许通过单击该字段来更改日期。我在 linux 上使用 rebol/view 2.7.8。实际上，我认为这段代码在几年前我使用 MS Windows 时可以工作，但由于某种原因不能在 linux 下工作。

博士

    rebol []
    trace true
    out: layout [
        style dater txt bold right [trans-date/date: copy (form now/date)] 48x24
        dater "T-Date:" trans-date: field 80x24 (form now/date) feel [
            engage: func [face action event][
                if action = 'up [
                    lv-dat: request-date/date/offset (now/date) 450x375
                    if lv-dat <> none [
                        trans-date/text: form lv-dat
                        show trans-date
                    ]
                ]
            ]
            show trans-date
        ]
    ]
    view out

【问题讨论】：

标签： rebol rebol2

【解决方案1】：

这是您的代码的清理版本：

Rebol []

out: layout compose/deep [
    style dater txt bold right 48x24
    dater "T-Date:"
    trans-date: field 80x24 (form now/date) feel [
        engage: func [face action event][
            if action = 'up [
                lv-dat: request-date/date/offset (now/date) 450x375
                if lv-dat [
                    face/text: form lv-dat
                    show face
                ]
            ]
        ]
    ]
]
view out

主要问题是在调用layout 之前缺少compose/deep 调用来评估paren 表达式。但是，这种方法不是初始化人脸属性的常用方法，您应该将初始化代码放在 VID 块的 do 部分，如下所示：

Rebol []

out: layout [
    style dater txt bold right 48x24
    dater "T-Date:"
    trans-date: field 80x24 feel [
        engage: func [face action event][
            if action = 'up [
                lv-dat: request-date/date/offset now/date 450x375
                if lv-dat [
                    face/text: form lv-dat
                    show face
                ]
            ]
        ]
    ]
    do [trans-date/text: form now/date]
]
view out

希望这会有所帮助。

【讨论】：