TIdTCPServer OnExecute 多次触发

Question

我有一个应用程序从另一个应用程序接收 TCP 套接字连接，处理通过套接字流式传输的内容，根据接收到的数据构建请求，使用 TIdHTTP 将请求发送到外部服务器，处理响应，并将 ack 发送回 tcp 客户端。

procedure TMyClass.TCPExecute(AContext: TIdContext);
var
  s: AnsiString;
begin
  s := TransferTCPBytesToString(AContext.Connection.IOHandler);
  // test string for terminating characters
  if Pos(#28#13, s) > 0 then
  begin
  //********PROBLEM: THIS WILL BE CALLED MULTIPLE TIMES 
  //********WITH THE SAME COMPLETE DATA STREAM CONTENT!
    BuildAndSendExternalRequest(s);
    AContext.Connection.IOHandler.InputBuffer.Clear;
    // send the response back to tcp client
    WriteTCPResponse(AContext.Connection.IOHandler);
  end;
end;

function TMyClass.TransferTCPBytesToString(AnIOHandler: TIdIOHandler): AnsiString;
begin
  if AnIOHandler.InputBufferIsEmpty then
    Exit;
  // read message from tcp client connection
  AnIOHandler.ReadBytes(FTCPBytes, AnIOHandler.InputBuffer.Size, True);
  SetLength(Result, Length(FTCPBytes));
  // copy message bytes to string
  Move(FTCPBytes[0], Result[1], Length(FTCPBytes));
end;

procedure TMyClass.WriteTCPResponse(AnIOHandler: TIdIOHandler);
var
  bytes: TBytes;
begin
  // FTCPBytes contains data from tcp client
  // bytes will contain processed response from external server
  BuildACK(FTCPBytes,bytes);
  // FTCPBytes now contains ACK data
  AnIOHandler.WriteDirect(FTCPBytes, Length(FTCPBytes));
end;

请求/响应周期成功完成；发送回 tcp 客户端请求者的响应是正确的，进程按预期执行和完成。

但是，由于 OnExecute 事件会使用相同的数据多次触发，因此会接收、构建、发送、确认两个请求等。

在查看 tcp 客户端应用程序上的日志时，日志仅显示正在发送的一个请求。不知道这里发生了什么。但我需要确保请求/响应周期是 1-1，而不是 1-many！

谢谢。

Answer 1

OnExecute 事件多次触发 ...

它应该是，因为它是一个 循环 事件。只要连接处于活动状态，循环就会运行。 OnExecute 事件处理程序中的代码负责决定每次循环迭代会发生什么。

理想情况是事件处理程序从客户端接收到 1 条消息，将 1 个响应发送回客户端，然后退出，以便下一次循环迭代准备好处理下一个请求/响应对。

根据您的描述，您正在尝试这样做，但显示的代码处理得不是很好。最值得注意的是，该代码没有考虑 TCP 的字节流性质。它不会区分一个传入消息与另一个消息。它只是将整个IOHandler.InputBuffer 内容原样转储到AnsiString 中（为什么是AnsiString？），如果AnsiString 恰好包含分隔符#28#13，那么您正在处理整个AnsiString 和然后将其丢弃，丢失分隔符之后收到的任何内容（即下一条消息的一部分）。如果AnsiString 不包含分隔符，那么您仍然会丢弃AnsiString，从而在分隔符到达之前丢失当前收到的所有数据。

如果你所有的消息都被#28#13分隔，那么我建议你使用IOHandler.ReadLn()或IOHandler.WaitFor()的方法来正确阅读每条消息。

此外，您在输入和输出中重复使用相同的FTCPBytes 成员，这本身就是错误的，但如果您有多个客户端连接，您也没有为其提供任何并发访问保护。

话虽如此，请尝试更多类似的东西：

procedure TMyClass.TCPConnect(AContext: TIdContext);
begin
  AContext.Connection.IOHandler.DefStringEncoding := IndyTextEncoding_8Bit;
end;

procedure TMyClass.TCPExecute(AContext: TIdContext);
var
  s: String;
  response: TIdBytes:
begin
  s := TransferTCPBytesToString(AContext.Connection.IOHandler);
  BuildAndSendExternalRequest(s, response);
  // send the response back to tcp client
  WriteTCPResponse(AContext.Connection.IOHandler, response);
end;

function TMyClass.TransferTCPBytesToString(AnIOHandler: TIdIOHandler): String;
begin
  // read message from tcp client connection
  Result := AnIOHandler.ReadLn(#28#13);
  or:
  Result := AnIOHandler.WaitFor(#28#13);
end;

procedure TMyClass.BuildAndSendExternalRequest(const Msg: String; var Response: TIdBytes);
begin
  // send Msg to external server as needed...
  // store response bytes in Response...
end;

procedure TMyClass.WriteTCPResponse(AnIOHandler: TIdIOHandler; const Response: TIdBytes);
var
  bytes: TIdBytes;
begin
  // Response contains processed response from external server
  BuildACK(bytes, Response);
  // bytes now contains ACK data
  AnIOHandler.Write(bytes);
end;

...使用相同的数据

鉴于您显示的代码，这是不可能的。在TransferTCPBytesToString() 中对IOHandler.ReadBytes() 的调用正在读取并丢弃来自IOHandler.InputBuffer 的所有字节，因此当稍后再次调用TransferTCPBytesToString() 时，相同的字节不可能仍然存在于该缓冲区中。因此，您可以一遍又一遍地看到相同数据的唯一方法是客户端一开始就一遍又一遍地发送相同的数据。