Oracle - 从引用游标中选择特定列

Question

我的情况：

• 我有一个名为 Table1 的表。它有很多列，其中之一是 Column1。我不知道其他列，它们有时甚至会发生变化。
• 有一个强类型引用游标类型，它返回 Table1%rowtype，名为 cur_Table1。
• 我有一个名为 SP1 的存储过程，它有一个类型为 cur_Table1 的 out 参数。我从另一个数据库调用这个 SP1 存储过程，该数据库只看到这个存储过程，而不是表或类型本身。

如何从返回的光标中只选择 Column1？

我知道我可以提取一条记录或与游标有多少列一样多的变量，但我只知道一列的存在，所以我不能声明完整的记录或正确数量的变量。

Answer 1

您可以使用 DBMS_SQL 来完成此操作，但它并不漂亮。

表格和样本数据（COLUMN1 的数字为 1 - 10）：

create table table1(column1 number, column2 date, column3 varchar2(1000), column4 clob);

insert into table1
select level, sysdate, level, level from dual connect by level <= 10;
commit;

带有打开引用光标并选择所有内容的过程的包：

create or replace package test_pkg is
    type cur_Table1 is ref cursor return table1%rowtype;
    procedure sp1(p_cursor in out cur_table1);
end;
/

create or replace package body test_pkg is
    procedure sp1(p_cursor in out cur_table1) is
    begin
        open p_cursor for select column1, column2, column3, column4 from table1;
    end;
end;
/

从引用游标中读取 COLUMN1 数据的 PL/SQL 块：

--Basic steps are: call procedure, convert cursor, describe and find columns,
--then fetch rows and retrieve column values.
--
--Each possible data type for COLUMN1 needs to be added here.
--Currently only NUMBER is supported.
declare
    v_cursor sys_refcursor;
    v_cursor_number number;

    v_columns number;
    v_desc_tab dbms_sql.desc_tab;
    v_position number;
    v_typecode number;
    v_number_value number;
begin
    --Call procedure to open cursor
    test_pkg.sp1(v_cursor);
    --Convert cursor to DBMS_SQL cursor
    v_cursor_number := dbms_sql.to_cursor_number(rc => v_cursor);
    --Get information on the columns
    dbms_sql.describe_columns(v_cursor_number, v_columns, v_desc_tab);

    --Loop through all the columns, find COLUMN1 position and type
    for i in 1 .. v_desc_tab.count loop
        if v_desc_tab(i).col_name = 'COLUMN1' then
            v_position := i;
            v_typecode := v_desc_tab(i).col_type;

            --Pick COLUMN1 to be selected.
            if v_typecode = dbms_types.typecode_number then
                dbms_sql.define_column(v_cursor_number, i, v_number_value);
            --...repeat for every possible type.
            end if;
        end if;
    end loop;

    --Fetch all the rows, then get the relevant column value and print it
    while dbms_sql.fetch_rows(v_cursor_number) > 0 loop
        if v_typecode = dbms_types.typecode_number then
            dbms_sql.column_value(v_cursor_number, v_position, v_number_value);
            dbms_output.put_line('Value: '||v_number_value);
        --...repeat for every possible type
        end if;
    end loop;   
end;
/

Answer 2

鉴于最初的问题，jonearles 的答案仍然是正确的，所以我将它标记为这样，但我最终做了一些完全不同的事情并且更好。

问题是/是我无法控制 SP1 的数据库，我只需要作为第 3 方客户端从其他地方调用它。现在我设法获得了不仅可以查看 SP 的权限，还可以查看光标的类型。我仍然看不到表格，但现在有一个更清洁的解决方案：

在另一个数据库中，我现在被授予查看此类型的权限：

type cur_Table1 is ref cursor return Table1%rowtype;

所以在我的数据库中我现在可以这样做：

mycursor OtherDB.cur_Table1;
myrecord mycursor%rowtype;
...
OtherDB.SP1(mycursor);
fetch mycursor into myrecord;
dbms_output.put_line(myrecord.Column1);

看，我仍然不需要访问表格，我只看到光标。关键是神奇的 %rowtype 也适用于游标，而不仅仅是表。它不适用于 sys_refcursor，但它适用于强类型。鉴于此代码，我不必关心另一侧是否有任何变化，我根本不必定义所有列或记录，我只需指定我感兴趣的一个列。

我真的很喜欢这种关于 Oracle 的 OOP 态度。

Answer 3

不知道这是否是一个选项，但不是更好的解决方案是创建一个返回您正在寻找的特定值的函数吗？这避免了发送额外数据的开销。或者，您可以定义一个光标，其中包含双方都知道的一组已知字段。