在 Delphi XE 中使用 Indy 发送电子邮件时出现 STARTTLS 错误

Question

我正在尝试使用以下代码从我的应用程序发送电子邮件：

  Var
  MailMessage : TIdMessage;
  SMTP        : TIdSMTP
   .
   .
   .
 //setup SMTP
 SMTP.Host := 'smtp.gmail.com';
 SMTP.Port := 25;
 //setup mail message
 MailMessage.From.Address := 'fromMe@gmail.com';
 MailMessage.Recipients.EMailAddresses := 'ToSomeOne@hotmail.com';
 MailMessage.Subject := 'Test';
 MailMessage.Body.Text := 'Hello, It is Just for test';

 SMTP.Connect;
 SMTP.Send(MailMessage);

当我运行它时，它会产生以下错误

**ERROR: Must issue a STARTTLS command first. i29sm34080394wbp.22**

我该如何解决这个问题？

Answer 1

smtp.gmail.com 强制您使用使用 STARTTLS 的加密连接。

Indy 9 不直接支持 STARTTLS，但 indy 10 支持。

在 Indy 10 中，在连接到服务器之前，您必须分配一个 启用S​​SL的IOHandler，如TIdSSLIOHandlerSocketOpenSSL，

见：http://www.indyproject.org/docsite/html/frames.html?frmname=topic&frmfile=TIdSSLIOHandlerSocketOpenSSL.html

添加以下代码：

var
...
SSLHandler: TIdSSLIOHandlerSocketOpenSSL;

SSLHandler:= TIdSSLIOHandlerSocketOpenSSL.Create(Form1);
SMTP.IOHandler:= SSLHandler;
SMTP.UseTLS:= utUseExplicitTLS;
SMTP.Username:= 'username';
SMTP.Password:= 'password';
SMTP.Port:= 587; 

如果您只是将 SMTP 发送到未加密的 SMTP 处理程序（您的 ISP 的 SMTP），您将不会遇到此问题。

Answer 2

该错误是因为 Gmail 使用 SSL 和 TLS。您将需要使用 Indy 的 SSL IO 处理程序以及适合您的 Indy 版本的 OpenSSL DLL's。

有一个让这个工作的教程here。

Answer 3

通过将答案放在一起，您可以获得以下代码。不要忘记 Nathanial Woolls 提到 here 将 libeay32.dll 和 ssleay32.dll 库从 here 放到您的项目文件夹或 following places 的路径中。

uses
  IdMessage, IdSMTP, IdSSLOpenSSL, IdGlobal, IdExplicitTLSClientServerBase;

procedure SendEmail(const Recipients: string; const Subject: string; const Body: string);
var
  SMTP: TIdSMTP;
  Email: TIdMessage;
  SSLHandler: TIdSSLIOHandlerSocketOpenSSL;
begin
  SMTP := TIdSMTP.Create(nil);
  Email := TIdMessage.Create(nil);
  SSLHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);

  try
    SSLHandler.MaxLineAction := maException;
    SSLHandler.SSLOptions.Method := sslvTLSv1;
    SSLHandler.SSLOptions.Mode := sslmUnassigned;
    SSLHandler.SSLOptions.VerifyMode := [];
    SSLHandler.SSLOptions.VerifyDepth := 0;

    SMTP.IOHandler := SSLHandler;
    SMTP.Host := 'smtp.gmail.com';
    SMTP.Port := 587;
    SMTP.Username := 'yourusername@gmail.com';
    SMTP.Password := 'yourpassword';
    SMTP.UseTLS := utUseExplicitTLS;

    Email.From.Address := 'yourusername@gmail.com';
    Email.Recipients.EmailAddresses := Recipients;
    Email.Subject := Subject;
    Email.Body.Text := Body;

    SMTP.Connect;
    SMTP.Send(Email);
    SMTP.Disconnect;

  finally
    SMTP.Free;
    Email.Free;
    SSLHandler.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  SendEmail('recipient@whatever.com', 'Subject', 'Body');
end;

希望有帮助