【问题标题】:In Perl, how can I find the index of a given value in an array?在 Perl 中,如何在数组中找到给定值的索引?
【发布时间】:2010-12-27 07:25:12
【问题描述】:
$VAR1 = [
          '830974',
          '722065',
          '722046',
          '716963'
        ];

如何计算值“722065”的数组索引?

【问题讨论】:

  • 只需用 for 循环查找即可。如果数组中有两个相等的值怎么办?
  • 您尝试过什么吗?这是作业吗?
  • @jsoverson:我是 perl 新手。自学项目。
  • 从 Perl 5.10 开始,你也可以使用my ($index) = grep { $array[$_] ~~ $element } 0 .. $#array;。见这里:stackoverflow.com/a/3222653/111036

标签: perl arrays


【解决方案1】:

List::MoreUtils 中的 firstidx 函数可以提供帮助:

use strict;
use warnings;
use List::MoreUtils qw(firstidx);

my @nums = ( '830974', '722065', '722046', '716963' );
printf "item with index %i in list is 722065\n", firstidx { $_ eq '722065' } @nums;

__END__
列表中索引为 1 的项目是 722065

【讨论】:

  • 如果你想定位多个这样的索引,你可以使用 List::MoreUtils::indexes。
【解决方案2】:

使用List::Util,它是一个核心模块,不像List::MoreUtils,它不是:

use List::Util qw(first);

my @nums = ( '830974', '722065', '722046', '716963' );
my $index = first { $nums[$_] eq '722065' } 0..$#nums;

【讨论】:

    【解决方案3】:

    以下是查找给定值出现的所有位置的方法:

    #!/usr/bin/perl
    
    use strict;
    use warnings;
    
    my @x = ( 1, 2, 3, 3, 2, 1, 1, 2, 3, 3, 2, 1 );
    my @i = grep { $x[$_] == 3 } 0 .. $#x;
    print "@i\n";
    

    如果你只需要第一个索引,你应该使用List::MoreUtils::first_index。

    【讨论】:

    • 老实说。不再提及 $[。它晦涩难懂,IIRC 已被弃用,没有诚实的理由使用它。
    • 这是 Perl 的街头信誉材料,我想 :-)
    【解决方案4】:

    如果您只需要查找一项,请按照其他人所说的使用firstidx。

    如果您需要进行多次查找,请建立索引。

    如果您的数组项是唯一的,则构建索引非常简单。但是构建一个处理重复项目的难度并不大。两者的例子如下:

    use strict;
    use warnings;
    
    use Data::Dumper;
    
    # Index an array with unique elements.
    my @var_uniq  = qw( 830974 722065 722046 716963 );
    my %index_uniq  = map { $var_uniq[$_] => $_ } 0..$#var_uniq;
    
    # You could use hash slice assinment instead of map:
    # my %index_uniq;
    # @index_uniq{ @var_uniq } = 0..$#var_uniq
    
    my $uniq_index_of_722065   = $index_uniq{722065};
    print "Uniq 72665 at: $uniq_index_of_722065\n";
    print Dumper \%index_uniq;
    
    # Index an array with repeated elements.
    my @var_dupes = qw( 830974 722065 830974 830974 722046 716963 722065 );
    my %index_dupes;
    for( 0..$#var_dupes ) {
        my $item = $var_dupes[$_];
    
        # have item in index?
        if( $index_dupes{$item} ) {
            # Add to array of indexes
            push @{$index_dupes{$item}}, $_;
        }
        else {
            # Add array ref with index to hash.
            $index_dupes{$item} = [$_];
        }
    }
    
    # Dereference array ref for assignment:
    my @dupe_indexes_of_722065 = @{ $index_dupes{722065} };
    
    print "Dupes 722065 at: @dupe_indexes_of_722065\n";
    print Dumper \%index_dupes;
    

    【讨论】:

      【解决方案5】:

      这是使用哈希进行反向查找的仓促书面尝试。

      my $VAR1 = [ '830974', '722065', '722046', '716963' ];
      
      my %reverse;
      $reverse{$VAR1->[$_]} = $_ for 0 .. @$VAR1 - 1;
      
      print $reverse{722065};
      

      这不考虑具有重复值的数组。我不赞成将此解决方案用于生产代码。

      【讨论】:

      • 在重复值的情况下,您只会得到第一个匹配的元素。如果不止一次查询一个长期存在的数组,这将非常有用。
      • 我不确定是否看懂了上面的评论,但是代码的写法,在重复值的情况下,最高索引获胜。
      【解决方案6】:

      查看Perl FAQ

      【讨论】:

      • RRTFM-ing(重新阅读精美的手册)是一种非常有益的体验。我第一次阅读文档时,大部分内容都在我脑海中浮现。随后的每一次阅读都揭示了新的意义。通过(重新)阅读手册可以学到的东西数量之多令人惊讶!
      • 如果大多数人至少读过一次我就很满足了。人们不断询问常见问题解答的相关性,而 StackOverflow 一直是一个很棒的自然实验:每个人都会重新提出常见问题解答问题。
      • @daotoad:可能是因为我一直在更改关于您的常见问题解答。 :)
      【解决方案7】:
      use strict;
      use Data::Dumper;
      
      sub invert
      {
       my $i=0;
       map { $i++ => $_ } @_;
      }
      
      my @a = ('a','b','c','d','e');
      
      print Dumper @a;
      
      print Dumper invert @a;
      

      【讨论】:

      • 使用严格;使用 Data::Dumper;子镜像 { 我的 $i=0;地图 { $i++ => \$_ } @{ shift @_ };我的@a = ('a','b','c','d','e');我的 %b = 镜像 \@a;打印自卸车@a;打印转储器 %b; $a[1] = '哇...';打印自卸车@a;打印转储器 %b; $a[3] = '我知道!';打印自卸车@a;打印自卸车 %b;
      猜你喜欢
      • 2016-06-25
      • 1970-01-01
      • 2013-11-02
      • 2014-06-03
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      • 1970-01-01
      相关资源
      最近更新 更多