特定字母后的 SUMIF 条件答案

【问题标题】：SUMIF condition following a specific letter特定字母后的 SUMIF 条件
【发布时间】：2014-10-23 13:41:59
【问题描述】：

我正在尝试在SUMIF 公式中建立一个条件，它会检查字母 u 之后的下一个字母是数字。我尝试了ISNUMBER，设置一个条件来检查它是否大于 1 或 1-9 之间的数字。

我需要扩展这个公式

=SUMIF(sheety!$A1:$A, 'sheetx'$C338&"u"&[get it it to check that the
 first one after is a number], sheety)

有什么想法吗？

【问题讨论】：

【解决方案1】：

此公式可能无法满足您的确切要求，但它可能会帮助您走上正确的道路。

{=SUM(IF(ISNUMBER(VALUE(MID(A2:A5,FIND("u",A2:A5)+1,1)))=TRUE,VALUE(MID(A2:A5,FIND("u",A2:A5)+1,1))))}

大括号，因为您必须按Ctrl + Shift + Enter，而不仅仅是Enter。

让我们分解一下

这是数据

    Col A
1   data
2   xux
3   xu1
4   u9
5   u5

首先我们需要找出“u”在字符串中的位置：

{=FIND("u",A2:A5)}

这将返回数组：2,2,1,1

然后我们展开返回“u”后面的字符（根据第一个“u”的位置，假设数字只有1个字符）

{=MID(A2,
         FIND("u",A2)
  +1,1)}

这将返回数组：x,1,9,5

然后我们可以展开测试看看是不是数字

{=ISNUMBER(
           VALUE(
                 MID(A2,FIND("u",A2)+1,1)
                 )
           )}

这将返回数组：FALSE,TRUE,TRUE,TRUE

现在我们可以根据标准求和。

 {=SUM(
       IF(
          ISNUMBER(VALUE(MID(A2:A5,FIND("u",A2:A5)+1,1)))=TRUE
          ,VALUE(MID(A2:A5,FIND("u",A2:A5)+1,1))))}

【讨论】：

【解决方案2】：

你能用一个吗？对于这样的单个字符

=SUMIF(sheety!$A:$A,'sheetx'!$C338&"u?",sheety!$B:$B)

这不会检查实际数字，但除非您还有在“u”后面带有字母的值，否则它应该可以正常工作。注意：我假设那个数字后面不会有任何内容，如果有则添加另一个通配符，这次 *

要显式检查数字，请尝试如下：

=SUM(SUMIF(sheety!$A:$A,'sheetx'!$C338&"u"&{0,1,2,3,4,5,6,7,8,9},sheety!$B:$B))

【讨论】：

【解决方案3】：

您可以像这样在“u”之后立即检查数字 1 字符，其中要搜索的字符串在单元格 B1 中，而公式进入单元格 A1：

="'sheetx"&"u"&IF(ISNUMBER(VALUE(MID(B1,1+SEARCH("u",B1),1))),
VALUE(MID(B1,1+SEARCH("u",B1),1)),"")&"!"

我不确定我是否完全理解您希望搜索的字符串在哪里（我假设它是某个其他单元格）。

如果您提供屏幕截图或更详细的示例，说明 SUMIF 实际汇总的内容以及您期望标准如何发挥作用，我可以进一步提供帮助。

【讨论】：