XSLT 包含两个句点

Question

我有一个使用无序列表显示导航的 HTML 文档。当它作为 XML 输出时，它不再使用列表，而是为每个链接分配一个<Description>。描述的工作方式是为主链接分配数字，如 100、200、300、400 等。这些子导航链接分配如下：200.100、200.200、200.300 等。

XML 如下所示：

<Items>
  <PgIndexElementItem>
      <Description>100</Description>
      <Title>This is the Title</Title>
  </PgIndexElementItem>
  <PgIndexElementItem>
      <Description>200</Description>
      <Title>This is the Title</Title>
  </PgIndexElementItem>
  <PgIndexElementItem>
      <Description>200.100</Description>
      <Title>This is the Title</Title>
  </PgIndexElementItem>
  <PgIndexElementItem>
      <Description>200.100.100</Description>
      <Title>This is the Title</Title>
  </PgIndexElementItem>
</Items>

如果你看最后一个 PgIndexElementItem，有三组数字。

我正在尝试使用 XSLT 重新创建无序列表。这是我迄今为止一直在做的事情：

<ul>
    <xsl:for-each select="//PgIndexElementItem">
        <xsl:if test="not(contains(Description, '.'))">
            <li><a href="{ResolvedURL/ServerRelative}"><xsl:value-of select="Title"/></a>
                <ul>
                    <xsl:for-each select="//PgIndexElementItem">
                        <xsl:if test="contains(Description, '.')">
                            <li><a href="{ResolvedURL/ServerRelative}"><xsl:value-of select="Title"/></a></li>
                        </xsl:if>
                    </xsl:for-each>
                </ul>
            </li>
        </xsl:if>
    </xsl:for-each>
</ul>

我的问题是，有没有办法指定 contains(Description 以两个句点为目标的描述，例如上面最后一个 PgIndexElementItem？

我希望我解释得足够好。我不知道如何使它不那么混乱。提前致谢！

编辑

o Graduate Program
   * How to Apply
   * Masters Program
        o M.A. Handbook
        o FAQs
        o Alumni
        o Masters Theses
        o Sample Thesis Proposals
   * M.A. Handbook
   * FAQs
   * Alumni
   * Masters Theses
   * Sample Thesis Proposals

Answer 1

你可以使用

<xsl:if test="contains(substring-after(Description, '.'), '.')">
    ...

测试一个元素是否有一个带有两个或更多句点的描述子元素。

但是，我会将您的 XSLT 更改为：

  <!-- this part replaces your <ul> code above -->
  <ul>
     <xsl:apply-templates
         select="//PgIndexElementItem[not(contains(Description, '.'))]" />
  </ul>      

更新了这个模板：

<!-- add this new template -->
<xsl:template match="PgIndexElementItem">
   <li>
      <a href="{ResolvedURL/ServerRelative}"><xsl:value-of select="Title"/></a>
      <xsl:variable name="prefix" select="concat(Description, '.')"/>
      <xsl:variable name="childOptions"
         select="../PgIndexElementItem[starts-with(Description, $prefix)
           and not(contains(substring-after(Description, $prefix), '.'))]"/>
      <xsl:if test="$childOptions">
         <ul>
            <xsl:apply-templates select="$childOptions" />
         </ul>
      </xsl:if>
   </li>
</xsl:template>

这将避免不必要的代码重复，以及不需要的空 <ul> 元素。

我对描述子项的解释方式做了一些假设......例如“200.100”应该出现在“200”下的子列表中，而不是“100”下。

Answer 2

使用：

string-length(Description) - string-length(translate(Description, '.',''))  = 2

这对任何数字 $n 都有效（而“substring-after”技术在一般情况下根本无法使用）：

string-length(Description) - string-length(translate(Description, '.',''))  = $n

Answer 3

我看起来您正在处理嵌套的 PgIndexElementItem 元素 - 如果它们嵌套在多个层中，您应该考虑重构您的 XSL 以使用递归模板（假设每个级别的 HTML 输出是可预测的）。

在编写时，您的 for-each 循环选择当前元素的所有 PgIndexElementItem 后代，然后在遇到内部 for-each 循环时再次执行此操作。可能不是你想要的。