如何识别包含嵌入图表的文档？

Question

我有一个适用于活动工作簿的 Excel 的 COM 加载项，虽然它大部分都可以工作，但我在一个特定的场景中遇到了问题。

如果我在使用插入->图表创建的 Word 2010 文档中有一个图表，那么当我单击图表工具->设计->编辑数据时，它会打开包含图表数据的工作簿。我的外接程序可以（大部分）使用该工作簿。

但是，我的加载项需要知道保存工作簿的文件夹，在这种情况下，我想使用 包含文档的文件夹（Word 文档或 PowerPoint演示文稿）已保存。但是，我找不到任何方法来获取有关容器文档的任何信息 - 事实上，我什至找不到方法来告诉我正在处理的工作簿 嵌入在文档中。

是否有任何方法可以让我访问容器文档？

Answer 1

我很确定通过Insert | Chart 功能区创建的图表不是链接文档，因此它没有.Path 属性。您应该不需要路径，您可以直接访问工作簿和图表对象：

要访问ChartData 工作簿/工作表对象，您可以执行以下操作：

Sub OpenChartData(shp as InlineShape)


Dim shp As InlineShape
Dim cht As Chart
Dim wb As ChartData

    If shp.Type = wdInlineShapeChart Then
        Set wb = shp.Chart.ChartData
        Set cht = shp.Chart  '## In case you need to manipulate the Chart options like Title, Axes, etc... you can use this variable.
        wb.Activate  '## Activate the chart's ChartData sheet

        ' do stuff to the worksheet

        wb.Workbook.Application.WindowState = -4140  '## Hide the ChartData when you're finished.
    End If

End Sub

评论更新：

图表数据是或者链接的工作簿，或者不是。如果它不是链接的工作簿，那么它作为具有完整路径的“已保存”文件等不存在于某处。

回答您的问题：

Are there any methods that would give me access to the container document?

您可以通过ChartData 对象访问容器文档。

但是，您不想使用此对象，因为您坚持或错误地理解该工作簿被“保存”在某处，而这仅仅是识别此工作簿保存在 何处 的问题，以便您的宏/加载项无需任何修改即可工作。

你的假设是错误的。工作簿没有保存在某个地方，它完全封装在 ChartData 对象中，它是 Microsoft Word 对象模型的一部分。

来自 MSDN

新对象 ChartData 已添加到 VBA 对象模型中，用于 Word 提供对基础链接或嵌入数据的访问 图表。每个图表都有与之相关联的用于绘制图表的数据 Word 中的图表。图表数据可以从外部链接 Excel 工作簿，或作为图表本身的一部分嵌入。图表数据 对象封装了对 Word 中给定图表数据的访问。为了 例如，下面的 VBA 代码示例显示，然后最小化， Word 中活动文档所包含的每个图表的图表数据。

http://msdn.microsoft.com/en-us/library/office/ff821389.aspx

所以，你的选择是：

1. 重新设计宏以与ChartData 对象兼容，或者
2. 在 Excel 中创建图表并作为 OLEObjects 插入/粘贴到 DOC，而不是使用 Word 的 Insert | Chart。
3. 尝试将以前使用 Word Insert | Chart 创建的所有图表转换为 OLEObjects。

进一步阅读：

Update Chart Data

Creating Charts with VBA

Answer 2

让我们再试一次......

然后创建另一个加载项（我将给出一个 XLAM 的示例），或者您可以将您的 COM 加载项修改为此，或者确保这个新加载项正在运行。此插件将捕获应用程序级 App_WorkbookActivate 事件，并检查新工作簿名称是否可能来自 Microsoft Word。

如果工作簿符合此条件，因为它正在触发 App_WorkbookActivate 事件，那么假设 MS Word 中的当前 ActiveDocument 是容器似乎相当安全。

然后，我们只需设置一些对象变量来捕获Word.Application，然后只需获取ActiveDocument，它是.Path，它是.Name，我们可以将这些值存储在命名变量中Excel 工作簿。

您可以在Names 管理器中查看它们，或者通过引用它们的名称.Names("docPath") 和.Names("docName") 以编程方式访问它们。

将其放入 XLAM 文件中的标准模块中：

Sub Auto_Open()
    Application.Run "ThisWorkbook.Workbook_Open" 'just in case
End Sub

以下代码位于 XLAM 文件的 ThisWorkbook 模块中：

Option Explicit
Private WithEvents App As Application
Dim dictWorkbooks As Object
Private Sub Workbook_Open()
    '## Instantiate the public variables for this Add-in:
    Set App = Application
    Set dictWorkbooks = CreateObject("Scripting.Dictionary")
End Sub

Private Sub App_WorkbookActivate(ByVal Wb As Workbook)
    '## Attempt to determine if a Workbook is opened from MS Word,
    '   and if so, store the container document's path & name in
    '   named variable/range in the Workbook.
    Dim wdApp As Object
    Dim wdDoc As Object
    Dim docPath As String
    Dim docName As String
    Dim w As Integer

    If Wb.Name Like "Chart in Microsoft Word" Then
        'Get out of here if we already have this workbook activated.
        If dictWorkbooks.Exists(Wb.Name) Then Exit Sub
        Set wdApp = GetObject(, "Word.Application")
        Set wdDoc = wdApp.ActiveDocument
        docPath = wdDoc.Path
        docName = wdDoc.Name
        dictWorkbooks.Add Wb.Name, docName

        With Wb
            On Error Resume Next
            .Names("docPath").Delete
            .Names("docName").Delete
            On Error GoTo 0
            .Names.Add Name:="docPath", RefersToR1C1:=docPath
            .Names("docPath").Comment = "A variable stores the parent DOC file's path"
            .Names.Add Name:="docName", RefersToR1C1:=docName
            .Names("docName").Comment = "A variable stores the parent DOC file's name"
        End With
    End If

End Sub
Private Sub App_WorkbookBeforeClose(ByVal Wb As Workbook, Cancel As Boolean)
    '## If you open multiple charts from the word document, without closing the Workbook
    ' they will be assigned unique names. However, if you open & close multiple Workbook
    ' they will all have the same name "Chart in Microsoft Word".  This method will
    ' remove an existing Key from our Dictionary when a workbook is closed, in order to
    ' prevent false matches.
    If dictWorkbooks.Exists(Wb.Name) Then _
        dictWorkbooks.Remove Wb.Name
End Sub