使用 Indy 恢复 HTTP 发布/上传

Question

我正在尝试使用 indy (HTTP Post) 恢复上传，代码如下所示（使用 Delphi 2010，Indy 10.4736）：

 IdHttp.Head('http://localhost/_tests/resume/large-file.bin');
 ByteRange           := IdHttp.Response.ContentLength + 1;

 // Attach the file to post/upload
 Stream              := TIdMultipartFormDataStream.Create;
 with Stream.AddFile('upload_file', 'D:\large-file.bin', 'application/octet-stream') do
 begin
      HeaderCharset  := 'utf-8';
      HeaderEncoding := '8';
 end;    // with

 with IdHTTP do
 begin
      IOHandler.LargeStream           := True;

      with Request do
      begin
           ContentRangeStart          := ByteRange;
           ContentRangeEnd            := (Stream.Size - ByteRange);
           ContentLength              := ContentRangeEnd;
           ContentRangeInstanceLength := ContentLength;
      end;    // with

      Post('http://localhost/_tests/resume/t1.php', Stream);
 end;    // with

但上传简历不起作用:(

我查看了Indy的代码，似乎IdIOHandler.pas

中的这个函数

TIdIOHandler.Write()

始终处理完整的流/文件（因为参数 ASize: TIdStreamSize 似乎始终为 0，根据代码表示发送完整的文件/流）。

这会阻止 indy 恢复上传。

我的问题是：是否可以避免发送完整的文件？

设置内容范围没有改变任何东西。我还调整了 indy 的代码（修改了 3 行）以使 indy 遵守内容范围/流位置，但它有问题，并且 indy 总是挂在 IdStackWindows.pas 中，因为这里有无限超时：

TIdSocketListWindows.FDSelect()

Answer 1

正如我在your earlier question 中告诉你的，你必须发布一个TStream，其中包含要上传的剩余文件数据。不要使用TIdMultipartFormDataStream.AddFile()，因为这会发送整个文件。请改用TStream 的TIdMultipartFormDataStream.AddFormField() 重载版本。

而TIdHTTP 的设计并非尊重ContentRange... 属性。大多数Request 属性仅设置相应的HTTP 标头，它们不会影响数据。这就是你的编辑破坏它的原因。

试试这个：

IdHttp.Head('http://localhost/_tests/resume/large-file.bin');
FileSize := IdHttp.Response.ContentLength;

FileStrm := TFileStream.Create('D:\large-file.bin', fmOpenRead or fmShareDenyWrite);
try
  if FileSize < FileStrm.Size then
  begin
    FileStrm.Position := FileSize;

    Stream := TIdMultipartFormDataStream.Create;
    try
      with Stream.AddFormField('upload_file', 'application/octet-stream', '', FileStrm, 'large-file.bin') do
      begin
        HeaderCharset  := 'utf-8';
        HeaderEncoding := '8';
      end;

      with IdHTTP do
      begin
        with Request do
        begin
          ContentRangeStart := FileSize + 1;
          ContentRangeEnd   := FileStrm.Size;
        end;

        Post('http://localhost/_tests/resume/t1.php', Stream);
      end;
    finally
      Stream.Free;
    end;
  end;
finally
  FileStrm.Free;
end;

话虽如此，这是对 HTTP 和 multipart/form-data 的严重误用。对于初学者来说，ContentRange 值在错误的位置。您将它们应用于整个Request，这是错误的。它们需要在FormField 上应用，但TIdMultipartFormDataStream 目前不支持。其次，multipart/form-data 无论如何都不是为了这样使用而设计的。从头开始上传文件很好，但不能恢复损坏的上传。你真的应该停止使用TIdMultipartFormDataStream，直接将文件数据传递给TIdHTTP.Post()，就像我suggested earlier一样，例如：

FileStrm := TFileStream.Create('D:\large-file.bin', fmOpenRead or fmShareDenyWrite);
try
  IdHTTP.Post('http://localhost/_tests/upload.php?name=large-file.bin', FileStrm);
finally
  FileStrm.Free;
end;

.

IdHTTP.Head('http://localhost/_tests/files/large-file.bin');
FileSize := IdHTTP.Response.ContentLength;

FileStrm := TFileStream.Create('D:\large-file.bin', fmOpenRead or fmShareDenyWrite);
try
  if FileSize < FileStrm.Size then
  begin
    FileStrm.Position := FileSize;
    IdHTTP.Post('http://localhost/_tests/resume.php?name=large-file.bin', FileStrm);
  end;
finally
  FileStrm.Free;
end;

我已经explained earlier 如何在 PHP 中访问原始的POST 数据。