将迭代的 fetch 替换为 BULK COLLECT

Question

有一个对象类型，表由该对象组成。 所以我们开始：

create or replace type lpu.someobj_o as object
(      
  name VARCHAR2(75),     
  enroll_date DATE,
  id NUMBER(12)
)

CREATE OR REPLACE TYPE lpu."SOMEOBJ_T" IS TABLE OF someobj_o;

还有一个通用的 PL/SQL 函数ETL principle。这是一段代码功能：

  for some_cursor_rec in some_cursor(startTime, recordInterval) loop
  open some_cur2(some_cursor_rec.name, some_cursor_rec.id);
  fetch some_cur2 into some_cursor_rec2;
  if some_cur2%rowcount > 0 then
    loop
      pipe row (
        lpu.someobj_o(
        id => some_cursor_rec2.id, 
        name => some_cursor_rec2.name, 
        enroll_date => some_cursor_rec2.enroll_date
      )
      );
      fetch some_cur2 into some_cursor_rec2;
      exit when some_cur2%notfound;
    end loop;      
  end if;
  close some_cur2;
end loop;

好的，所以问题是性能很小。如何提高完成此功能的速度？我读过BULK COLLECT 应该会提高性能。但是我如何在我的情况下使用它？我尝试过BULK COLLECT，但它给了我错误，即集合类型错误。 提前致谢！真心希望得到您的帮助！

Answer 1

如果您关心性能，那么您应该开始考虑组合两个光标。

当前您正在执行 some_cursor 中的查询一次，并且您在游标 some_cur2 中执行查询的次数与第一个查询中选择的行数一样多。这很可能是您的性能瓶颈。

如果您将两个查询合并为一个查询并执行游标 for 循环（仅执行一次查询），那么您将自动一次批量获取 100 行，因此可能不会有真正的需要手动将其转换为批量获取。

问候，
抢。

Answer 2

这是一个基本示例，如何将bulk collect into 与对象类型一起使用。

create or replace type someobj_o as object
(      
  name varchar2(75),     
  enroll_date date,
  id number(12)
);
/

create or replace type someobj_t is table of someobj_o;
/

create table someobj_table of someobj_o;

insert into someobj_table values(someobj_o('Joe', current_date, 100));
insert into someobj_table values(someobj_o('Jack', current_date, 101));
insert into someobj_table values(someobj_o('John', current_date, 102));

declare
  v_objs someobj_t;
begin
  select someobj_o(name, enroll_date, id)
    bulk collect into v_objs
    from someobj_table;

  dbms_output.put_line('number of objects in a collection = ' || v_objs.count);
end;
/

---

更新

同上，带光标：

declare
  type objcur_t is ref cursor;
  v_objcur objcur_t;
  v_objs someobj_t;
begin
  open v_objcur for
    select someobj_o(name, enroll_date, id)
    from someobj_table;

  fetch v_objcur bulk collect into v_objs;

  close v_objcur;

  dbms_output.put_line('number of objects in a collection = ' || v_objs.count);
end;
/