我有这样的数据：
A=5 B=8 . C=8
A=4 . . C=4
A=8 . . C=3
我需要检查文件中的所有列，如果找到letter=number（例如 A=5），我只需要打印number。如果缺少值 (.)，请跳过它。
所以输出应该是：
5 8 . 8
4 . . 4
8 . . 3
我会使用 awk：
awk -v OFS="\t" '{split($0,arr2,"="); print arr2[2]}' infile.txt
【问题讨论】：
使用 sed 是一种快速而肮脏的方法：
sed -e 's/[A-Z]\+=//g' infile.txt
这只是删除一个（一组）字母后跟等号的所有实例。
【讨论】：
\+ 是非标准的，因此在某些版本上需要-E 和+（或者只使用*，因为它也可以）。
使用 GNU awk 你可以这样做：
$ awk -F= -vRS='[ \t\n]+' '{printf "%s%s", (NF>1?$NF:$0), RT}' file
5 8 . 8
4 . . 4
8 . . 3
Awk 将它的输入分隔到记录中，并将记录分隔到字段中。使用-vRS='[ \t\n]+'，我们将记录分隔符设置为一系列空格、制表符或换行符。我们还将带有-F= 的字段分隔符设置为等号。所以本质上我们将输入分成记录，每条记录是一个单词，然后我们使用= 作为分隔符将记录分割成字段。
通过这部分'{printf "%s%s", (NF>1?$NF:$0), RT}'，我们打印所需的输出。对于每条记录，我们可以有两种情况：如果字段数（变量NF）大于一个，这意味着我们有一个等于，所以我们将记录的最后一个字段保留为$NF。如果记录有一个字段（不等于），我们保持字段不变。我们先打印想要的值，然后打印分割字段时匹配的分隔符，存储在RT变量中。
【讨论】：
RS 代表记录分隔符，它是一个正则表达式，用于指定如何拆分记录。 RT 是特定记录的记录分隔符的值。我添加了几段来解释这是如何工作的。如果还有什么不清楚的，请告诉我。
awk 对字段进行交互，如果字段以字母开头，则从开头剥离到 = 的部分，然后是 =，然后是末尾的任何数字：
awk '{for(i=1; i<=NF; i++) if($i~/^[A-Za-z]=[0-9]+$/) sub("^.*=", "", $i)}{print}'
如果你是一个单词而不是一个单词：
awk '{for(i=1; i<=NF; i++) if($i~/^[A-Za-z]+=[0-9]+$/) sub("^.*=", "", $i)}{print}'
示例：
$ cat file.txt
A=5 B=8 . C=8
A=4 . . C=4
A=8 . . C=3
$ awk '{for (i=1; i<=NF; i++) if ($i~/^[A-Za-z]=[0-9]+$/) sub("^.*=", "", $i)} { print }' file.txt
5 8 . 8
4 . . 4
8 . . 3
【讨论】：
awk '{for(i=1; i<=NF; i++) if($i~/^[A-Za-z]+=[0-9]+$/) sub("^.*=", "", $i)}{print}' file.txt >output.txt 将它保存在文件output.txt 或者如果你有GNU awk：awk -i inplace '{for(i=1; i<=NF; i++) if($i~/^[A-Za-z]+=[0-9]+$/) sub("^.*=", "", $i)}{print}' file.txt
这个 awk 单行与 gawk 一起工作：
awk -F'\\S*=' -v OFS="" '{$1=$1}7' file
5 8 . 8
4 . . 4
8 . . 3
想法是：通过设置FS删除FOO=
【讨论】：
awk '{gsub(/[A-Z]=/,"")}1' file
5 8 . 8
4 . . 4
8 . . 3
【讨论】：