用 Perl 向地址中带有撇号的人发送电子邮件

Question

我目前正在尝试用 Perl 写一封电子邮件给其中有撇号但不知道如何发送的用户。这条线是这样的：

$to = "o'connell\@website.com";

这是我用来发送电子邮件的线路：

system("echo $message | mailx -s $subject $to ");

这是o'connell@website.com 的示例电子邮件。由于撇号，它不会发送它。我尝试了以下方法，但没有奏效。我正在使用mailx 发送电子邮件

$to = "o'connell\@website.com";
$to = "o''connell\@website.com";
$to = "o"'"connell\@website.com";

这些都不起作用。不过，我可以向电子邮件中没有电子邮件的人发送电子邮件。有什么建议吗？

Answer 1

这不是 Perl 问题，而是 shell 问题。您必须正确转义值：

system("echo $message | mailx -s $subject \"$to\" ");

或者，更具可读性：

system qq(echo $message | mailx -s $subject "$to");

我也想避开这个话题，你也应该非常小心 $message - 如果它包含怎么办

; rm -rf /

请参阅Task::Kensho::Email，了解如何直接从 Perl 发送电子邮件。

Answer 2

像 Andrzej 一样，我会说避免使用 shell。但是有一种更简单的方法可以做到这一点：

open(FH, "|-", "mailx", "-s", $subject, $to) or die "Can't mailx: $!";
print FH $message;
close(FH);

如果您提供命令及其参数以“|-”模式打开，open 和 close 将为您处理 execing 和 waitpiding。

来自perldoc -f open：

         The following blocks are more or less equivalent:

            open(FOO, "|tr '[a-z]' '[A-Z]'");
            open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
            open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
            open(FOO, "|-", "tr", '[a-z]', '[A-Z]');

            open(FOO, "cat -n '$file'|");
            open(FOO, "-|", "cat -n '$file'");
            open(FOO, "-|") || exec "cat", "-n", $file;
            open(FOO, "-|", "cat", "-n", $file);

        The last two examples in each block show the pipe as "list form",
        which is not yet supported on all platforms. A good rule of thumb
        is that if your platform has a real "fork()" (in other words, if
        your platform is Unix, including Linux and MacOS X), you can use
        the list form. You would want to use the list form of the pipe so
        you can pass literal arguments to the command without risk of the
        shell interpreting any shell metacharacters in them. However, this
        also bars you from opening pipes to commands that intentionally
        contain shell metacharacters, such as:

            open(FOO, "|cat -n | expand -4 | lpr")
                // die "Can't open pipeline to lpr: $!";

        See "Safe Pipe Opens" in perlipc for more examples of this.

...

        Closing any piped filehandle causes the parent process to wait for
        the child to finish, then returns the status value in $? and
        "${^CHILD_ERROR_NATIVE}".

Answer 3

你可以让 perl 直接执行 mailx 而无需“中间”的 shell。
[看看wdebeaum answer中更简单的实现]

$message="message\n";
$to='$to = 'o\'connell\@website.com';
$subject= "x's " . time(); # string with apostrophe and time mark for testing

# 分隔符在上面混淆后使stackoverflow语法着色工作

if( my $child_pid = open(my $TO_KID,   "|-")) {
   # I am the parent:
   print $TO_KID $message;
   close($TO_KID);
   waitpid $child_pid, 0;
} elsif(defined($child_pid)) {
   # I am the child; use STDIN/STDOUT normally
   exec 'mailx','-s',$subject,$to;
   die "couldn't exec mailx: $!";
}else{
   # $child_pid is undefined - fork (in open) failed
   die "can't fork: $!";
}

Answer 4

您不正确地构建了 shell 命令。使用以下内容：

use String::ShellQuote qw( shell_quote );

my $cmd1 = shell_quote('echo', $message);
my $cmd2 = shell_quote('mailx', '-s', $subject, $to);
system("$cmd1 | $cmd2");

但您可以避免使用echo 并通过使用以下内容来涉及 shell：

open(my $pipe, "|-", "mailx", "-s", $subject, $to)
   or die("Can't execute mailx: $!\n");
print($pipe $message);
close($pipe);

最好是使用旨在帮助您发送电子邮件的模块。