在特殊条件下将一系列单元格粘贴到相同大小的目标范围？

Question

感谢您帮助我。我在网上找不到解决方案，所以这里是：P。我想知道如何将一系列值（在本例中为 C6:R371）粘贴到另一个相同大小的工作表中。我的问题是我只想将源工作表中的数据粘贴到目标工作表上空白的单元格中，而不是更改目标工作表上已经在 C6:R371 范围内的值。本质上，我有一系列需要 c&p 的单元格，但我希望宏只将范围内的值粘贴到目标范围的空白单元格上。非常感谢你

    Range("C6:S371").Select
    Selection.Copy
    wbWest2.Activate
    Dim rng As Range 
    Dim row As Range 
    Dim cell As Range 
    Set rng = Range("D9:S374") 
    For Each row In rng.Rows 
    For Each cell in row.Cells 
    If cell.value = 0 then selection.paste 
    Next cell 
    Next row         

Answer 1

使用With ... End With statements 隔离两个工作表，以便它们的单元格是唯一考虑的单元格。最快的比较是将两个范围批量加载到变体数组中。

Sub fill_blanks_from_source()
    Dim r As Long, c As Long, aSRCs As Variant, aDSTs As Variant

    With Worksheets("Sheet1")     '<~~ source
        aSRCs = .Range("C6:R371").Value2
    End With
    With Worksheets("Sheet2")     '<~~ destination
        aDSTs = .Range("D9").Resize(UBound(aSRCs, 1), UBound(aSRCs, 2)).Value2
    End With

    For r = LBound(aDSTs, 1) To UBound(aDSTs, 1)
        For c = LBound(aDSTs, 2) To UBound(aDSTs, 2)
            If Not CBool(Len(aDSTs(r, c))) Then
                aDSTs(r, c) = aSRCs(r, c)
            End If
        Next c
    Next r

    With Worksheets("Sheet2")
        .Range("D9").Resize(UBound(aDSTs, 1), UBound(aDSTs, 2)) = aDSTs
    End With

End Sub

一旦满足比较条件并且目标中的空白值填充了源中的值，整个变体数组就会返回到目标工作表。

范围将始终保持相同的大小。将源值加载到第一个变量数组后，LBound 和 UBound 函数将用于从左上角的单元格扩展的目标范围的所有进一步尺寸标注。