如何使用 Windows 命令提示符删除空文件夹？答案

【问题标题】：How to delete empty folders using windows command prompt?如何使用 Windows 命令提示符删除空文件夹？
【发布时间】：2011-12-11 11:46:06
【问题描述】：

我需要使用 Windows 命令提示符从我的应用程序文件夹中删除所有空文件夹吗？

如何创建这样的 bat 文件？

请帮帮我。

【问题讨论】：

标签： windows command-line command directory

【解决方案1】：

您可以使用ROBOCOPY 命令。它非常简单，也可以用来删除大层次结构中的空文件夹。

ROBOCOPY folder1 folder1 /S /MOVE

这里的源和目标都是folder1，因为您只需要删除空文件夹，而不是将其他（必需）文件移动到不同的文件夹。 /S 选项是跳过复制（在上述情况下移动）空文件夹。由于文件在同一个驱动器内移动，速度也更快。

【讨论】：

喜欢它。但是 robocopy 是否始终可用以便成为公认的答案？
好的，这看起来很棒并且有效！我只是不明白为什么，如果从项目文件夹中运行 cmd，它会给我“错误 32 (0x00000020) 删除源目录” - 这意味着它无法删除主目录！感谢上帝，它不能删除它，因为不应该 - 它不是空的！（“该进程无法访问该文件，因为它正被另一个进程使用。” - 其中文件必须是目录）。我在里面运行： robocopy 。 . /s /move。
@PedroReis 据我说，当您在子文件/文件夹仍处于打开状态时尝试删除/移动它时，您会收到此错误。如果您需要更多帮助，我认为最好将其作为一个新问题发布，以便遇到此问题的其他人可以找到您的问题并解决他们的问题。
@VarunSharma 我现在看到问题可能是 ROBOCOPY 确实将文件夹 1 移动到文件夹 1；检查它是否在同一位置，然后根本不要移动它，这不是明智的做法！并且真的删除并再次创建它。尽管如此，即使出现此错误，它仍然会删除空文件夹...（有点奇怪，但这是我想要的）
@PedroReis 实际上，它不会删除和创建文件。它只是更改地址，因为它是在同一个驱动器内完成的。尝试这个。 ROBOCOPY 一个 2+ GB 的文件，你可以看到它只需要不到 2 秒。它可以以这样的速度执行此操作，因为它实际上并不移动任何文件，而是更改驱动器文件系统表中的文件地址。我不确定它是否会更改地址，它可能只是检查地址。只有在创建文件副本或将文件移动到不同驱动器时才需要时间。

【解决方案2】：

更简单的方法是执行 xcopy 以使用 /s 开关制作整个目录结构的副本。 /s 的帮助说复制目录和子目录，除了空目录。

xcopy dirA dirB /S

其中 dirA 是空文件夹的源。 DirB 将是没有空文件夹的副本

【讨论】：

这应该是公认的答案。又好又简单！谢谢！
添加 /I 开关，例如xcopy dirA dirB /SI 将跳过提示“dirB 在目标上指定文件名或目录名吗？”
我同意这很简单，但我有一个包含超过 1TB 数据的目录结构。我不想复制它！
你可以用 RoboCopy 做类似的事情，而不是复制空文件夹。我想如果你要复制数据很有用，但如果你想修剪空文件夹就不行了。
另外请注意，这不会复制隐藏文件和系统文件 - 包括 /h 标志

【解决方案3】：

for /f "usebackq" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"

来自：http://blogs.msdn.com/b/oldnewthing/archive/2008/04/17/8399914.aspx

当然，在执行该命令之前，我会先对其进行测试而不删除。此外，这是来自 cmets 的修改版本，其中包含带空格的文件夹：

 for /f "usebackq delims=" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"

附：博文中有更多的 cmets 可能会对您有所帮助，因此请务必在尝试之前阅读这些内容

【讨论】：

我喜欢这个。这里的链接提到这个更简单（类似于下面的那个）：for /f "tokens=*" %%d in ('dir /ad/b/s ^| sort /R') do rd "%%d"
你把文件夹路径放在哪里？
@MAGx2 我也有这个问题。我不知道如何在 cmets 中发布反引号，但我正在使用 ([backquote]dir /ad/b/s "c:\path"[backquote])
如果您不在批处理文件中使用上面的行，那么您需要将%%d替换为%d
使用 ROBOCOPY 可以轻松完成。有关详细信息，请参阅下面的答案。

【解决方案4】：

你不需要 usebackq：

FOR /F delims^= %%A IN ('DIR/AD/B/S^|SORT/R') DO RD "%%A"

【讨论】：

谢谢汤姆...你是对的。但是在命令行中，它实际上会使用与批处理文件相反的单个 % 。用户：请注意，RD 不会删除文件或包含文件的目录。只是空目录。所以它是完全安全的。 FOR /F delims^= %A IN ('DIR/AD/B/S^|SORT/R') DO RD "%A"
如果您使用的是 cygwin，请确保检查您的路径顺序，或明确将 SORT 指向 dos 版本。

【解决方案5】：

从同一引用页面添加到被腐蚀的答案是 PowerShell 版本 http://blogs.msdn.com/b/oldnewthing/archive/2008/04/17/8399914.aspx#8408736

Get-ChildItem -Recurse . | where { $_.PSISContainer -and @( $_ | Get-ChildItem ).Count -eq 0 } | Remove-Item

或者，更简洁地说，

gci -R . | where { $_.PSISContainer -and @( $_ | gci ).Count -eq 0 } | ri

鸣谢作者

【讨论】：

【解决方案6】：

这是上述的混合体。它会删除所有早于 X 天的文件，并删除给定路径的所有空文件夹。要使用，只需设置日期、文件夹路径和驱动器

@echo off
SETLOCAL
set days=30
set folderpath=E:\TEST\
set drive=E:

::Delete files
forfiles -p %folderpath% -s -d -%days% -c "cmd /c del /q @path "

::Delete folders
cd %folderpath%
%drive%
for /f "usebackq delims=" %%d in (`"dir /ad/b/s | sort /R"`) do rd "%%d"`

【讨论】：

不错，但我必须在 /f "usebackq delims=" %%d in ("dir /ad/b/s | sort /R") do rd "%%d" 的最后一行末尾删除撇号

【解决方案7】：

从命令行： for /R /D %1 in (*) do rd "%1"

在批处理文件中 for /R /D %%1 in (*) do rd "%%1"

我不知道它是否有这样的记录，但它适用于 W2K、XP 和 Win 7。我不知道它是否总是有效，但它不会意外删除文件。

【讨论】：

【解决方案8】：

它会工作得很好。这是删除旧文件和递归删除空目录的最佳方法。以下 .bat 文件是，

forfiles /p [PATH] /s /m [FILE-PATTERN] /d -[DAYS] /c "cmd /c del @path"
for /f "delims=" %%d in ('dir [PATH] /s /b /ad ^| sort /r') do rd "%%d"

占位符需要替换如下（不带引号）：

[DAYS] = Max. age of the files in days, e.g. “10”
[PATH] = Path to search for old files and empty folders, e.g. “C:\Backup\”
[FILE-PATTERN] = Pattern that matches files to delete, e.g. “*.bkp”

该脚本已在 Windows 7 和 Windows Server 2003 下成功测试。

【讨论】：

【解决方案9】：

安装任何适用于 Windows 的 UNIX 解释器（Cygwin 或 Git Bash）并运行 cmd：

find /path/to/directory -empty -type d

To find them

find /path/to/directory -empty -type d -delete

To delete them

（不是真正使用 windows cmd 提示符，但它很简单，运行需要几秒钟）

【讨论】：

加上十个用于包括如何找到它们。
在我的 find 版本中，第一个命令有效，但添加 -delete 时显示“invalid predicate -delete”

【解决方案10】：

@echo off
set /p "ipa= ENTER FOLDER NAME TO DELETE> "
set ipad="%ipa%"
IF not EXIST %ipad% GOTO notfound
IF EXIST %ipad% GOTO found
:found
echo DONOT CLOSE THIS WINDOW
md ccooppyy
xcopy %ipad%\*.* ccooppyy /s > NUL
rd %ipad% /s /q
ren ccooppyy %ipad%
cls
echo SUCCESS, PRESS ANY KEY TO EXIT
pause > NUL
exit 
:notfound
echo I COULDN'T FIND THE FOLDER %ipad%
pause
exit

【讨论】：

【解决方案11】：

如果您想在资源管理器上下文菜单中使用 Varun 的 ROBOCOPY 命令行（即右键单击），这里是 Windows 注册表导入。我尝试将此作为评论添加到他的答案中，但内联标记不可行。

我已在自己的 Windows 10 PC 上对此进行了测试，但使用风险自负。它将打开一个新的命令提示符，运行命令，然后暂停，以便您可以看到输出。

复制到一个新的文本文件中：

Windows 注册表编辑器 5.00 版

[HKEY_CURRENT_USER\Software\Classes\directory\Background\shell\Delete Empty Folders\command] @="C:\Windows\System32\Cmd.exe /C \"C:\Windows\System32\Robocopy.exe \"%V\" \"%V\" /s /move\" && PAUSE"

[HKEY_CURRENT_USER\Software\Classes\directory\shell\Delete Empty Folders\command] @="C:\Windows\System32\Cmd.exe /C \"C:\Windows\System32\Robocopy.exe \"%V\" \"%V\" /s /move\" && PAUSE"
将 .txt 扩展名重命名为 .reg
双击导入。

【讨论】：

感谢 Varun Sharma 的原创作品。

【解决方案12】：

for /r "D:\Music" /d %F in (.) do @dir /b "%F" | findstr "^" >nul || rmdir %~fF

D:\Fun 是包含空文件夹的文件夹文件夹名有空格的情况下双引号（本例不需要）

【讨论】：

【解决方案13】：

好吧，对于没有空格的简单 1 级目录结构、[编辑] 以及仅包含一种我认为有用的文件类型的目录（在某些时候来自 http://www.pcreview.co.uk/forums/can-check-if-folder-empty-bat-file-t1468868.html），这只是一个快速而肮脏的建议：

for /f %a in ('dir /ad/b') do if not exist %a\*.xml echo %a Empty

/ad : 只显示目录条目
/b : 使用裸格式（只是名称）

[edit] 使用普通星号检查任何文件（上面的 %a\*）将不起作用，感谢更正

因此，删除将是：

for /f %a in ('dir /ad/b') do if not exist %a\*.xml rmdir %a

【讨论】：

即使目录为空，上面的测试也通过了。
@SteveHollasch 感谢您的评论，我更正了上面的代码

【解决方案14】：

这可以通过使用带有两个参数的rd 命令轻松完成：

rd <folder> /Q /S

/Q - 安静模式，不询问是否可以删除目录树 /S
/S - 删除指定目录中的所有目录和文件 除了目录本身。用于删除目录树。

【讨论】：

它会删除所有文件，而不仅仅是空文件夹。
Format C: 也会删除空文件夹，而且命令会更短；)