VBA中的条件格式单元格

Question

我正在有条件地格式化一系列单元格。我想做大于和小于另一个单元格值。我在网上找到了这段代码，可以让我这样做，但我想知道如果条件单元格为空白，是否有办法跳过格式化。

示例：如果值大于“D14”+“E14”，我想将“G14”突出显示为红色。反之亦然。如果“E14”的值为空白，它仍然会变为红色，因为它的行为就像它是零一样。

这是我的代码：

'Format Measured
 Dim rg As Range
 Dim cond1 As FormatCondition, cond2 As FormatCondition, cond3 As FormatCondition
 Set rg = Range("G14", Range("G14").End(xlDown))

'clear any existing conditional formatting
rg.FormatConditions.Delete

'define the rule for each conditional format
Set cond1 = rg.FormatConditions.Add(xlCellValue, xlGreater, "=$D14+$E14+$H14")
Set cond2 = rg.FormatConditions.Add(xlCellValue, xlLess, "=$D14-$F14")

'define the format applied for each conditional format
With cond1
.Font.FontStyle = "Bold"
.Font.Color = vbRed
End With

With cond2
.Font.FontStyle = "Bold"
.Font.Color = vbRed
End With

Answer 1

您可以通过多种方式执行此操作，但根据我的评论，例如：

Set rg = Range("D14", Range("G14").End(xlDown))
Set rg = Intersect(rg.Columns(1).SpecialCells(2).Rows.EntireRow, Range("G:G"))

我也会考虑明确您的范围对象，考虑引用 Sheet 对象。

顺便说一句，如果您还想避免E14 为空，您可以扩展Intersect：

Set rg = Intersect(rg.Columns(1).SpecialCells(2).Rows.EntireRow, rg.Columns(2).SpecialCells(2).Rows.EntireRow, Range("G:G"))

显然，另一个答案可能是关于如何使用公式作为条件来检查单元格是否为 '""`

Answer 2

提出使用公式的替代解决方案：

Sub Test()
    Dim rg As Range
    Dim cond1 As FormatCondition, cond2 As FormatCondition, cond3 As FormatCondition
    Set rg = Range("G14", Range("G14").End(xlDown))

    'clear any existing conditional formatting
    rg.FormatConditions.Delete

    'define the rule for each conditional format
    Set cond1 = rg.FormatConditions.Add(xlExpression, , "=AND($G14>$D14+$E14,$E14<>"""")")
    Set cond2 = rg.FormatConditions.Add(xlExpression, , "=AND($G14<$D14-$E14,$E14<>"""")")

    'define the format applied for each conditional format
    With cond1
        .Font.FontStyle = "Bold"
        .Font.Color = vbRed
    End With

    With cond2
        .Font.FontStyle = "Bold"
        .Font.Color = vbRed
    End With
End Sub

请注意，如果每个规则的格式相同，则可以将两者合二为一。