VBA 条件格式

Question

我正在努力寻找一种通过 VBA 应用条件格式规则的优雅方法。我更喜欢 VBA，因为 a) 规则将适用于多个工作表，b) 它可以防止在工作表之间复制/粘贴时出现 CF 重复问题。

我有一份库存物品清单，所有物品都保存在不同的位置。我想使用以下格式根据位置进行格式化：

字体颜色（每个位置都会改变）；上边框（与字体颜色相同）；底部边框（与字体颜色相同）

此外，范围需要是动态的，因为对于每个工作表，它适用于该工作表上的表格。我想对每个适用的工作表应用相同的代码，而不是对每个工作表的表名进行硬编码。

任何帮助将不胜感激。

---

--更新-- 我尝试修改 J_V 的代码 here，但在公共子的 r.FormatConditions.Add Type:=xlExpression, Formula1:=formula 上收到“运行时错误'5'：无效的过程调用或参数”。我不确定边界上的最后一位是否正确，因为运行时会停止宏。我还需要处理动态表引用，但我一次只处理一个问题。

Sub ConditionalFormatting()

Dim myRange As Range
Set myRange = ThisWorkbook.Sheets("Widget1").Range("Widget1_table[Location]")

myRange.FormatConditions.Delete

Call FormatRange(myRange, 10, "=$E5="Warehouse1")
Call FormatRange(myRange, 11, "=$E5="Warehouse2")
Call FormatRange(myRange, 13, "=$E5="Warehouse3")

End Sub

Public Sub FormatRange(r As Range, color As Integer, formula As String)
r.FormatConditions.Add Type:=xlExpression, Formula1:=formula
r.FormatConditions(r.FormatConditions.Count).Font.colorindex = color

With r.FormatConditions(1).Borders(xlTop)
    .LineStyle = xlContinuous
    .Color = color
    .TintAndShade = 0
    .Weight = xlThin
End With
With r.FormatConditions(1).Borders(xlBottom)
    .LineStyle = xlContinuous
    .Color = color
    .TintAndShade = 0
    .Weight = xlThin
End With
r.FormatConditions(1).StopIfTrue = False

End Sub

Answer 1

问题实际上不在Sub FormatRange 内，而在于您在Sub ConditionalFormatting 内调用公式时分配公式的方式。该公式包含一个字符串，因此引号必须像这样加倍。

Sub ConditionalFormatting()
    Dim myRange As Range
    Set myRange = ThisWorkbook.Sheets("Widget1").Range("Widget1_table[Location]")

    myRange.FormatConditions.Delete

    Call FormatRange(myRange, 10, "=$E5=""Warehouse1""")
    Call FormatRange(myRange, 11, "=$E5=""Warehouse2""")
    Call FormatRange(myRange, 13, "=$E5=""Warehouse3""")
End Sub

至于第二个宏，当您添加一个新条件时，它会进入队列的底部。如果您查看创建 CF 规则的记录输出，您会看到它通常包含该行，

    Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority

这会将 CF 规则放在队列的顶部，以便之后可以将其称为 .FormatConditions(1)。如果您不希望它位于队列顶部，则必须将其称为队列中的 last，如下所示。

Public Sub FormatRange(r As Range, clr As Integer, frml As String)
    r.FormatConditions.Add Type:=xlExpression, Formula1:=frml
    r.FormatConditions(r.FormatConditions.Count).Font.ColorIndex = clr

    With r.FormatConditions(r.FormatConditions.Count).Borders(xlTop)
        .LineStyle = xlContinuous
        .ColorIndex = clr
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With r.FormatConditions(r.FormatConditions.Count).Borders(xlBottom)
        .LineStyle = xlContinuous
        .ColorIndex = clr
        .TintAndShade = 0
        .Weight = xlThin
    End With
    r.FormatConditions(r.FormatConditions.Count).StopIfTrue = False
End Sub

我还将您的边框 .Color 分配更改为 .ColorIndex，因为 10、11 和 13 似乎是 * 的 ColorIndex 标识符绿色、蓝色和紫色。元音已从变量名称中删除，以避免与集合属性的名称冲突。