创建 TThread 数组时访问冲突

Question

我正在创建一个多线程应用程序，它创建了一个 TThread 类的动态数组，但对我来说神秘的是它会导致错误“访问冲突”到“创建”

代码形式：

Unit UNT_Main;

Interface

Uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, UNT_Socks;

Type
  TFRM_Main = Class(TForm)
    Procedure FormCreate(Sender: TObject);
  Private
    Procedure OnUpload(Success: Boolean; SockAction: TSockAction);
  Public
    { Public declarations }
  End;

Var
  FRM_Main: TFRM_Main;
  Socks: Array Of TSocks;
  SA: Array Of TSockAction;

Implementation

{$R *.dfm}

Procedure TFRM_Main.OnUpload(Success: Boolean; SockAction: TSockAction);
Begin
  ShowMessage(SockAction.Response);
End;

Procedure TFRM_Main.FormCreate(Sender: TObject);
Var
  I: Integer;
Begin

  SetLength(Socks, 5);
  SetLength(SA, 5);

  For I := 0 To High(Socks)-1 Do
  Begin
    SA[I].SUrl := 'http://google.com.co';
    Socks[I].Create(SA[I]);
    Socks[I].OnUpload := Self.OnUpload;
    Socks[I].Start;
  End;

End;

End.

代码 UNT_Socks：

Unit UNT_Socks;

Interface

Uses Classes, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient, IdHTTP;

// action script
Type
  TSockAction = Record
    SUrl: String;
    Response: String;
  End;

  // Eventos
Type
  // on upload event
  TUpload = Procedure(Success: Boolean; SockAction: TSockAction) Of Object;

  // Clase Socks, ejecuta las acciones
Type
  TSocks = Class(TThread)
    // Http indy sock
    Http: TIdHTTP;
    // action script
    FAtnSck: TSockAction;
    // Temp boolean response
    FbTempRet: Boolean;
  Private
    { Eventos }
    FOnUpload: TUpload;
    { Destructor }
    { Metodos & Funciones }
    Function UploadFile: Boolean;
    { Eventos }
    Procedure DoUpload;
  Protected
    Procedure Execute; Override;
  Public
    { Constructor }
    Constructor Create(SockAction: TSockAction);
    { Eventos }
    Property OnUpload: TUpload Read FOnUpload Write FOnUpload;
  End;

Implementation

{ Constructor }
Constructor TSocks.Create(SockAction: TSockAction);
Begin
  Inherited Create(True);

  FAtnSck := SockAction; // <===== Access Violation Here!
  Http := TIdHTTP.Create(Nil);
End;

{ Eventos }
Procedure TSocks.DoUpload;
Begin
  // check if the event is assign
  If Assigned(FOnUpload) Then
    // call it
    FOnUpload(FbTempRet, FAtnSck);
End;

{ Execute }
Procedure TSocks.Execute;
Begin

  FbTempRet := UploadFile;
  Synchronize(DoUpload);

End;

Function TSocks.UploadFile: Boolean;
Var
  SRes: String;
Begin

  Try
    With Http Do
      FAtnSck.Response := Get(FAtnSck.SUrl);
  Except
    Result := False;
  End;

  Result := True;
End;

End.

可能出了什么问题？

谢谢。

Answer 1

您的创建循环中有 2 个错误：

1) 当您应该循环到 High(Socks) 时，您正在循环到 High(Socks)-1。您正在分配 5 个元素的数组，但只初始化其中的 4 个。不要将 -1 与 High() 一起使用，而应与 Length() 一起使用。

2) 您在滥用TSocks.Create()，这就是您获得 AV 的原因。您将其调用为实例方法而不是构造函数，但尚未构造任何实例，因此崩溃了。

改用这个：

For I := 0 To High(Socks) Do
Begin
  SA[I].SUrl := 'http://google.com.co';
  Socks[I] := TSocks.Create(SA[I]); // <-- here
  Socks[I].OnUpload := Self.OnUpload;
  Socks[I].Start;
End;

Answer 2

代替

Socks[I].Create(SA[I]);

你应该使用

Socks[I]:= TSocks.Create(SA[I]);

一些小提示：

为什么是高（袜子）-1？

Uploadfile 的结果是否总是 True？

需要释放Http吗？

Answer 3

我同意 Remy。UNT_Socks 中的 TSocks 也有内存泄漏。Http(TIdHttp),FAtnSck(TSockAction) 字段在线程终止后不是空闲的。

在 TSock 的构造函数中设置 FreeOnTermiate

Constructor TSocks.Create(SockAction: TSockAction);
Begin
  Inherited Create(True);
  FreeOnTerminate:=True;
  FAtnSck := SockAction;  
  Http := TIdHTTP.Create(Nil);
End;

然后重写 TSock 的析构函数

 Destructor TSocks.Destroy;
 Begin

   SockAction.Free; // <===== if needed
   Http.Free;
   Inherited;
 End;